Auyan-Tepui
ア ウ ヤ ン ・ テ プ イ
南米の秘境・ギアナ高地の広大で急峻なテーブルマウンテンに登攀します。
断崖や高い段差は登れません。よじ登れるルートを見つけ、一歩ずつ頂上を目指しましょう。
テーブルの頂から見える幻の絶景とは… ?
べき乗を乗算に変更して、ちょっぴり高速化しました。 2024/1/31
!注意!
本ゲームは広大なマップを有する一種の迷路であり、難易度は高いです。
ヒントが欲しい方は QR コードを読んで下さい 。自力で解いてみたい人は見ないでください。
対応機種
PB-SIM(fast モード)、PockecomGO(fast モード) ※パソコンはテンキー使用を推奨
プログラムサイズは 542 ステップです。
※PB-100 実機(拡張メモリ無し)でも動作しますが、非常に計算量が多いため推奨しません。
プログラム入力
プログラム・リストを入力し、[P0]にて RUN[EXE]または Shift+[0]で開始します。
中断後の再開は、[P0]にて RUN 3[EXE]です。
遊び方
タイトル表示で[EXE]キーを押すと、ゲーム開始となります。ベースキャンプは座標(-1.4,-0.5)にあり、北の方角を向いています。ここから正面にそびえるテーブ ルマウンテン(テプイと呼ばれる)の頂上である標高 20 を目指して進んで下さい。
進めるのは以下の地形のみです。現在地に対し標高差2以上の段差(=崖)は登れません。
・現在地と同じ標高(平地)
・現在地より標高差 1 のみ高い段差
・現在地より低い標高(落差が大きくても懸垂下降で降りる想定 )
キーを押すと、押したキーのキャラクタを表示してから、地形計算に入ります。キャラクタが消えて、地形が更新表示されたら、次のキー入力ができます。
テプイとベースキャンプの位置関係
目指すテプイは、ベースキャンプから向かって前方~右前方(北東方向)に広がっており、その大き さは東西/南北何れもおよそ 100 歩数(ズームレベル1の場合)です。周囲は断崖絶壁に囲まれてい ますが、頂上まで到達できるルートが幾つかあると伝えられます。それを探し出し、なるべく少ない 歩数で頂上に到達することを目指しましょう。
[*]を押すと、現在地の座標 X,Y を表示します。
ズームについて
頂上まであと少しというところで、高い崖に阻まれるのがテプイ登攀の怖いところ。どうしても行き 詰ったら、[+]を押してズームしてみましょう。歩幅が半分になります。登れそうにない高い崖でも、 歩幅を狭めてよく見ると小さな段差があって登れる場合もあります。 但し、以下注意点があります。
・ズームは2回(表示 1z→2z→3z)まで可能です。
・一度ズームすると元には戻せません。
・ズームするとスコアが大幅に下がっていきます。従って最後までズームは我慢しましょう 。
登頂!
徐々に高度を上げていき、標高 20 に到達するとテプイ登頂です。スコアを表示したあと、眼下に広がる絶景が表示され、ゲーム終了です。 作者が最短コースで登頂したとき、スコアは 151 でした 。
テプイの秘密について
古い石板によれば、登頂を目指すテプイには何らかの秘密があるそうです。全体の形に鍵があるとも言 われますが、テプイはあまりに広大で険しく、全容は明らかになっていません。また、一帯のガウシア ン平原は通常世界とは隔絶した異界の地であることから、秘密は厚いベールに包まれています。 あなたには分かりますか ?
このテプイは一体何でしょう。お分かりの方、宜しければnuao1109@gmail.comまでメールを下さい。
![](https://www.google.com/images/icons/product/drive-32.png)
プログラム説明書
実機でも動きますが、遅すぎ。
(原理的に計算量が多い)
PB-100実機形式
PB-SIM形式
[P0]
1 VAC
2 PRINT "Auyan-Tepui":E=-1.4:F=-.5:H=.02:L=2:Z=1
3 $=" _.,-\PI\SQ\SG\DA\LA^\RAE-=:"
4 X=E-H:Y=F+G:K=0:GOSUB #1:X=E+H:Y=F-G:K=1:GOSUB #1
5 X=E+G:Y=F+H:K=2:GOSUB #1:K=SGN G:R=SGN H:PRINT
6 PRINT B$+D$+C$;L;Z;"z ";MID(9+2*ABS K+ABS R+K+R,1);
7 IF L<20 THEN 15
8 K=1:PRINT:PRINT "TOP!";INT(10^4/S
9 PRINT MID(K+12,1);:K=K+1/K:IF K<5 THEN 9
10 END
15 $=KEY:IF $="" THEN 15
20 PRINT CSR1;$;:IF $="1";K=G:G=-H:H=K
25 IF $="3";K=G:G=H:H=-K
30 IF $="5";IF I-L<2;E=X:F=Y:L=I:S=S+Z^Z
35 IF $="*";PRINT:PRINT E;F
40 IF $<>"+" THEN 3
45 IF Z<3;Z=Z+1:H=H/2:G=G/2
50 GOTO 3
[P1]
1 I=0:V=0:W=0
2 M=V*V-W*W+X:N=2*V*W+Y:IF M*M+N*N>4 THEN 4
3 V=M:W=N:I=I+1:IF I<20 THEN 2
4 R=1:IF I-L>=6;R=8:GOTO 6
5 IF I-L>=0;R=I-L+2
6 B$(K)=MID(R,1):RETURN