Dq+pB
on PB-100+OR-1 / PB-SIM / Pokecom GO
by NUAO / Jan. 2023
あの伝説の大冒険が、いま PB で蘇る…
Roto の剣で「りゅうおう」を倒せ !
＜遊び方＞
・RUN モードにおいて「MODE 5[EXE]」と操作し、RAD モードにしておきます。 （DEG モードでは遊べません）
・初回は[Shift]+[9]で開始します。中断後のゲーム再開は[Shift]+[0]です。
・ラダトームの町近くの大平原からスタートします。
大平原（2D）
キー入力
[2][4][6][8] 東西南北移動
[A] メニューを開く
山岳△と海（には行けません。
森林 では強い敵が現れます。最初は大平原で弱い敵を倒しましょう。
ラダトームの町ｈ及びダンジョン Ω に行くと自動的に中に入ります
バトル
キー入力
[A]を押すと攻撃 Attack します。強さ（レベル）に応じたダメージを与えます。但し外すこともあります。
[H]を押すと、薬草 Herb を使って体力を最大まで回復します。薬草の残数が０であれば回復しません。
[X]を押すと逃げる eXit ことを試みます。但し必ずしも成功するとは限りません。
勇者のアクションが終了すると、敵が攻撃します。但し外すこともあります。
勇者が攻撃されダメージを受けると「***」と表示します。
敵を倒すと、Gold と経験値が手に入ります。
勇者は一定の経験値を積むとレベルアップします。レベル５が最高です。
勇者の体力が０になると死亡し、魂がラダトームの町に戻り、王の命で再生します。 その際所持金は半減します。それ以外のパラメータは保存します。
ラスボスを倒すとクリアです
ダンジョン
ダンジョンは疑似３Ｄ表示です。
左右の壁があるときは 「 ）」、「（ 」 無いときは「 」(スペース)を表示します。
正面の壁があるときは「□」、無いときは「 」(スペース)を表示します。
キー入力
[5]で一歩前進します。
[1][3]で左右を向きます。
[A]でメニューを開きます。
ダンジョンの中では、より強い敵が、高い頻度で現れます。
どこかに Roto の剣があり、取ると攻撃力が増します。
ダンジョン入口で外を向くと、ダンジョンの外に出ます
ラダトームの町
先ずステータスを表示します。
[EXE]を押すと町のメニューを表示します。
キー入力
[I]を押すと宿に 2gold で泊まります。体力が最大まで回復します。
[S]を押すと店で薬草を一つ買います。(勇者のレベルに応じて値段が上がる)
{C]を押すと王に謁見して町を出発します。
メニュー
メニューは、大平原移動時、ダンジョン移動時に[A]ボタンで開くことができます。
先ずステータスを表示します。
[EXE]を押すとメニューと勇者のレベルを表示します。
キー入力
[H]を押すと薬草を使い、体力を回復します。
[X]を押すとメニューを終了します。
DQPB 説明書.pdfPB-SIM形式
[P9]
5 VAC
10 L=1:H=10:F=2:I=4:J=6:PRINT CSR 3;"Dq+pB":GOTO #0
[P0]
5 P=J:GOSUB 89:PRINT:PRINT $;CSR I;"\CL";
10 M$=MID(I+1,1):IF M$="h";GOTO #3
15 IF M$="\OM";X=-3:Y=4:V=0:W=-1:GOTO #2
20 IF RAN#<.2;GOTO #1
25 $=KEY:IF $="" THEN 25
30 IF $="A";GOSUB #4:GOTO 5
35 R=I:S=J:IF $="4";I=I-1
40 IF $="6";I=I+1
45 IF $="8";J=J-1
50 IF $="2";J=J+1
55 P=J:GOSUB 89:C$=MID(I+1,1)
60 IF C$<>"\TR";IF C$<>"(" THEN 5
65 I=R:J=S:GOTO 5
89 GOTO P+90
90 $="\TR\TR\TR\TR\TR\TR\TR\TR":RETURN
91 $="\TR\OM\SP\SP\TR\TR\SP (":RETURN
92 $="\TR\TR\TR \SP\SP (":RETURN
93 $="\TR\TR\TR\SP\SP (":RETURN
94 $="\TR\TR\SP\TR ((":RETURN
95 $="\TR\SP\SP (":RETURN
96 $="\TR\TR h \SP(":RETURN
97 $="\TR\TR\SP (":RETURN
98 $="\TR\TR\TR\SP\SP ((\SP(":RETURN
99 $="\TR\TR\TR\TR(((((":RETURN
[P1]
5 $="cx\MUyMP\SG":D$="\BX\BX\BX"
10 IF O=7 THEN 30
15 IF M$=" ";O=1+INT(RAN#*2:D$="___":GOTO 30
20 IF M$="\SP";O=1+INT(RAN#*4:D$="\SP\SP\SP":GOTO 30
25 O=3+INT(RAN#*4
30 Q=3*O*O
35 PRINT:PRINT "[";D$;"]";H;"AHx";CSR 2;MID(O,1);
40 K$=KEY:IF K$="" THEN 40
45 IF K$="A" THEN 80
50 IF K$="H";IF F>0;H=L*L*10:F=F-1
55 IF K$="X";IF RAN#<.5 THEN 115
60 IF RAN#<.3 THEN 35
65 PRINT CSR 1;"***";:H=H-INT(RAN#*3*O*O:P=SIN SIN 2
70 IF H<=0;H=0:PRINT CSR 5;"DEAD":O=0:GOTO #3
75 GOTO 35
80 PRINT CSR 2;"/";:P=SIN SIN 2
85 IF RAN#>.9 THEN 60
90 Q=Q-L*L*(N+1:IF Q>0 THEN 60
95 PRINT CSR 2;"_";:G=G+2*O:E=E+O
100 IF E<(L+1)^3 THEN 110
105 IF L<5;L=L+1:PRINT CSR 5;"LvUp!"
110 IF O=7;PRINT:PRINT "CLEAR":END
115 O=0:IF M$="\OM" THEN #2
120 GOTO #0
[P2]
5 $=" )\SQ("
10 T=X+W:U=Y-V:GOSUB 80:A$=MID(Z+1,1)
15 T=X-W:U=Y+V:GOSUB 80:C$=MID(Z*3+1,1)
20 T=X+V:U=Y+W:GOSUB 80:B$=MID(Z*2+1,1)
25 PRINT:PRINT A$;B$;C$;
30 IF X=4;IF Y=-9;O=7:GOTO #1
35 IF Y-X=7;IF W=1;I=2:GOTO #0
40 IF X*Y=6;IF N=0;PRINT "Roto's";:N=1
45 K$=KEY:IF K$="" THEN 45
50 IF K$="1";P=V:V=W:W=-P
55 IF K$="3";P=V:V=-W:W=P
60 IF K$="A";GOSUB #4:GOTO 10
65 IF K$="5";IF B$=" ";X=T:Y=U
70 IF RAN#<.3;GOTO #1
75 GOTO 10
80 Z=0:IF 1.89<ABS(T+U-5*SIN T*COS (U+3)^2);Z=1
85 RETURN
[P3]
1 IF H=0;PRINT:PRINT "Revive":H=L*L*10:G=INT(G/2
3 PRINT:PRINT H;F;G;"G","\SP_In_Sp_\SPCa\SP";
5 $=KEY:IF $="C";PRINT:PRINT "GoodLuck":I=4:J=6:GOTO #0
7 IF $="I";IF G>=2;H=L*L*10:G=G-2:GOTO 3
8 IF $="S";IF G>=L;F=F+1:G=G-L:GOTO 3
9 GOTO 5
[P4]
1 PRINT:PRINT H;F;E;"E","Hb x";L;"L";
3 K$=KEY:IF K$="H";IF F>0;H=L*L*10:F=F-1:GOTO 1
5 IF K$="X";RETURN
7 GOTO 3
実機形式
