表示されている５つのキャラクタが少しずつ変化していきます。変化したらすかさずHit!

ときどき入る邪魔にめげず、視野の端の変化を見逃すな！

はじめに

本ゲームはPB-100シリーズ(拡張メモリ不要)を推奨します。PB-SIM(normal)に対応しますが、PokecomGOには対応しません。プログラム・サイズは541stepsです。

遊び方

Shift+[0]でゲーム開始です。画面に表示される５つのキャラクタが、時間経過とともに徐々に変化しますので、変化した瞬間に対応するキー[Q][W][E][R][T]を押します。変化後に正解キーをすばやく押すほど高得点が入ります。

・変化して一定の時間が経つと、正解キーを押しても得点はゼロになります。

・間違ったキーを押すとスコア減点１となります。スコアは99点が上限です。

・変化の総回数はランダムです。

・300サイクルで終了してスコアを表示します。

・ときどき邪魔が入ります。邪魔の種類は、黒塗り／全消去／邪魔キャラ表示／表示位置ズレ

プログラム・リスト（PB-SIM形式）

[P0]

5 VAC

10 $="1Ii!l8B0OD2Z7Z2TYX\\Y>\GE)]>.,\DT'\DT":N$=" "

15 FOR I=0 TO 4:V(I)=5*INT(RAN#*6:O$(I)=MID(V(I)+1,1):NEXT I

20 FOR I=0 TO 300:E=0:J=RAN#

25 IF J<.95 THEN 50

30 IF J>.98;N$=MID(1+RAN#*30,1):GOTO 50

35 IF J>.97;E=1:PRINT:GOTO 50

40 N$=" ":IF J>.96;PRINT:GOTO 55

45 PRINT CSR0;"\BX\BX\BX\BX\BX\BX\BX\BX\BX";:GOTO 55

50 PRINT CSR E;O$+N$+P$+N$+Q$+N$+R$+N$+S$;

55 PRINT CSR11;" ";CSR9;L;CSR9;":";

60 D=D-SGN D:K$=KEY:IF K$<>"";GOSUB #1:D=0

65 IF RAN#>.05;NEXT I:PRINT:PRINT "Score";L:END

70 C=INT(RAN#*5:V(C)=V(C)-4+5*SGN FRAC(.2+V(C)/5

75 O$(C)=MID(V(C)+1,1):D=9:GOTO 25

[P1]

1 GOTO 10

2 L=L+D:IF L>99;L=99

3 RETURN

4 L=L+SGN L*(SGN D-1):RETURN

10 IF D>0 THEN C*2+30

20 GOTO 4 

30 IF K$="Q" THEN 2

31 GOTO 4 

32 IF K$="W" THEN 2

33 GOTO 4 

34 IF K$="E" THEN 2

35 GOTO 4 

36 IF K$="R" THEN 2

37 GOTO 4 

38 IF K$="T" THEN 2

39 GOTO 4 

ゲーム集へ戻る　ホームへ戻る