Now lets connect some sensor channels to the Gabrielle's head transforms

click-select the "AngX" server channel, click-select the  "Head Side-side" client channel

click on the "Add Link" button

must be selected when you use the "Modify" or "remove" button

You can save/load your server-client links as a text file

note that the script will not accept to load links for the Head when the selected object is not a Head

As you can see below when the Arduino starts

this is called the "HEADERS" message

then the next transmissions will be the property values, separated by TAB characters with an "eol\n" delimiter at the end of each record

this is called the "DATA" messages

By default the sampling rate is 10 per second ( 100ms intervals ) but you can adjust this with the "period (ms)" slider.

Also by default the Arduino doesn't send data samples until you click the "One Sample" button or you check-mark the "Periodic" checkbox

 
 Source code for mpu6050.ino
 
 
#include <MPU6050_tockn.h>
#include <Wire.h>

//mCasualJacques 08/26/2018 5:18PM

MPU6050 mpu6050(Wire);
bool bPeriodic = false;
int period = 100;
long timer = 0;
long timezero = millis();

void setup() {
  Wire.begin();
  mpu6050.begin();
  mpu6050.calcGyroOffsets(true);

  Serial.setTimeout(50); //improve responsiveness
  Serial.begin(57600);
  delay( 10 );
  // note: we delayed the Serial.begin() until now
  // to avoid having the mpu6050 setup functions
  // sending debug info in a format that
  // mcjMPU6050.dsa cant process
  // the alternative would be to modify MPU6050_tockn.cpp
  // but we prefer not doing that
  sendHeaders();
}  

void sendHeaders()
{  
  timezero = millis();
  Serial.print( "HEADERS\t" );
  Serial.print(millis()-timezero);  Serial.print("\t");
  Serial.print( "tmpr\t" );
  Serial.print( "aclX\t" );
  Serial.print( "aclY\t" );
  Serial.print( "aclZ\t" );
  Serial.print( "gyrX\t" );
  Serial.print( "gyrY\t" );
  Serial.print( "gyrZ\t" );
  Serial.print( "acAX\t" );
  Serial.print( "acAY\t" );
  Serial.print( "gyAX\t" );
  Serial.print( "gyAY\t" );
  Serial.print( "gyAZ\t" );
  Serial.print( "angX\t" );
  Serial.print( "angY\t" );
  Serial.print( "angZ\t" );
  Serial.print( "eol\n" );
}

void sendSample()
{
  Serial.print("DATA");                 Serial.print("\t");
  Serial.print(millis()-timezero);      Serial.print("\t");
  Serial.print(mpu6050.getTemp());      Serial.print("\t");
  Serial.print(mpu6050.getAccX());      Serial.print("\t");
  Serial.print(mpu6050.getAccY());      Serial.print("\t");
  Serial.print(mpu6050.getAccZ());      Serial.print("\t");
  Serial.print(mpu6050.getGyroX());     Serial.print("\t");
  Serial.print(mpu6050.getGyroY());     Serial.print("\t");
  Serial.print(mpu6050.getGyroZ());     Serial.print("\t");
  Serial.print(mpu6050.getAccAngleX()); Serial.print("\t");
  Serial.print(mpu6050.getAccAngleY()); Serial.print("\t");
  Serial.print(mpu6050.getGyroAngleX());Serial.print("\t");
  Serial.print(mpu6050.getGyroAngleY());Serial.print("\t");
  Serial.print(mpu6050.getGyroAngleZ());Serial.print("\t");
  Serial.print(mpu6050.getAngleX());    Serial.print("\t");
  Serial.print(mpu6050.getAngleY());    Serial.print("\t");
  Serial.print(mpu6050.getAngleZ());    Serial.print("\teol\n");
}

void loop() {
  mpu6050.update();
  if( (millis() - timer > period ) && bPeriodic ) 
  {
    sendSample();
    timer = millis();
  }
  else
  {
    if (Serial.available()) 
    {
      //example: "period 33" for 30fps
      String str = Serial.readString();
      str.replace("\n","");
      int pos = str.indexOf( "period" ); 
      if( pos >= 0 )
      {
        period = str.substring( pos + 6 ).toInt(); 
        Serial.print("ACK"); Serial.print("\t");
        Serial.print(millis()-timezero); Serial.print("\t");
        Serial.print(str); Serial.print("\teol\n");
      }
      else if( str.indexOf( "getHeaders" ) >= 0 )
      {
        sendHeaders();
      }
      else if( str.indexOf( "getSample" ) >= 0 )
      {
        sendSample();
      }
      else if( str.indexOf( "setPeriodic on" ) >= 0 )
      {
        bPeriodic = true;
        Serial.print("ACK"); Serial.print("\t");
        Serial.print(millis()-timezero); Serial.print("\t");
        Serial.print(str); Serial.print("\teol\n");
      }
      else if( str.indexOf( "setPeriodic off" ) >= 0 )
      {
        bPeriodic = false;
        Serial.print("ACK"); Serial.print("\t");
        Serial.print(millis()-timezero); Serial.print("\t");
        Serial.print(str); Serial.print("\teol\n");
      }
      else
      {
        Serial.print("NACK"); Serial.print("\t");
        Serial.print(millis()-timezero); Serial.print("\t");
        Serial.print(str); Serial.print("\teol\n");
      }
    }
  }
}


 
 
 
 

________________________________________________________________________

Notes
________________________________________________________________________
using a sampling period lower than the desired sampling period
may allow you to get up to 120 samples per second.
but dont go too low, else the arduino will not have idle time to check 
your commands. a sampling period of 10ms was ok

The arduino transmits 14 parameters, if only the last 3 interest you
then in mcjmpu6050.ino comment out the lines  for those parameters
Be careful not to comment out the following lines. Also make sure that 
if you comment out a DATA item, you comment out the corresponding HEADERS item

  Serial.print( "HEADERS\t" );
  Serial.print(millis()-timezero);  Serial.print("\t");
  ...
  Serial.print( "eol\n" );

and

  Serial.print( "DATA\t" );

________________________________________________________________________
Programmer notes, protocol
________________________________________________________________________

The Arduino recognizes the following commands

 period 33
 set the sampling period at 33ms 
 getHeaders
 get the record column headers
 getSample 
 get one record values
 setPeriodic on
 setAutomatic sampling + transmission on 
 setPeriodic off
 setAutomatic sampling + transmission off 

The arduino can send the following responses

 HEADERS	0	tmpr	aclX	aclY	aclZ	gyrX	gyrY	gyrZ	acAX	acAY	gyAX	gyAY	gyAZ	angX	angY	angZ	eol
 response for getHeaders
 DATA	31293	28.36	0.02	-0.05	1.03	0.19	-0.02	-0.09	-2.83	-0.87	-1.14	-0.81	0.30	-2.73	-1.41	0.30	eol
 response for getSample
 ACK	8032	~~~valid command~~~	eol
 acknowledging valid commands
 NACK	8032	~~~invalid command~~~	eol
 acknowledging invalid commands

facer100.mp4

________________________________________________________________________