PIRATE's GOLD
博士からのメッセージ 「古代の宝の地図の、失われたピースが発見された! 」
湾の入口に面したとある遺跡に、古代海賊の秘宝伝説が伝わっている。古地図には宝の位置らしき場所は示されているものの、地図の大事な部分が失われているため、これまで誰もその正確な場所を知ることはできなかった。 ところが、私は長年にわたる研究の成果として、ついにこの失われたピースを発見することに成功した。宝の位置を特定する、極めて重要な情報がそこには書かれていた! しかし、このピースを私の研究室に保管することは極めて危険と判断した。そこでこれをある場所に隠すことにしたのだ。 皆さんには特別にそのピースの位置をお教えしたい。私は長年の研究で不自由な体となってしまい、もはや宝の場所までたどり着くことはできない。あとはあなた方の力で、座標を手に入れ、海賊の伝説的な財宝を見つけ出していただきたい。ただし、毒蛇が出るし、近くには毒沼もあるので、くれぐれも気をつけて欲しい。
これはGPS(又は GPS に見立てた PB-100)を使って宝を探すアドベンチャーゲームです。
ゲームは2モードから選択して挑戦できます。 マップは「だいたい同じ」です。
PB-100 モード:プログラムリストを入力することで、PB-100の中でプレイできます。
リアルモード:スマホを片手に、実フィールドの中でプレイできます 。
1.PB-100 モード
PB-100+拡張メモリ/PB-SIM/Pokecom GOに対応しています。
<遊び方>
・プログラム・リストを PB-100 に入力し、[P0]を実行するとスタートします。
・画面表示例
①方角 ②地形 ③距離
① 方角:目標への方角を示します。
(例) ↑↑ :ほぼ真北 ↑↑→:北北東 ↑→ :北東 ↑→→:東北東 →→ :ほぼ真東
②地形:自分の廻り東西南北の壁(崖)の様子を示しています。表示はありませんが中心に自分がいると考えてください。
東西 「・」壁(崖) 「 」通路
南北 「’」北に壁(崖) 「.」南に壁(崖) 「:」南北共に壁(崖)
※地形表示は門真なむ様の「MAZE 21x29」のアイデアを参考にしました。
③距離: 現在の目標までの距離を表示しています。 GPSですので誤差があります。
・操作
移動:東西 4←→6 南北8↑ 2↓
アクション(足元を探す等):A
・ここだと思う場所でアクション A を押してください。
・アクションの際に毒蛇(Viper)に襲われることがあり、その場合プレイヤーは驚いて(入口に近い方に)一目散 に逃げてしまいますので、そこから再スタートして下さい。毒蛇は入口から遠いほど頻繁に出現します。
・足元に何かあっても、必ず見つけられるとは限りません。諦めず探して下さい。なお、GPS 計測距離には誤差 があることに留意して下さい。
・最初、プレイヤーは博士から「失われたピース」の位置(XY 座標)を受け取っており、それを目標としてスタートします。 ゲームの進行に従い、新しい目標が自動的に「GPS」へロードされます。
・ゲームの最終目標:海賊の財宝を入手すること。
・ゲームを中断した場合、[P0]において RUN 50 で再開します。
2.リアルモード
長崎県に行くことができる方は、リアルモードに挑戦できます。
<遊び方>
・普通のスマホ又はGPS受信機を用意し、GPS を有効にします。PB-100は使いません。
・博士から頂いた「失われたピース」の座標をスマホの Google map の検索欄 に入力します。
失われたピースの座標:
「N32 43.139 E129 51.095」
・実際に座標の位置に行き、隠された「失われたピース」を探し、次の目標に向 かいます。
・携行品:スマホ、手袋、虫よけ、運動靴、古地図プリントアウト、筆記具、フラッシュライト、水筒
・毒沼(下水処理場)に迷い込まないように。またマムシに注意。
・所要時間(スタートからクリアまで):約1.5~2時間
・ゲームの最終目標:「海賊の財宝」を見つけてそこに名を記し、冒険の過程を SNS に up すること。
・バスで行く場合は、新地中華街バスターミナルから長崎バスの30番(戸町経由のもの)に乗車し、女神(めがみ)というバス停で降りると近いです。(二本松経由のものは通りませんので注意してください)
・車道からの入口に「許可なく立ち入ることはご遠慮ください」との表示がありますが、足元が悪いので自己責任でとの意味であり、立ち入り禁止ではないことを下水道局に確認済です。足元に注意して進んで下さい。
・★注意点★ 隠されているハコ(キャッシュといいます)は、全て元通りに戻してください。ただし、最後の宝箱に入っている小物は、宜しければ記念に1,2個お持ち帰り下さい。それ以外は持ち帰らないようにお願いします。(他にもゲームで訪れる人がいますので)
・ヒント ①階段脇の壁面 ②広場の縁 ③掲示板の裏
※このゲームシステムは、Geocaching.com におけるジオキャッシュ GC1EPKV「PIRATES OF NAGASAKI」を流用しています。GPS を備えた普通のスマホでプレイ可能です。
※全世界リアル宝探しゲーム Geocaching アクティビティの詳細は、https://i-red.info/geocaching/
※GPS 受信機の例は、https://www.garmin.co.jp/products/outdoor/?cat=handhelds
博士より受け取った古地図
![](https://www.google.com/images/icons/product/drive-32.png)
PBロッキーさんのアイデアを実践!
PB-SIM形式
[P0]
10 VAC
15 PRINT "PIRATEs'GOLD";
20 X=1:Y=16:M=6:N=15
50 C$="":P=(N-Y)/ABS(M-X+.01)
60 IF P>.2;C$="\DA":IF P>1.3;C$=C$+"\DA"
65 IF P<-.2;C$="^":IF P<-1.3;C$=C$+"^"
70 P=(M-X)/ABS(N-Y+.01)
75 IF P>.2;C$=C$+"\RA":IF P>1.3;C$=C$+"\RA"
80 IF P<-.2;C$=C$+"\LA":IF P<-1.3;C$=C$+"\LA"
90 E=INT(SQR((N-Y)^2+(M-X)^2)+RAN#*2-1)
100 V=X-1:W=Y:GOSUB #1:A$=" ":IF Z$="#";A$="\DT"
105 V=X+1:W=Y:GOSUB #1:B$=" ":IF Z$="#";B$="\DT"
110 K=0:V=X:W=Y-1:GOSUB #1:IF Z$="#";K=1
115 W=Y+1:GOSUB #1:IF Z$="#";K=K+2
120 $=" '.:"
125 PRINT:PRINT C$;CSR 4;"[";A$;MID(K+1,1);B$;"]";ABS(E);
130 $=KEY:IF $="" THEN 130
135 IF $="2";IF K<2;Y=Y+1
140 IF $="4";IF A$<>"\DT";X=X-1
145 IF $="6";IF B$<>"\DT";X=X+1
150 IF $="8";IF 0=FRAC(K/2);Y=Y-1
155 IF $="A";GOSUB #2
160 GOTO 50
[P1]
1 GOSUB 2+INT(W/3):L=10*(W-3*INT(W/3)):Z$=MID(L+V+1,1):RETURN
2 $="###########..###...##........#":RETURN
3 $="####.##..##....######.###....#":RETURN
4 $="#........######.#..###....####":RETURN
5 $="##.#########...#########.##..#":RETURN
6 $="####.....#####.#...#####..##.#":RETURN
7 $="#####..####.....##############":RETURN
[P2]
5 IF RAN#>.6-Y/30 THEN 30
10 PRINT:PRINT "sS Viper!"
15 W=INT(RAN#*18):IF W<Y THEN 15
20 V=INT(RAN#*10):GOSUB #1:IF Z$="#" THEN 15
25 X=V:Y=W:RETURN
30 IF RAN#<.5 THEN 40
35 IF X=M;IF Y=N;GOSUB F+50:PRINT:PRINT $:RETURN
40 PRINT:PRINT "None.":RETURN
50 F=1:M=8:N=1:$="GetBox(XY)!":RETURN
51 F=2:M=6:N=15:$="\SQ\LANeedKey..":RETURN
52 F=3:M=2:N=1:$="GetKey(XY)!":RETURN
53 F=4:M=8:N=1:$="\MU GetKey!!":RETURN
54 PRINT:PRINT "Get $Golds$ Clear!":END
実機形式