AGO .START
I INTENDED THIS TO BE QBREAK, BUT I CANNOT FIX THAT AT THE MOMENT.
I INTENDED THAT THE PRIOR QBREAK BE RENAMD QQBREAK
IT WORKS. DEMENTIA HAS GOT ME. THERE'S AT LEAST 1 MISTAKE,
BUT IT DOES WORK. OKAY, NOW IT DOES WORK.
C:\USERS\LIN\DOCUMENTS\Z390CODE\ZX
S FF230.!=C'DCB' (=,!=,<,<=,>,>=) (CAUSE I FORGET)
ASSEMBLE AND TEST
SET G=C:\USERS\LIN\DOCUMENTS\Z390CODE\ZX
SET SYSPRINT=%G%.SYSPRINT.TXT
SET SYSIN=%G%.SYSIN.TXT
SET IN=%G%.PRN
SET OUT=%G%.OUT.TXT
SET BREAK=%G%.BREAK.TXT
BAT\ASMLG %G%.MLC TIME(1)
TEST
SET G=C:\USERS\LIN\DOCUMENTS\Z390CODE\ZX
SET SYSPRINT=%G%.SYSPRINT.TXT
SET SYSIN=%G%.SYSIN.TXT
SET IN=%G%.PRN
SET BREAK=%G%.OUT.TXT
SET OUT=%G%.OUT2.TXT
BAT\EZ390 %G%.MLC TIME(1999) TEST(BREAK)
V02.20 DOES HAVE AN ERROR, BUT DOES SEEM TO WORK
V02.23 AFTER MUCH HAIR PULLING, IT DOES SEEM TO WORK.
DEFAULT GETMAIN IS 8K (PARM='2') YOUI CAN HAVE MORE (PARM='4')
SYSIN KEYWORDS ARE:
LOADLOC= 80000 FF000 FE000 (4K BOUNDS ARE NICE.
LOADLOC= 4R%, 13R% TO CREATE LIST COMMANDS FOR DSECT LABELS
LISTLEN=32 LENGTH OF LIST=LABEL DISPLAY
INSTLEN=32 LENGTH OF INST OPERAND DISPLAY
BREAK=LABEL,LABEL PLACES TO SET BREAK POINTS
LIST=LABEL, GENERATE LIST COMMANDS FOR THESE
OPCODE=TRT,ED* INSTRUCTIONS THAT I WANT TO STOP AT.
STOPLOC= LISTING LOC TO ABEND S0C3 TO HEPL WITH TESTING
STOP#= PRN RECORD # TO ABEND S0C3 "
USER MUST !!! PUT LABELS WITH CORRECT LOADLOC LOCATIONS/REGISTERS.
YOU CAN DO THIS WRONG. I HAVE DONE IT WRONG. IT'S PRETTY EASY
GENERAL DESCRIPTION OF SECTIONS OF CODE.
NORMAL INITIALIZATION.
GETMAIN FOR 8K (OR MORE) WORK AREA.
FIRST 1.5K ARE FIELDS THAT
I TOOK OUT OF THE W/A OF THE PROGRAM.
THEN ABOUT 1K OF TRT TABLES TO FIND VARIOUS THINGS
AFTER THAT IN THE GETMAIN I BUILD A 64 BYTE DSECT ENTRIES
FOR EVERY LABEL OR OPCODE SPECIFIED.
THEN INITIALIZE THE 256 BYTE TRT TABLES.
THE FIRST ONES ARE MAINLY SPACES.
THE LAST HALF DOZEN ARE MAINLY ZEROS
THEN GO TO OPEN TO OPEN FILES.
AND READ SYSIN AT
GETSYSIN, SKIPS BLANKS IN COL-1 (54), "*" COMMENTS,
LOC 000000. ETC, AND TESTS KEYWORDS=
GETR8 IS CALLED TO SET UP BREAK= (AND A=), LIST=, AND OPCODE=
ZZ= EODAD FOR SYSIN.
LIST THE MAIN TABLE
SORT IT, SET UP TRT-TABLE FOR FIRST CHARACTER OF LABELS,
AND LIST IT AGAIN
THEN SAVE OPCODES IN THE TABLE AND LIST IT AGAIN.
GETIN CALLS READIN TO READ THE PRN FILE AND THROW RECORDS AWAY.
CHECK THE TABLE AND CALL ...
FOUND TO FORMAT THE OUTPUT BREAK/LIST RECORD.
Z=END OF PRN FILE,
PRINT TOTALS INCLUDING WHICH LABELS WERE AND WERE NOT FOUND.
CLOSE FILES, FREEMAIN, EXIT.
.START ANOP
* ---------------------------------
MACRO
&LBL ERR &BC,&MSG
LCLA &N
&L SETC 'SYS&SYSNDX'
&LBL REVB &BC,&L.Z
BAL R14,ERR
DC AL1(L'&L.M-1)
&L.M DC C&MSG
&L.Z DS 0H
MEND
* ---------------------------------
MACRO
&LBL $$LA ®,&FLD
LCLC &F,&G,&H
&F SETC ' &FLD(1)'
&G SETC '&FLD(1,1)'
&H SETC '&FLD'(1,1)
MNOTE ,'FLD(1,1) (2) IN THIS CASE, = &FLD(1,1) &F &G &H'
AIF ('&H.' NE '(').A
&LBL LA ®,0&FLD
MEXIT
.A ANOP
&LBL LA ®,&FLD
MEND
* ------------------------------------
MACRO
&LABEL REVB &COND,&TO
LCLC &C,&B
LCLA &LEN
AIF ('&COND' NE 'B').ADDREM
&LABEL NOP &TO
MEXIT
.ADDREM ANOP
&LEN SETA K'&COND
AIF ('&COND'(2,1) NE 'N').ADD
&B SETC '&COND'(3,&LEN-2)
AGO .DOIT
.ADD ANOP
&B SETC '&COND'(2,&LEN-1)
&B SETC 'N&B'
.DOIT ANOP
&LABEL B&B &TO
MEND
* -----------------------------------------------------------
MACRO
&LABEL BUBBLE &FIRST=,&END=,&ENTLEN=,&KEY=,&KEYLEN=
&LABEL $$LA 1,&FIRST
LCLC &SYS
LCLA &K
&K SETA &KEY
&SYS SETC 'SYS&SYSNDX.'
$$LA 15,&ENTLEN
$$LA 0,&END
LR 14,0
SR 0,15
ST 1,0(13)
CH 15,=H'64'
BH *+8
LA 14,8(13)
&SYS.C CLC &K.(&KEYLEN,1),&ENTLEN+&K.(1)
BNH *+22
MVC 0(&ENTLEN,14),0(1)
MVC 0(&ENTLEN,1),&ENTLEN.(1)
MVC &ENTLEN.(&ENTLEN.,1),0(14)
LA 1,&ENTLEN.(1)
CR 1,0
BL &SYS.C
SR 0,15
L 1,0(13)
CR 1,0
BL &SYS.C
MEND
* -----------------------------------------------------------
* DOESN'T WORK. DON'T KNOW WHY. BUBBLE DOES WORK.
*
.*
.* THE SELSORT IS ABOUT THE SAME LENGTH AS THE BUBBLE SORT,
.* HOWEVER, EACH MOVE PUTS AN ENTRY INTO IT'S FINAL POSITION,
.* SO FEWER ENTRY SWAPS ARE DONE, THUS IT'S FASTER.
.* "AND" IT HAS THE SAME BENEFIT OF KEEPING DUPLICATE KEYS
.* IN THEIR SAME RELATIVE POSITIONS. (YES, I JUST WROTE IT.)
.*
.* WRITING A SELSORT, ONE CAN EITHER MOVE THE LOWEST ENTRY TO
.* THE TOP, OR HIGHEST TO THE BOTTOM. THEY'RE EQUALLY EFFICIENT.
.*
.* MACRO
.* &LABEL SELSORT &FIRST=,&END=,&ENTLEN=,&KEY=,&KEYLEN=
.* LCLC &SYS
.* LCLA &K,&KL,&EL
.* &L SETC 'SYS&SYSNDX'
.* &K SETA &KEY
.* &KL SETA &KEYLEN
.* &EL SETA &ENTLEN
.* &SYS SETC 'SYS&SYSNDX.'
.* &LABEL $$LA 0,&END
.* LA 15,&ENTLEN
.* AIF (T'&ENTLEN EQ 'N').A
.* MNOTE 12,'ENTLEN=## MUST BE A DISCRETE #, NOT REG OR LABEL'
.* MEXIT
.* .A AIF (T'&KEYLEN EQ 'N').B
.* MNOTE 12,'ENTLEN=## MUST BE A DISCRETE #, NOT REG OR LABEL'
.* MEXIT
.* .B AIF (T'&KEY EQ 'N').C
.* MNOTE 12,'KEY=## MUST BE A DISCRETE #, NOT REG OR LABEL'
.* MEXIT
.* .C ANOP
.* $$LA 1,&FIRST
.* STM 15,1,8(13) <---- ENTLEN, END, BEGINNING
.* S 0,12(13)
.* AIF (&EL GT 52).LAST
.* LA 14,20(13)
.* AGO .LOAD2
.* .LAST $$LA 14,&END
.* .LOAD2 ANOP
.* &L.A LA 15,&EL.(1)
.* &L.C CLC &KEY.(&KL,1),&K.(15)
.* BL *+6
.* LR 1,15
.* LA 15,&EL.(15)
.* CR 15,0
.* BNH &L.C
.* CR 1,15
.* BE *+22
.* MVC 0(&EL,14),0(1)
.* MVC 0(&EL,15),0(1)
.* MVC 0(&EL,1),0(14)
.* L 1,16(13)
.* S 0,12(13)
.* CR 1,0
.* BL &L.A
.* AIF (&ENTLEN LT 53).Z
.* MVI 0(14),X'FF'
.* MVC A(&ENTLEN-1,14),0(14)
.* .Z MEND
* -----------------------------------------------------------
MACRO
&LBL $ &TEXT
LCLA &N
LCLC &L
&L SETC 'SYS&SYSNDX'
&N SETA K'&TEXT-3
&LBL DC AL1(&N),C&TEXT
&L EQU *
MEND
* ---------------------------------
ZX START 0
USING *,12,11
YREGS
B BEG-ZX+2(15)
*
IDMSG DC C'ZX V02.23 ASM &SYSTIME &SYSDATE'
BEG DC H'-1'
STM 14,12,12(13)
LR 12,15
LA 11,4095
LA 11,1(12,11) INIT DONE.
L 1,0(1)
CLI 1(R1),0
BE *+10
MVC LGETMAIN+3(1),2(R1)
L R2,LGETMAIN
N R2,=F'15'
SLL R2,12
SH R2,=H'42'
ST R2,LGETMAIN
LR R0,R2
LR R3,R13 SAVE CALLER'S R13
GETMAIN R,LV=(0)
ST R1,AGETMAIN
LR R14,R1
LA R15,2
MVI 0(R14),C' '
CLEAR2 LA R0,5
CLEAR6 MVC 1(256,R14),0(R14)
LA R14,256(R14)
BCT R0,CLEAR6
MVI 0(R14),0
LA R0,7
BCT R15,CLEAR6
* ------------------------------------
LR R13,R1
ST R3,4(R13)
ST R13,8(R3)
USING SAVEAREA,13
LA R14,0(R1,R2)
SH R14,=H'128'
ST R14,EGETMAIN
ST R14,ETABLE
LA R15,TABLE
ST R15,ATABLE
ST R15,ETABLE
ST R15,LAST
ST R15,LAST+4
* ------------------------------------
MVI FINDSPAC+C' ',C' '
MVI FINDCHAR+C' ',0
MVC TESTHEX+C'A'(60),TESTHEXI
*
MVI FINDEND+C' ',1
MVI FINDEND+C',',2
MVI FINDEND+C'*',3
MVI FINDEND+C'+',4
MVI FINDEND+C'-',5
* MVC ATLINEI(17),INITATL A FF000.+12345.
MVC LINE-5(5),=X'0040000040'
MVC ATLINE-5(5),=X'0040000040'
** MVC CARD-5(5),=X'0054000040'
B OPEN
INITATL DC C'A F0123.+12345. '
TESTHEXI DC 6X'00',41C' ',10X'00',6C' '
* ------------------------------------
PUSH PRINT
PRINT NOGEN
USING IHADCB,2
OPENMSG DC C'........ OPENED FOR OUTPUT, RECFM= LRECL=..... '
OPENSYSP MVC OPENMSG(8),DCBDDNAM
OPEN ((2),OUTPUT)
MVC LINE(L'IDMSG),IDMSG
PUT SYSPRINT,LINE-1
MVC LINE,LINE-1
B OPENM
OPENO MVC OPENMSG(8),DCBDDNAM
MVC OPENMSG+20(3),=C'OUT'
OPEN ((2),OUTPUT)
B OPENM
OPENI MVC OPENMSG(8),DCBDDNAM
MVC OPENMSG+20(3),=C' IN'
OPEN ((2),INPUT)
OPENM UNPK OPENMSG+34(3),DCBRECFM(2)
TR OPENMSG+34(2),HEX-240
MVI OPENMSG+36,C' '
LH R0,DCBLRECL
CVD R0,16(13)
OI 23(13),X'0F'
UNPK OPENMSG+43(5),21(3,13)
NOTSYSP MVC LINE(L'OPENMSG),OPENMSG
BAL R10,PUTLINE
BR R9
DROP 2
POP PRINT
* ------------------------------------
* ========================= COMMON WRITE ROUTINES ===============
*
* PUTBADDR DC CL20' ' THIS PREVENTS DUPLICATE BREAK
* PUTBREAK CLC PUTBADDR,LINE POINT LOCATIONS, WHEN A LABEL
* BER R9 IS FOUND ON A LABEL + CODE.
* MVC PUTBADDR,LINE
* PUTBREAP PUT OUT,LINE
* ** B PUTLINE
WTOATLIN MVC LINE,ATLINE
WTOLINE WTO MF=(E,LINE-5)
B PUTLINE
*
PUTATLIN MVC LINE,ATLINE
PUTOUT CLC LINE(33),SPACES
BE PUTLINE
PUT OUT,LINE
B PUTLINE
*
PUTCARD MVC LINE(80),CARD
* PUTLINE CLC LINE(44),SPACES
* BNE PUTLINEP
* MVC LINE+2(20),0(R3)
* MVC LINE+24(40),53(R3)
PUTLINE PUT SYSPRINT,LINE-1
MVC LINE,LINE-1
BR R10
*
* MVI LINE+5,C'-'
* MVC LINE+6(55),LINE+5
* LR R0,R10
* SR R0,R12
* ST R0,12(R13)
* UNPK LINE+33(5),14(3,R13)
* TR LINE+33(4),HEX-240
* MVI LINE+37,C'-'
* MVC LINE+17(16),=C'BLANK LINE FROM '
* MVC LINE+40(6),0(R3)
* PUTLINEP PUT SYSPRINT,LINE-1
* MVC LINE,LINE-1
* BR R10
* ============================================
* ERROR ROUTINE CAN BE USED FROM SEVERAL TESTS.
* IT LISTS THE PROGRAM LOCATION, ALONG WITH THE ERROR MSG.
* -------------------------------------------------
DC F'0'
ERR LA R1,0(R14)
ST R1,ERR-4
STM R14,R1,DW
TM DCBOFLGS-IHADCB+SYSPRINT,DCBOFOPN
BO ERRA
LA R2,SYSPRINT
BAL R9,OPENSYSP
LM R14,R1,DW
ERRA STM R14,R1,DW
SR R1,R12
ST R1,12(R13)
UNPK ERRMSG+13(5),14(3,R13)
TR ERRMSG+13(4),HEX-240
MVI ERRMSG+17,C' '
MVC LINE+1(L'ERRMSG),ERRMSG
CLI LINE+19,C'$'
BNE *+8
MVI LINE+19,C' '
SR R2,R2
IC R2,0(R14)
MVC LINE+1+L'ERRMSG(0),1(R14)
EX R2,*-6
ERR$ L R14,ERR-4
CLI 1(R14),C'$'
BNE ERRWRITE
ERR$$$ LA R15,LINE+5+L'ERRMSG(R2) LABEL FOR TESTING
MVC 0(40,R15),CARD
ERRWRITE WTO MF=(E,LINE-5)
OI RC,12
SP ERR#,P1
BP GETSYSIN
BAL R9,PRINTDOC
ERRABEND ABEND 1
ERRMSG DC C'SYSIN ERR AT .... '
ERR# DC P'9'
* ------------------------------------
SAVINSTL LA R5,INSTLEN+1 INSTLEN=
B SAVLISTL+4
SAVLISTL LA R5,LISTLEN+1 LISTLEN=
CLI CARD+8,C'0'
ERR BL,'$BAD LENGTH REQUEST'
TRT CARD+8(4),FINDEND
ERR BZ,'$LEN REQ TOO LONG'
LR R2,R1
S R2,=A(CARD+9)
MVC 0(0,R5),CARD+8
EX R2,*-6
B GETSYSIN
* ------------------------------------
SAVLOADL MVC CARD+4(4),SPACES LOADLOC=9R% <== +9
MVC LOADLOC(6),CARD+6
CLC =C'R%',CARD+9
BE SAVLOADM
MVC LOADLOC(6),CARD+7 LOADLOC=11R% LOADL00011R%
CLC =C'R%',CARD+10 LOADLO..11R%
BE SAVLOADM
MVC LOADLOC(5),CARD+8
MVI LOADLOC+5,C'.' LOADLOC=FF000
SAVLOADM MVC LINE+16(8),=C'LOADLOC='
MVC LINE+16+8(6),LOADLOC
MVI LINE+16+8+6,C'+'
BAL R10,PUTLINE
B GETSYSIN
* ===================================== OPEN======================-
OPEN LA R2,SYSPRINT
BAL R9,OPENSYSP
LA R2,SYSIN
BAL R9,OPENI
LA R2,IN THESE ARE THE FILE OPEN ROUTINES.
BAL R9,OPENI ONCE DONE, WE COULD USE THIS AREA
LA R2,OUT FOR WORK AREAS.
BAL R9,OPENO
LA R8,TABLE
ST R8,BEGLABEL
* ========================FALL THROUGH TO READ
GETSYSIN GET SYSIN
MVC CARD(80),0(R1)
GOTSYSIN CLI CARD,C' '
BE GETSYSIN SKIP BLANKS
MVC LINE(80),CARD
* -----------------------------------
WTO MF=(E,LINE-5)
CLC =C'LOADLOC=',CARD
BE SAVLOADL
BAL R10,PUTLINE
CLC =C'INSTLEN=',CARD
BE SAVINSTL
CLC =C'LISTLEN=',CARD
BE SAVLISTL
CLI CARD,C'O' =C'OPCODE=',CARD
BE SAVEOPCD
CLI CARD,C'B' =C'BREAK=',CARD
BE GETR8+4
CLI CARD,C'A' AT=
BE GETR8+4
CLI CARD,C'L' =C'LIST=',CARD
BE GETR8+4
CLC =C'STOPLOC=',CARD
BE SETSTOPA
CLC =C'STOP#=',CARD
BE SETSTOP#
ZAP ERR#,P0
ERR B,'$UNKNOWN CONTROL CARD INPUT'
EX 0,*
*
SAVEOPCD CLI RECORD+1,C' '
ERR BNE,'$CAN ONLY HAVE 1 SINGLE OPCODE= COMMAND'
MVC RECORD+1(80),CARD
B GETSYSIN
*
SETSTOPA MVC STOPLOC,CARD+8
B GETSYSIN
SETSTOP# MVC CARD,CARD+7
BAL R14,GET##
MVC REC#+4,DW+4
B GETSYSIN
*
PACK DW,CARD(0)
GET## CLI CARD,C'0'
BL GET##X
LA R1,CARD
LA R1,1(R1)
CLI 0(R1),C'0'
BNL *-8
CLI 0(R1),C' '
BNE GET##X
S R1,=A(CARD+1)
EX R1,GET##-6
CVB R0,DW
BR R14
GET##X ERR B,'$BAD NUMERIC REQUEST'
* -----------------------------------
* WE'RE GOING TO LOAD THE ENTIRE LINE OF BREAK= OR LIST= ENTRIES
* -----------------------------------
SETLIST MVC CARD,CARD+5 LIST=LABEL,LABEL
MVI TYPE,C'L'
B GETR8
*
SETBREAK MVC CARD,CARD+6 BREAK=LABEL,LABEL+.0C
MVI TYPE,C'A'
B GETR8
* -----------------------------------
DC A(GETSYSIN)
GETR8 ST R14,GETR8-4
CLI CARD,C'A'
BE GETR8TRT
CLI CARD,C'L'
BE GETR8TRT
CLI CARD,C'B'
BE GETR8TRT-4
CLI CARD,C'O'
BE GETR8TRT
CLI CARD,C'Z'
BE GETR8TRT
GETR8BAD ERR B,'$BAD SYSIN KEY= RECORD'
*
MVI CARD,C'A'
GETR8TRT MVC TYPE,CARD
TRT CARD(8),FINDEQ
BZ GETR8BAD
MVC CARD,1(R1)
*
GETR8TOP L R8,LAST
PUT SYSPRINT,CARD-1
USING DSECT,R8
MVC 0(LDSECT,R8),DSECTINI
*
LA R0,LDSECT(R8)
ST R0,LAST
C R0,EGETMAIN
MVC 0(R6,R8),SPACES
ERR BNL,'$TABLE OVERFLOW'
TRT CARD(12),FINDEND
ERR BZ,'$UNKNOWN ERR LOOKING FOR END OF LABEL'
*
STC 2,INDEX
*
LR R2,R1
S R2,=A(CARD)
STH R2,DSTRLEN
BCTR R2,0
CH R2,=AL2(L'STRING-1)
ERR BH,'$BREAK=????? TOO LONG'
MVC DSTRING(0),CARD
EX R2,*-6
*
LA R15,DSTRING+1(R2)
MVI 0(R15),C' '
*
CLI INDEX,3
BL GETR8YR1
*
BH GETPM
STH R2,DSTRLEN
LA R1,1(R1)
B GETR8YR1
*
GETPM CLI TYPE,C'L'
ERR BE,'$CANNOT HAVE LABEL+/-.0C ON LIST='
*
MVC CARD,0(R1)
TRT CARD+1(4),FINDEND
ERR BZ,'$BREAK=LABEL+.0C TOO LONG'
LR R2,R1
S R2,=A(CARD+1)
MVC DADDLOC(0),CARD
EX R2,*-6
B GETR8YR1
*
GETR8YR1 MVC CARD,1(R1)
GETR8Z CLI CARD,C' '
BNE GETR8TOP
L R14,GETR8-4
LA R0,GETSYSIN
ST R0,GETR8-4
BR R14
* -----------------------------------
LISTMEM MVC LINE,LINE-1
PUT SYSPRINT,LINE-1
MVC LISTMEMM+16(7),=C' BYTES '
LA R2,2
L R3,LAST
S R3,ATABLE
L R4,EGETMAIN
S R4,ATABLE
B MEMCVD
*
LISTMEML MVC LISTMEMM+16(7),=C'ENTRIES'
SR R0,R0
LR R1,R3
D R0,=A(LDSECT)
LR R3,R1
SR R0,R0
LR R1,R4
D R0,=A(LDSECT)
LR R4,R1
*
MEMCVD CVD R3,16(R13)
CVD R4,24(R13)
MVC LINE(L'ED5),ED5
ED LINE(L'ED5),21(R13)
MVC LINE+2+L'ED5(2),=C'OF'
MVC LINE+4+L'ED5(L'ED5),ED5
ED LINE+4+L'ED5(L'ED5),29(R13)
MVC LINE+6+L'ED5+L'ED5(L'LISTMEMM),LISTMEMM
PUT SYSPRINT,LINE-1
MVC LINE,LINE-1
BCT R2,LISTMEML
PUT SYSPRINT,LINE-1
BR R9
*
LISTMEMM DC C'AVAILABLE TABLE BYTES USED'
ED5 DC X'4020206B202120'
LTORG
*
* -------------------------------------------------
LISTABLE LA R8,TABLE
LA R0,22
LISTLOOP MVC LINE,LINE-1
MVC LINE(1),DTYPE
MVC LINE+3(6),=C'" "'
MVC LINE+04(4),DLISTLEN
MVC LINE+14(6),=C'" "'
MVC LINE+15(4),DINSTLEN
MVC LINE+24(6),=C'" "'
MVC LINE+25(4),DADDLOC
LH R1,DSTRLEN
CR R1,R0
BL *+6
LR R1,R0
STC R1,LINE+31
OI LINE+31,C'0'
MVC LINE+33(0),DSTRING
EX R1,*-6
BAL R10,PUTLINE
* PUT SYSPRINT,LINE-1
* MVC LINE,LINE-1
*
LA R8,LDSECT(R8)
C R8,LAST
BL LISTLOOP
PUT SYSPRINT,LINE-1
BR R9
*
SORT LA R2,TABLE
L R3,LAST
*
BUBBLE FIRST=(R2),END=(R3),ENTLEN=64,KEY=40,KEYLEN=23
BR R9
*
*
ZZEND MVC CARD,SPACES
MVC CARD(4),=C'Z=99'
BAL R14,GETR8
BR R9
*
ZZ BAL R9,LISTABLE
BAL R9,LISTMEM
BAL R9,SORT
BAL R9,LISTABLE
*
L R8,LAST
ST R8,ENDLABEL
BAL R9,ZZEND
*
CLI RECORD+1,C' '
BE NOOPCODS
MVC CARD(80),RECORD+1
MVC RECORD,SPACES
L R8,LAST
ST R8,BEGOPCDE
BAL R14,GETR8
L R8,LAST
ST R8,ENDOPCDE
BAL R9,ZZEND
BAL R9,LISTABLE
BAL R9,LISTMEM
*
NOOPCODS DS 0H
* * MVC DSTRLEN,H2
* * MVC DSTRING,SPACES
* * MVI DSTRING,C'.'
* * LA R0,LDSECT+R8
* * ST R0,LAST
* *
* BAL R9,LISTMEM
* BAL R9,LISTABLE
* ** BAL R9,LISTOPC
* LA R2,TABLE
* L R3,LAST
* LA R4,DSTRING-DSECT
* LA R5,L'DSTRING
* * SELSORT FIRST=(R2),END=(R3),ENTLEN=32,KEY=15,KEYLEN=17
* ** ENTLEN=LDSECT,KEY=DSTRING-DSECT,KEYLEN=L'DSTRING
* *
* * B BUBBLE FIRST=(R2),END=(R3),ENTLEN=64,KEY=42,KEYLEN=23
* ** ENTLEN=LDSECT,KEY=DSTRING-DSECT,KEYLEN=L'DSTRING
*
SR R1,R1
SR R15,R15
L R8,BEGLABEL
LA R2,SPACES
SETLOC LA R1,1(R1)
CLC DSTRING(1),0(R2)
BE SETLOCN
*
LA R2,DSTRING
IC R15,DSTRING
LA R14,LBLTBL(R15)
CLI 0(R14),0
BNE *+8
STC R1,0(R14)
*
SETLOCN LA R8,LDSECT(R8)
C R8,ENDLABEL
BL SETLOC
BAL R9,READIN
B GETIN
*
REL DC X'E985D340'
DC F'0'
READIN ST R9,READIN-4
READIGET GET IN
* CLI 53(R1),C'A'
* BNE READIN
AP #RECREAD,P1
CLC =C'LISTUSE',0(R1)
BE READIGET
LA R3,0(R1)
AP REC#,P1
CP REC#,REC#+4
BNE *+8
BAL R15,S0C3
CLI 53(R3),C'*'
BE READIGET
*
CLI 0(R3),C'0' Q. LOCATION?
BNE READIGET
CLC =C'000000',0(R3) Q. DUMB FIRST RECORDS?
BNE READCHKL
CP #RECTSTD,P1
BL READIGET
*
* CLI 53(R3),C' '
* BE READIGET
*
TRT 53(16,R3),FINDSPAC END OF LABEL
BZ READIGET
LR R15,R1
TRT 0(15,R15),FINDCHAR START OF OPCODE
CLC =C'DSECT ',0(R1)
BNE READCHKL
MVI DSECTFLG,C'D'
*
READCHKL CLI 53(R3),C' '
BNE CHECKREL
CLI BEG,0
BE CHECKREL
*
TRT 53(44,R3),FINDSPAC
BZ READIGET
TRT 0(44,R1),FINDCHAR
BZ READIGET
LR R2,R1
*
MVC OPCODE,0(R2)
BAL R14,TESTOPC
BZ CHECKDC
LR R8,R1
* LA R0,1
* AH R0,DCOUNT
* STH R0,DCOUNT
B FOUND
*
CHECKDC CLC =C'DC ',0(R2)
BE READIGET
CLC =C'DS ',0(R2)
BE READIGET
*
CHECKREL CLC REL,0(R3)
BE Z
CLC =C'SYM=',1(R3) Q. IN CASE WE MISSED END?
BE Z YES, EOF OF //PRN
READSAVE MVC RECORD,NEXTREC
MVC NEXTREC,0(R3)
CLC RECORD(6),NEXTREC
BE READIGET
LA R3,RECORD
LA R4,53(R3)
CLI STOPLOC,C' '
BE READINZ
*
LA R14,STOPLOC-7
STOPLOOP LA R14,7(R14)
CLI 0(R14),C' '
BE READINZ
CLC 0(6,R14),0(R3)
BNE STOPLOOP
BAL R15,S0C3
RESTART LA R3,RECORD
LA R4,53(R3)
READINZ L R9,READIN-4
BR R9
*
S0C3 EX 0,*
BR R15
* -----------------------------------------
*
GETIN BAL R9,READIN
GOTPRN SR R2,R2
AP #RECTSTD,P1
*
* HERE WE'RE GOING TO SAVE THE LABEL, OPCODE, AND 2 BYTES OF OPERAND
* JUST MAKES PROCESSING EASIER.
*
* --------------------------------------
SAVLABEL LA R14,LBOPOPER
MVC LBOPOPER,SPACES
LA R1,53(R3)
LA R0,8
CLI 0(R1),C' '
BE TRTOPC
* BUT WE'LL ONLY SAVE 10
LR R15,R1
TRT 0(22,R15),FINDSPAC <======= FIND END OF LABEL
LR R2,R1
SR R2,R15
CR R2,R0
BL *+6
LR R2,R0
MVC LABEL(0),0(R15) SAVE LABEL
EX R2,*-6
*
TRTOPC LR R15,R1
TRT 0(54,R15),FINDCHAR <======= FIND OPCODE
BZ GETIN
LR R15,R1 SAVE OPC ADDR
TRT 0(16,R15),FINDSPAC <=== FIND END OF OPCODE
LR R2,R1
SR R2,R15
CR R2,R0 CALC LENGTH OF OPCODE
BL *+6
LR R2,R0 SET MAX LENGTH
MVC OPCODE(0),0(R15) <===== SAVE OPCODE
EX R2,*-6
* -----------------------------------------
CLI BEG,0
BNE GETOPER
STM R14,R8,12(R13)
BAL R14,TESTOPC
BNZ FOUND
LM R14,R8,12(R13)
* -----------------------------------------
*
GETOPER CLI LABEL,C' '
BE GETIN
LR R15,R1
*
TRT 0(54,R1),FINDCHAR <======= SAVE OPERAND
BZ GETIN
LR R15,R1
LA R1,8(R15)
TRT 0(9,R15),FINDSPAC LOOK FOR SPAC, BUT IF NOT FOUND
LR R2,R1 WE'RE ALREADY GOT OK LENGTH
SR R2,R15
CR R2,R0
BL *+6
LR R2,R0
MVC OPERAND(0),0(R15)
EX R2,*-6
*
L R8,BEGLABEL
SR R2,R2 CALC LOCATION IN LABEL TABLE
TRT LABEL(1),LBLTBL TO START SEARCHING.
BZ GETIN FIRST CHAR MUST MATCH
LR R7,R2 IF NOT, GO CHECK OPCODE TABLE
LR R1,R2 IF NOT, GO CHECK OPCODE TABLE
*
SLL R7,6
*
L R8,BEGLABEL
S R7,=A(LDSECT)
AR R8,R7
*
AP #LBLSTST,P1
*
CLC =C'ED',OPCODE
BNE CHKLBL
BAL R14,TESTOPC
BZ CHKLBL
LR R8,R1
B FOUND
*
CHKLBL LH R2,DSTRLEN
EX R2,CLCSTR
BE FOUND
LA R8,LDSECT(R8)
C R8,ENDLABEL
BNL GETIN
CLC DSTRING(1),LABEL
BE CHKLBL
B GETIN
CLCSTR CLC DSTRING(0),LABEL
*
* QOPCODE BAL R14,TESTOPC
* BNZ FOUND
* B GETIN
*
*
* -------------------------------------------
* OKAY, GOT THE LABEL, SEE IF IT'S IN THE TABLE.
* IF NOT, GO READ
* IF YES, SET UP THE COMMAND,
* AND DETERMINE IF IT'S DATA OR INSTRUCTION.
* -------------------------------------------
* =======================
CLC DSTRING(0),LABEL
TRYMORE MVC ATLINE,SPACES
L R8,FOUND-4
LA R8,LDSECT(R8)
* ST R8,FOUND-4
C R8,LAST
BNL GETIN
LH R1,DSTRLEN
EX R1,TRYMORE-6
BNE GETIN
B FOUND
*
DC F'0'
FOUND ST R8,FOUND-4
AP #RECSOK,P1
MVC ATLINE(99),SPACES
MVC ATLINE(L'INITATL),INITATL
* MVC ATLINE+2(5),DLOADLOC
MVC ATLINE+7(2),=C'.+'
MVC ATLINE+9(5),1(R3)
MVI ATLINE+14,C'.'
MVC ATLINE+15(4),DADDLOC
MVC ATLINE+20(8),LABEL WE WRITE DATA DISPLAY TO THE
MVC ATLINE+29(5),OPCODE
LA R14,LINE+35
CLI DTYPE,C'O'
BNE SETF
LA R0,1
AH R0,DCOUNT
STH R0,DCOUNT
B SETF+4
SETF MVI DFOUND,C'F'
CLI DTYPE,C'L'
BNE INST
MVI ATLINE,C'L'
MVC ATLINE+15(4),LISTLEN
DATA BAL R10,WTOATLIN
B TRYMORE
* ==========================CHECK OPCODE=================
CLC OPCODE(0),DSTRING-DSECT(R1)
TESTOPC CLI BEGOPCDE+3,1
BE TESTOPCZ-2
CLC =C'ED',OPCODE
BNE TESTOPCZ-2
L R1,BEGOPCDE
TESTOPCL LH R15,DSTRLEN-DSECT(R1)
EX R15,TESTOPC-6
BE TESTOPCZ
LA R1,LDSECT(R1)
C R1,ENDOPCDE
BL TESTOPCL
SR R1,R1
TESTOPCZ LTR R1,R1
BR R14
*
*
* OKAY, NOW I'M CONFUSED. JUST DID THE LIST.
* NOW WE'RE GOING TO DO A BREAK
* AND THEN 1-2 LISTS FOR THE OPERAND(S)
*
* INSTRUCTION TYPES ARE: RR, RX, RS, SI, SS
*
* WE CAN DO A BREAK ON RR INSTRUCTIONS, BUT NOTHING ELSE.
* THEY DON'T HAVE ASSOCIATED MEMORY LOCATIONS.
*
* SHIFT LOGICAL/ALGEBRAIC DON'T HAVE MEMORY LOCATIONS
*
* FOR AN RX INSTRUCTION, THERE CAN BE A BASE AND AN INDEX REGISTER.
* MAKERX DOES THOSE
* FOR OTHER INSTRUCTIONS, THERE CANNOT BE AN INDEX REGISTER.
* MAKELOOP DOES ALL THE OTHERS
*
INST MVI ATLINE,C'A'
MVC ATLINE+15(4),DADDLOC ADD+/=0C.
MVC ATLINE+20(8),LABEL
*** LA R4,ATLINE+38
CLC ATLINE+15(2),SPACES IF THERE IS +/-, CANNOT DO
BNE INSTPUTA REGS, 'CAUSE DON'T HAVE INST.
CLI 7(R3),C'8' SHIFT AND BXH/BXLE INSTRUCTIONS
BE INSTPUTA NO MEMORY STUFF
CLI 7(R3),C'0'
BL INSTMAK
CLI 7(R3),C'3'
BH INSTMAK
MVC ATLINE+45(7),=C'RR INST'
MVC ATLINE+62(4),OPCODE
MVC ATLINE+68(4),7(R3)
B INSTPUTA
*
INSTMAK BAL R9,MAKELIST
INSTPUTA BAL R10,PUTATLIN
B TRYMORE
* -------------------------------------------------
MAKELIST CLI 6(R3),C' '
BNER R9
CLI 7(R3),C' '
BER R9
CLI 11(R3),C' ' Q. R-R INST
BER R9 YES, SKIP
LA R4,11(R3) FIRST RDDD STRING
CLI 8(R4),C' ' Q. STRING TOO LONG?
BNE R9 YES, SKIP IT
*
CLI 7(R3),C'4' RX INST?
BE MAKERX IF SO, CAN HAVE BASE+INDEX REGS+OFFSET
CLI 7(R3),C'5'
BE MAKERX
LA R2,11(R3)
B MAKELOOP IF NOT, JUST REG+OFFSET
*
* NOTIMMED MVC 12(2,13),3(R3) 581EF001 ADD R14+R15+001
*
* THIS ROUTINE GETS 1 OR 2 REGISTERS (BASE + INDEX_
*
*
GETAREG LA R0,2 ASSUME 2 REGS
GETAREGL CLI 0(R2),C'0' Q. REG=0
BE GETAREGZ YES, SKIP IT.
SR R1,R1
IC R1,0(R2) LOAD REG
CH R1,=H'234' A-F OR 1-0
BH *+8 1-9 FINE, A-F ADD +57 TO GET FA-FF
LA R1,57(R1)
N R1,=F'15' CLEAR HIGH BITE
SLL R1,1 * 2 = INDEX INTO THE 000102-1415
LA R1,MAKEREGS(R1) GET ADDR OF REG TABLE
MVC 0(2,R14),0(R1) COPY TO PRINT AREA
MVC 2(3,R14),=C'R%+' FIX 12 TO 12R%+
*
CLI 0(R14),C'0' Q. 08R%+
BNE *+12 NO
MVC 0(6,R14),1(R14) YES, MAKE IT 8R%+
BCTR R14,0 SUBT 1 FROM PRINT LOC
LA R14,5(R14) NEXT PRINT LOC
GETAREGZ LA R2,1(R2) NEXT REGISTER
BCT R0,GETAREGL LOOP IF BASE+INDEX
BR R7
*
MAKEREGS DC C'00010203040506070809101112131415'
* ---------------------FORMAT 13R%+8R%+123.-------------------------
MAKERX LA R2,10(R3) POINT TO BASE
LA R14,ATLINE+38 AND PRINT LOC
MVI ATLINE+36,C'L'
BAL R7,GETAREG GET BOTH REGS
MVC 0(3,R14),0(R2) AND ADD THE OFFSET
MVI 3(R14),C'.'
MVC 4(4,R14),DINSTLEN
B SHOWINST
* BR R9
*
* R2 = FROM LOCATION (A REGISTER)
* R4 = PRINT LOCATION
* R14 = PRINT LOCATION PAST "L "
*
* ---------------------ALL THIS TO GET THE REGISTER-------------
MAKELOOP LA R14,ATLINE+36
MVI 0(R14),C'L'
LA R14,2(R14)
LA R0,1
LA R2,11(R3)
BAL R7,GETAREGL
MVC 0(3,R14),0(R2)
MVI 3(R14),C'.'
MVC 4(4,R14),DINSTLEN
CLI 4(R2),C' '
BE SHOWINST
*
LA R2,15(R3)
LA R14,9(R14)
MVI 0(R14),C'L'
LA R14,2(R14)
LA R0,1
BAL R7,GETAREGL
MVC 0(3,R14),0(R2)
MVI 3(R14),C'.'
MVC 4(4,R14),DINSTLEN
*
* MVC ATLINE+62(4),OPCODE
SHOWINST MVC ATLINE+68(12),7(R3)
BR R9
* ============================================
LISTOPCD CLI BEG,0
BNER R9
LA R8,BEG+4
LISTOPM MVC LINE(8),DSTRING
LH R0,DCOUNT
LTR R0,R0
BZ LISTOPNO
CVD R0,DW
MVC LINE+9(5),=C'FOUND'
*
MVC LINE+14(L'ED5),ED5
ED LINE+14(L'ED5),DW+5
MVC LINE+16+L'ED5(5),=C'TIMES'
* UNPK LINE+32(5),DFOUND(3)
* TR LINE+32(4),HEX-240
* MVI LINE+36,C' '
B LISTOPUT
LISTOPNO MVC LINE+9(18),=C'WAS NOT FOUND/USED'
LISTOPUT BAL R10,PUTLINE
LA R8,LDSECT(R8)
C R8,BEG
BL LISTOPM
PUT SYSPRINT,LINE-1
BR R9
*
LISTFLBL LA R8,TABLE
MVC DW(16),SPACES
MVC LINE(L'DSTRING),DSTRING
CLI DFOUND,C'F'
BE LISTFF
LH R0,DCOUNT
LTR R0,R0
*
BZ LISTFNOT
** B LISTFF
CVD R0,16(R13)
OI 23(R13),X'0F'
UNPK DW(3),22(2,R13)
MVC DW+3(6),=C' TIMES'
B LISTFF
LISTFNOT MVC LINE+L'DSTRING(18),=C'WAS NOT FOUND/USED'
B *+16
LISTFF MVC LINE+L'DSTRING(09),=C'WAS FOUND'
MVC LINE+L'DSTRING+11(10),DW
BAL R10,PUTLINE
LA R8,LDSECT(R8)
C R8,LAST
BL LISTFLBL+4
PUT SYSPRINT,LINE-1
BR R9
*
* ============================================
ZDCBLIST DC A(SYSIN,OUT,IN,SYSPRINT,0)
CLOSE LA R3,ZDCBLIST
L R2,0(R3)
MVC LINE+2(5),=C'CLOSE'
BAL R10,PUTLINE
* PUT SYSPRINT,LINE-1
MVC LINE,LINE-1
CLOSETM TM DCBOFLGS-IHADCB(R2),DCBOFOPN
BZ NOCLOSE
CLOSE ((2))
CLI 6(R3),0
BZ NOCLOSE
MVC LINE+2(8),DCBDDNAM-IHADCB(R2)
MVC LINE+11(6),=C'CLOSED'
BAL R10,PUTLINE
* PUT SYSPRINT,LINE-1
NOCLOSE LA R3,4(R3)
L R2,0(R3)
LTR R2,R2
BP CLOSETM
BR R9
* -------------------------------------------------
Z MVC LINE,LINE-1
MVC LINE(11),=C'INTERACTIVE'
PUT OUT,LINE
MVC LINE,LINE-1
PUT SYSPRINT,LINE-1
BAL R9,LISTOPCD
BAL R9,LISTFLBL
BAL R9,LIST#REC
MVC LINE,LINE-1
BAL R9,CLOSE
L 13,4(13)
FREEMAIN LM R0,R1,LGETMAIN
FREEMAIN R,LV=(0),A=(1)
SR 15,15
IC 15,RC
L 14,12(13)
LM 0,12,20(13)
BR 14
* -------------------------------------------------
LTORG
DC 10C'XYZ'
REC# DC PL4'0',PL4'89999999'
ATABLE DC 2A(0)
ETABLE DC A(0)
LTABLE EQU LDSECT
*
BEGLABEL DC A(0)
ENDLABEL DC A(0)
BEGOPCDE DC A(1)
ENDOPCDE DC A(0)
*
LAST DS 2F'0'
LGETMAIN DC F'2'
AGETMAIN DC F'0'
EGETMAIN DC F'0'
INDEX DC 2C' '
DSECTFLG DC C' '
RC DC X'00'
P0 DC X'0C'
P1 DC X'1C'
H0 DC H'0'
H1 DC H'1'
H2 DC H'2'
H9 DC H'9'
DW DC 2D'0'
HEX DC C'0123456789ABCDEF '
* ---------------------------------
DSECTINI DC CL64' '
ORG DSECTINI
DC C'A '
LOADLOC DC CL5'FF000',C'.+'
LISTLOC DS CL5'12345',C'.'
MORE DS CL4 +/-0C.
DS CL1
ADDLOC DS CL4 +0C.
LISTLEN DS CL4 LENGTH FOR L COMMAND
INSTLEN DS CL4 LENGTH FOR AT OPERAND(S)
STRLEN DC HL2'0' LENGTH OF STRING
COUNT DC HL2'0' # TIMES OPCODE FOUND
FOUNDF DS C STRING FOUND FLAG
DS C
TYPE DS C DATA TYPE A/L/O
DS C
STRING DS CL24 LABEL STRING
LDSECTIN EQU *-DSECTINI
* = LDSECT
* ---------------------------------
DC H'64,0',C' '
CARD DC CL80' ',CL253' '
#RECREAD DC PL4'0'
$ 'LISTING RECORDS READ'
#RECTSTD DC PL4'0'
$ 'LISTING RECORDS TESTED'
#LBLSTST DC PL4'0'
$ 'LABELS TESTED'
#RECSOK DC PL4'0'
$ 'LIST/BREAK RECORDS WRITTEN TO OUT'
DC X'FF'
LIST#REC LA R2,#RECREAD
SR R3,R3
LIST#RM MVC LINE(L'ED4),ED4
ED LINE(L'ED4),0(R2)
IC R3,4(R2)
MVC LINE+L'ED4+2(0),5(R2)
EX R3,*-6
BAL R10,PUTLINE
LA R2,6(R2,R3)
CLI 0(R2),C'9'
BL LIST#RM
BR R9
ED4 DC X'40202020206B212020'
* -------------------------------
PUSH PRINT
PRINT NOGEN
DS 0D
IN DCB DDNAME=IN,DSORG=PS,MACRF=GL,RECFM=FT,LRECL=366,EODAD=Z
OUT DCB DDNAME=OUT,DSORG=PS,MACRF=PM,RECFM=FT,LRECL=80
SYSIN DCB DDNAME=SYSIN,DSORG=PS,MACRF=GL,RECFM=FT,LRECL=80,EODAD=ZZ
SYSPRINT DCB DDNAME=SYSPRINT,DSORG=PS,MACRF=PM,RECFM=FT,LRECL=133
POP PRINT
* -------------------------------------------------
*
* AGO .NODOC
MVC LINE+2(0),1(R2)
PRINTDOC LA R2,DOC
SR R3,R3
MVC LINE,LINE-1
PUT SYSPRINT,LINE-1
PRINTLOP IC R3,0(R2)
EX R3,PRINTDOC-6
BAL R10,PUTLINE
PRINTDO# LA R2,2(R2,R3)
CLI 0(R2),99
BL PRINTLOP
B ERRABEND
DOC $ 'PROBABLE SYSIN KEYWORD ERROR'
$ '.'
$ 'PARM CAN BE 1 # CHAR FOR LENGTH * 4K OF GETMAIN. DEFAULT="2" (8K)'
$ '.'
$ 'SYSIN KEYWORDS ARE'
$ 'LOADLOC= 80000, FF000, 4R%, 13R% (REQUIRED)'
$ 'LISTLEN=32 LENGTH OF LIST=LABEL DISPLAY'
$ 'INSTLEN=32 LENGTH OF INST OPERAND DISPLAY'
$ 'LIST=LABEL, GENERATE LIST COMMANDS FOR THESE (CAN BE IN DSECT)'
$ 'BREAK=LABEL,LABEL PLACES TO SET BREAK POINTS'
$ 'AT= IS THE SAME AS BREAK='
$ 'OPCODE=OPCODE,OOPCODE,OPCODE (ALL IN 1 RECORD ONLY)'
$ 'STOPLOC= LISTING LOC TO ABEND S0C3'
$ 'STOP#= PRN RECORD # TO ABEND S0C3'
$ '.'
$ 'USER MUST PUT LABELS AFTER THE CORRECT LOADLOC LOCATIONS/REGISTERS'
DC X'FF'
* .NODOC ANOP
* -------------------------------------
* UNFORTUNATELY, GONE OVER 4K. THAT'S THE WAY IT GOES.
* -------------------------------------
@@PAD#0 EQU *-ZX+4095
@@PAD#1 EQU @@PAD#0/(4097)
@@PAD#2 EQU (@@PAD#1*4096)
ORG ZX+@@PAD#2
*
SAVEAREA DSECT 0
DS XL768
ORG SAVEAREA
DS XL72
*
LBOPOPER DS 0CL36
LABEL DS CL12
OPCODE DS CL12
OPERAND DS CL12
DS XL5
LINE DS CL133
DS CL5
ATLINE DS CL80,CL53
RECORD DS CL80
NEXTREC DS CL80
STOPLOC DS CL80
* ------------------ TABLES BELOW ARE MOSTLY SPACES
ORG
FINDOPC DS XL256
FINDCHAR DS XL256
TESTHEX DS XL256
SPACES EQU FINDCHAR+66
ZEROS EQU FINDSPAC+66
* ------------------ TABLES BELOW ARE MOSTLY ZEROS
OPCDTBL DS XL256
LBLTBL DS XL256 THE FIRST CHAR OF EACH LABEL IS KEPT,
FINDCOMA EQU *+C' '-C','
FINDEQ EQU *+C' '-C'='
FINDSPAC DS XL256
FINDEND DS XL256
DS 0D
TABLE DS XL64
*
DSECT DSECT 0
DS CL2 'A '
DLOADLOC DS CL5,CL2 'FF000',C'.+'
DLISTLOC DS CL5,CL1 '12345',C'.'
DMORE DS CL4 +0C.
DS CL1
DADDLOC DS CL4 LABEL+0C.
DLISTLEN DS CL4 LABEL 32
DINSTLEN DS CL4 LABEL 32
DSTRLEN DS H 05
DCOUNT DS H
DFOUND DS C FLAG TO SAY IT WAS USED.
DS C
DTYPE DS C A/L
DS C
DSORTLOC EQU *-DSECT+1
DSTRING DS CL24
LDSECT EQU *-DSECT
*
* DCBD DEVD=DA
END ZX