サンフランシスコ湾内の島にあるアルカトラズ連邦刑務所。脱出不可能と評される監獄に、新入りの受刑者モリスが送られてくる。頭脳明晰な彼に刑務所長が警戒を強める中、彼は数人の囚人仲間と共に通気孔を外して脱出する計画を立てた。

明日、モリスは房を移される。決行は今夜だ。果たして明朝の点呼までに脱出できるか…？

遊び方

Shift+[0]で脱獄開始です。

Stage 1　独房からの脱出

[4]を押すとモリスが起き上がり、壁の前で押し続けるとスプーンで壁を少しずつ掘削します。

[6]を押すと急いでベッドに戻り、スプーンを隠します。

・一定間隔で看守が近づき、モリスの房を覗き込みます。ベッドにダミー人形を置いているので直ちには気づかれませんが、モリスがベッドに寝ていなかったり、スプーンを隠せていないと怪しみゲージが＋１します。

・怪しみゲージが３になると独房検査が入り、脱獄失敗です。

・朝６時になると点呼が入り、脱獄失敗です。

・看守は時々フェイントをかけて戻ってきます。怪しみゲージが高くなると頻繁に戻ってきます。

Stage 2　屋上からの脱出

壁を貫通したら屋上から脱出のシーンになります。すぐに[2]キーを押してしゃがみ、サーチライトによる監視を避けてください。タイミングを見て[4]キーを押して左側へ移動し、左端（海岸）に到達したら脱獄成功です。
用意した手製ボートを使って極寒のサンフランシスコ湾を渡り、逃げ切りましょう。

・Stage 2への切り替わりは何の予告もありませんので、すぐに[2]キーでしゃがんでください。

・時刻はStage 1から継続しています。左端（海岸）到着前に点呼が始まると、失敗です。

[P0]

1 VAC

2 $="\BX\BX\BX\BX\BX\BX#______\CL  \CL \TR \DT  0123456":G=4.9:W=6:X=8:H=-1

3 PRINT "ALCATRAZ"

4 M$=MID(24+T,1)+MID(7-INT W,6):N$="=\CII"+MID(14+2*INT G,2)

6 PRINT CSR0;M$+N$;:IF F=1;PRINT CSR X-1;"q\PI";

7 MODE S+4:IF X=1 THEN #2

8 K$=KEY:IF K$<>"";GOSUB #1

9 G=G+H*RAN#/2:IF S+1>RAN#*20;H=-1

10 IF G>=5;G=4.9:H=-H

11 IF G<.7;G=.7:H=-H:S=S+F:IF S>2;T=7

12 GOSUB #3:GOTO 4

[P1]

1 IF K$<>"4" THEN 5

2 IF F=0;F=1:RETURN

3 IF X-W<2;W=W-RAN#/5:RETURN

4 X=X-1:RETURN

5 IF K$<>"6";RETURN

6 IF X<8;X=X+1:RETURN

7 F=0:RETURN

[P2]

1 M$=MID(1,6):X=9

2 $=KEY:N$="@":IF $="2";N$="a"

3 PRINT CSR0;M$+M$;CSR V;" + ";CSR X;N$;

5 IF X=0;PRINT:PRINT "ESCAPED":END

6 IF X=V+1;IF N$="@";T=7

7 V=V+1:IF V=9;V=0

8 IF $="4";X=X-1

9 GOSUB #3:GOTO 2

[P3]

1 IF T>6;PRINT:PRINT "Caught":END

2 T=T+.02:RETURN

あとがき

1979年公開、クリント・イーストウッド主演の映画「アルカトラズからの脱出」をモチーフにした手に汗握る？脱獄ゲームです。あれ、実話なんですよね。脱獄囚フランクは、まさか62年後の日本のポケコンの上でも自分が穴掘りしているとは、夢にも思わなかったことでしょう。

アルカトラズからの脱出（映画）