Touchscreen

$Crystal=8000000

$hwstack=40

$swstack=16

$framesize=32

' ------------------------------- Initialisierungen

' LCD

   Config Lcdpin = Pin , Db4 = Portd.7 , Db5 = Portd.6 , Db6 = Portd.5 , Db7 = Portd.4 , E = Portb.1 , Rs = Portb.0

   Config Lcd = 16 * 2

   initlcd

   Cls

   Cursor Off

' ADC

   Config Adc = Single , Prescaler = Auto , Reference = avcc

   Start Adc

' Pins

   LCDLight alias portb.2:config  LCDLight = output:set lcdlight

' ------------------------------- Variablendeklaration

   dim pos(2) as word

' ------------------------------- Programmbeginn

  '            X1    Y2    X2    Y1

  '            C.2   C.3   D.3   D.2

  '            12    11    14    13

  'measure X:  VCC   ADC   GND   --

  'measure Y:  ADC   VCC   --    GND

  '

  ' PC2/3 per PullDown Widerstand (10k) auf GND ziehen, damit stabiles Ergebnis und Erkennung von "Nicht gedrückt" erfoglt

  lcd "Touchscreen"

  lowerline

  lcd version()

  wait 1

  cls

  do

   ' bei den Deklarationen der Ein/Ausgänge erst auf Eingang setzten,

   ' da sonst "Kurschluss" vorkommen kann

   ' lese X Position

   ddrc.3=0:ddrd.2=0 'Y2 und Y1 auf Eingang

   portc.3=1:portd.2=0 'Y2 pull-up und und Y1 in tristate

   ddrc.2=1:ddrd.3=1 'X1 und X2 auf Ausgang

   portc.2=1:portd.3=0' X1=1, X2=0

   pos(1)=getadc(3)    ' lese ADC Wert

   ' lese Y Position

   ddrc.2=0:ddrd.3=0 'X1 und X2 auf Eingang

   portc.2=1:portd.3=0' X1 pull-up und X2 in tristate

   ddrc.3=1:ddrd.2=1 'Y2 und Y1 auf Ausgang

   portc.3=1:portd.2=0 'Y2=1 und Y1=0

   pos(2)=getadc(2)    ' lese ADC Wert

   'Ausgabe

   upperline

   lcd "X: ";

   if pos(1)<30 or pos(1)>1000 then

      lcd "     "

   else

      lcd pos(1);"  "

   end if

   lowerline

   lcd "Y: ";

      if pos(2)<30 or pos(2)>1000 then

      lcd "     "

   else

      lcd pos(2);"  "

   end if

   waitms 100

  loop