Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat:
Objectiu de l'activitat:
Presentació de l'alfabet lletra a lletra mitjançant una barra de desplaçament.
Desenvolupament de l'activitat:
1 Obrir el calc i canvari el nom del Full1 pel de M6P1 alfabet
2. Fomatar la cel·la B5 com es veu en el gràfic de presentació.
3. Inserir un quadre de text on s'escrigui: “L'alfabet”
4. Fer servir una barra de desplaçament
i enllaçar-la a la cel·la E1 seguint els següents passos:
Ara es tracta d'enllaçar aquesta barra de desplaçament amb una cel·la determinada
5. Fer que els valors mínim i màxim de desplaçament de la barra sigui 1 i 26 respectivament.
Aquests valors de desplaçament es corresponent a les 26 lletres de l'alfabet.
7. Fer que la barra de desplaçament estigui situada i tingui el mateix o semblant format (atributs) que la que es veu en el gràfic de presentació de l'activitat.
Per modificar els atributs (colors, alçada, amplada …) de la barra de desplaçament, fer clic a la solapa General de la finestra Propietats: barra de desplaçament i provar les diferents opcions (color de fons, orientació …).
8. Escriure el valor 1 a la cel·la F1
9. Extendre el contingut de la cel·la F1 fins a la cel·la F26.
10. Escriure l'alfabet en les cel·les del rang G1:G26.
Havent fet la llista de l'alfabet, es pot aprofitar per crear una nova llista (alfabet) i així fer-la servir quan convingui sense haver d'escriure-la una altra vegada. És a dir, en escriure a una cel·la determinada la lletra a, després només exetenen la cel·la de la lletra a es pot generar la llista de l'alfabet. Per crear noves llistes es pot fer el següent:
13. Escriure a la cel·la B5:=MAJUSC(CONSULTA(E1;F1:F26;G1:G26))
14. Comprovar que l'activitat funcioni correctament fent clics als extrems de la barra de desplaçament i observant com augmenten o disminueixen el números de la cel·la E1
Perquè funcioni la barra de desplaçament, aquesta barra ha d'estar en mode de disseny desactivat
Per editar la barra de desplaçament, aquesta barra ha d'estar en mode de disseny activat
.
15. Protegir les cel·les que convingui.
16. Protegir la barra de desplaçament.
17. Fer no visibles les cel·les que convingui.
18. Desar el fitxer Modul6NomiCognom.ods
Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat:
Objectiu de l'activitat:
Escriure la lletra anterior i la posterior a partir d'un determinada lletra.
Desenvolupament de l'activitat:
1. Obrir el fitxer Modul6NomiCognom.ods i canviar el nom de Full2 pel de M6P1 alfabet escriure.
2. Escriure a la cel·la B1: =SI(A1=0;ALEATENTRE(2;25))
L'aleatori comença en 2 perquè si comencés en 1 llavors l'anterior seria 0 que no hi és a la llista de la consulta (rang H5:H30). Començant en 2, l'anterior serà l'1 que sí que hi és a la llista de la consulta. L'aleatori acaba en 25 perquè si acabés en 26 llavors el posterior mostraria el 27 que no hi és a la llista de la consulta (rang H5:H30).
3. Escriure a la cel·la H5: 1
4. Extendre la cel·la H5 fins la cel·la H30
5. Escriure a la cel·la I5 la lletra a
6. En cas que s'hagi fet la llista d'ordenació (alfabet) comentada al punt 10 de l'activitat M6P1 alfabet, llavors només caldrà extendre la cel·la I5 fins la cel·la I30 perquè es mostri la llista de l'alfabet. En cas que aquesta llista no estigui creada, caldrà torna a escriure-la o copiar-la del rang G1:G26 del full M6P1 alfabet.
7. Escriure a la cel·la D9: =CONSULTA(B1;H5:H30;I5:I30)
8. Escriure a la cel·la A9: =CONSULTA(B1-1;H5:H30;I5:I30)
Al criteri de consulta cal restar-li 1 (B1-1) per donar la possibilitat que aparegui l'1 ja que cal tenir en compte que l'aleatori comença en 2 per la raó que en la nota del punt 2 s'explica. A més, cal restar-hi perquè mostri la lletra anterior a la mostrada a la cel·la B1.
9. Escriure a la cel·la B9: =SI(C9=””;””;SI(A9=C9;”bé”;”no”))
A la cel·la C9 és on l'alumne escriu una solució
10. Escriure a la cel·la G9: =CONSULTA(B1+1;H5:H30;I5:I30)
Al criteri de consulta cal sumar-li 1 (B1+1) per donar la possibilitat que aparegui el 26 ja que cal tenir en compte que l'aleatori acaba en 25 per la raó que en la nota del punt 2 s'explica. A més, cal sumar-hi perquè mostri la lletra posterior a la mostrada a la cel·la B1.
11. Escriure a la F9: =SI(E9=””;””;SI(E9=G9;”bé”;”no”))
A la cel·la E9 és on l'alumne escriu l'altra solució
12. Formatar les cel·les C9, D9 i E9 com es veu en el gràfic de presentació de l'activitat.
13. Fer una macro amb les següent funcions:
14. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
15. Validar la cel·la A1 per al valor 0.
16. Ocultar les cel·les que convingui.
17. Protegir les cel·les que convingui.
18. Comprovar que l'activitat funcioni correctament.
19. Desar el fitxer Modul6NomiCognom.ods.
En aquesta activitat cada vegada que es faci clic a la macro “Actualitzar”, es presentarà un nou llistat de paraules en les cel·les de color taronja les quals l'alumne haurà d'ordenar alfabèticament en les cel·les de color gris. L'ordenació de les paraules s'haurà de fer sense que l'alumne faci servir l'opció d'ordenar paraules que ja inclou el calc.
Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat:
Objectiu de l'activitat:
L'objectiu d'aquesta activitat és la de treballar l'alfabet i donar suport en cercar paraules al diccionari.
Desenvolupament de l'activitat:
1. Obrir el fitxer M6
NomiCognoms.ods i canviar el nom del Full2 pel de M6P2 ordenar paraules.
2. Copiar el següent llistat de paraules a la cel·la C22:
porta
taula
cadira
llapis
goma
estoig
pissarra
bolígraf
carpeta
retolador
foli
full
guix
esborrador
finestra
porta
armari
clip
llibreta
llibre
blanc
negre
marró
rosa
blau
groc
lila
taronja
caminar
saltar
córrer
parlar
escoltar
cantar
alt
baix
gran
petit
escales
aula
mestra
jersei
camisa
sabates
jaqueta
bufanda
plat
cullera
forquilla
ganivet
En fer-ho, el llistat es veurà copiat a les cel·les del rang C22:C71
3. Escriure el número 1 a la cel·la B22 i estendre aquesta cel·la fins la cel·la B31. D'aquesta manera es farà un llistat de números de l'1 al 10. Aquesta operació caldrà repetir-la als rangs B32:B41, B42:B51, B52:B61 i B62:B71
4. Escriure a la cel·la B7: =CONSULTA(ALEATENTRE(1;10);B22:B31;C22:C31)
5. Escriure a la cel·la B8: =CONSULTA(ALEATENTRE(1;10);B32:B41;C32:C41)
6. Escriure a la cel·la B9: =CONSULTA(ALEATENTRE(1;10);B42:B51;C42:C51)
7. Escriure a la cel·la B10: =CONSULTA(ALEATENTRE(1;10);B52:B61;C52:C61)
8. Escriure a la cel·la B11: =CONSULTA(ALEATENTRE(1;10);B62:B71;C62:C71)
9. Escriure a la cel·la F6: paraules ordenades que serà la capçalera del rang B7:B11
10. Fer una macro anomeda “Actualitzar” amb les següents funcions:
11. Escriure a la cel·la F22: =C7&C8&C9&C10&C11
12. Escriure a la cel·la F23: =F7&F8&F9&F10&F11
13. Escriure a la cel·la D7: =SI(O(C7=””;C8=””;C9=””;C10=””;C11=””);””;SI(F22=F23;”bé”;”no”))
14. Fer que el format de l'activitat sigui semblant al gràfic de la presentació de la pràctica.
15. Protegir i ocultar les cel·les que convingui.
16. Comprovar que funcioni correctament l’activitat.
17. Desar el fitxer M6
NomiCognoms.ods.
Presentació gràfica de l'activitat.
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
Es tracta d'escriure amb lletra a la cel·la de color gris el número que hi ha a la cel·la B5. En fer clic a la macro, es presenta un nou número i s'esborra el que hi ha escrit a la cel·la C5. El número aleatori que hi ha a la cel·la B5 està entre el 0 i el 999.999.
Desenvolupament de l'activitat:
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P3 escriure números amb lletra.
2. Escriure a la cel·la B5: =SI(A1=0;ALEATENTRE(0;999999))
3. Assignar els següents atributs a la cel·la C5:
4. Escriure a la cel·la F5: =B5
5. Escriure a la cel·la F4: =LONG(F5)
Amb la fórmula =LONG(F5) es compta el número de caràcters de la cel·la F5, que són el número de dígits del número que es mostra a la cel·la B5.
6. Escriure a la cel·la H5: =SI(F4<6;””;VALOR(MIG(F5;F4-5;1))).
La fórmula =SI(F4<6;””;VALOR(MIG(F5;F4-5;1))) significa el següent:
En cas que el valor de F4 sigui menor que 6, llavors el contingut de la cel·la serà buit; si no, extreu de la cel·la F5 el caràcter definit per la fórmula VALOR(MIG(F5;F4-5;1).
L'F5 és el text de qual s'han de determinar les paraules parcials (contingut de la cel·la F5).
L'F4-5 és la posició des de la qual s'ha de determinar la paraula inicial (que en realitat és un número). En cas que el número que apareix a la cel·la F4 sigui el 6, llavors F4 menys 5serà 1 per la qual cosa la posició d'inici serà el primer caràcter començant per l'esquerra.
L'1 és el nombre de caràcters que cal extreure partint de la posició inicial F4-5. En cas que el número que apareix a la cel·la F4 sigui el 6, s'extrauria el valor de la centena de miler.
VALOR converteix el text en un número.
7. Escriure a la cel·la I5: =SI(F4<5;””;VALOR(MIG(F5;F4-4;1)))
8. Escriure a la cel·la J5: =SI(F4<4;””;VALOR(MIG(F5;F4-3;1)))
9. Escriure a la cel·la K5: =SI(F4<3;””;VALOR(MIG(F5;F4-2;1)))
10. Escriure a la cel·la L5: =SI(F4<2;””;VALOR(MIG(F5;F4-1;1)))
11. Escriure a la cel·la M5: =VALOR(MIG(F5;F4;1))
Els passos 7, 8, 9, 10 i 11 segueixen la mateixa dinàmica que l'explicat en la nota del pas6.
Amb el passos del 6 a l'11 s'obté la unitat (M5), la desena (L5), la centena (k5), la unitat de miler (J5), la desena de milers (I5) i la centena de miler del número que hi ha a la cel·la B10
12. Escriure a la cel·la I6: =SI(I(I5=””;J5=””);””;VALOR(I5&J5))
13. Connectar les cel·les I6 i J6
14. Escriure al rang de les ce·les H10:H18 els números del 1 al 9
15. Escriure en lletra al rang de les cel·les I10:I18 el següent:
16. Escriure al rang de les cel·les J10:J109 els números de 0 al 99
17. Escriure al rang de les cel·les K9:k109 els números amb lletra corresponents al rang J10:J109
18. Escriure a la cel·la H7: =SI(H5=””;””;CONSULTA(H5;H9:H18;I9:I18))
Amb aquesta fórmula si H5 mostra algun valor, s’obté la centena de miler fent-se la corresponent consulta; si no, no mostra cap valor.
19. Escriure a la cel·la I7:
=SI(I6=””;””;SI(I6=1;”un mil”;SI(I6=0;” mil”;CONSULTA(I6;J9:J109;K9:K109)&” mil”)))
Amb aquesta fórmula si la cel·la I6 mostra el valor de 1, retorna la paraula “mil”; si és un valor diferent de 1, es fa la corresponent consulta concatenant la paraula mil. Observar l’espai que hi ha abans de la lletra m de ” mil”.
20. Escriure a la cel·la k7: =SI(K5=””;””;SI(K5=0;””;CONSULTA(K5;H9:H18;I9:I18)))
21. Escriure a la cel·la L6: =VALOR(L5&M5)
22. Connectar les cel·les L6 i M6.
D’aquesta manera s’obté un número que representa la desena o la unitat del número que hi ha a la cel·la B5
23. Escriure a la cel·la L7: =SI(I(L5=0;M5=0);””;SI(VALOR(H5&I5&J5&K5&L5&M5)=0;”zero”;CONSULTA(L6;J10: J109;K10:K109)))
Amb SI(I(L5=0;M5=0) s'aconsegueix que es retorni l'expressió de “X cents” sempre que laX sigui major que 1 o l'expressió “cent” en cas que la X sigui 1.
24. Escriure a la cel·la G5: =RETALLA(H7&” ”&I7&” ”&K7&” ”&L7)
La funció RETALLA elimina del text els espais extres. D’aquesta manera s’obté en lletra el número que apareix a la cel·la B5.
El passos que venen a continuació, del 25 al 29, serveixen per a donar opció a escriure els números en masculí o en femení.
25. Escriure a la cel·la G6: =SUBSTITUEIX(G5;”cents”;”centes”)
26. Escriure a la cel·la G7: =SUBSTITUEIX(G6;”dos”;”dues”)
27. Escriure a la cel·la G8: =SUBSTITUEIX(G7;”un”;”una”)
28. Escriure a la cel·la G9: =SUBSTITUEIX(G5;”un”;”u”)
29. Escriure a la cel·la D5: =SI(C5=””;””;SI(O(C5=G5;C5=G8;C5=G9);”bé”;”no”))
Amb aquesta fórmula s’avalua l’escrit a la cel·la C5 si aquesta mostra algun valor. Si el que s’ha escrit a la cel·la C5 és igual a qualsevol de les cel·les G5, G8 o G9, llavors apareix l’avaluador “bé”; si no, apareix el “no”.
30. Fer una macro amb les següent funcions:
• Esborrar el contingut de la cel·la C5
• Assignar a la cel·la A1 el valor de 0
• Que la cel·la C5 rebi el focus.
31. Crear un botó (comandament) de Controls de formulari i assignar-li la macro feta anteriorment.
32. Validar la cel·la A1 per al valor 0.
33. Protegir les cel·les que convingui.
34. Fer no visibles les cel·les que convingui.
35. Comprovar que l’activitat funcioni correctament.
36. Desar el fitxer M6NomiCognoms.ods.
Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
En aquesta pràctica es tracta de fer dictats i així treballar l'escriptura de les lletres de les paraules que interessi (g,j,tx, gu, güí ….). A més de treballar l'ortografia de les paraules, també serveix per a treballar la comprensió oral en alumnes que estan aprenent el català a les aules d'acollida (alumnes nouvinguts).
Desenvolupament de l'activitat
Aquesta activitat es va fer amb Windows XP, per la qual cosa és possible que no funcioni bé amb una altra versió més nova de Windows. A continuació d'aquesta pràctica se n'explica una altra feta amb el Windows Vista.
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P4 dictats
2. Insereix | Objecte | Objecte Olé | Objectes addicionals (clic en d'acord) | Archivos de sonido (clic en aceptar).
Havent fet aquests passos, apareix una finestra anomenada “sonido, gravadora de so” i un altaveu.
3. Fent servir el micròfon i prement el botó de gravar de la gravadora, gravar el següent: El Joan llegeix un llibre.
4. Fer un clic a sobre del símbol del so i situar-lo a la cel·la B6
5. Escriure a la cel·la D6: =SI(C6=””;””;SI(C6=“El Joan llegeix un llibre.”;”bé”;”no”))
També es podria fer que la resposta sigui correcta escrivint-ho de les dues maneres. llavors la fórmula seria:
=SI(C6=””;””;SI(O(C6=“El Joan llegeix un llibre”;C6=“El Joan llegeix un llibre.”);”bé”;”no”))
6. Fer una macro amb les següent funció:
7. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
8. Situar la macro com es veu en el gràfic de l'activitat de presentació.
9. Protegir les cel·les que convingui.
10. Per protegir la posició i la mida del símbol del so es pot fer el següent.
11. Comprovar que l'activitat funcioni correctament fent elsegüent:
12. Desar el fitxer M6
NomiCognoms.ods
Presentació gràfica de l'activitat
Ilustradora: Llum Morancho
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
En aquesta activitat es tracta d'escriure la paraula que correspongui a la imatge per així treballar el vocabulari.
Dessenvolupament de l'activitat
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P5 vocabulari
2. Fer una caputra d'imatge (tecla Imp Pant Pet Sis) del gràfic de la presentació d'aquesta activitat (la cadira i la taula).
3. Obrir l'Mspaint i enganxeu la imtage (Ctrl + V)
4. Seleccionar només la imatge de la cadira mitjançant l'eina de selecció.
5. Un cop s'ahagi seleccionat la cadira, fer una còpia (Ctrl+ C)
6. Tornar a obrir l'Mspaint i enganxar la imatge de la cadira (Ctrl + V)
7. Ajustar els atributs de la imatge (amplada i alçada) per ajustar-ho a les mesures de la cadira. La imatge de la cadira té unes dimensions aproximades de 80 X 100 pixels i un tamany aproximat de 11 KB.
8. Guardar la imatge de la cadira com un fitxer amb extensió png (*.png) a la carpeta “Mis imágenes” o en una altra carpeta.
9. Escriure a la cel·la E6: =SI(D6=””;””;SI(D6=“cadira”;”bé”;”no”))
10. Fer una macro amb les següents funcions:
11. Protegir la posició i la mida de la imatge de la cadira:
12. Comprovar que l'activitat funcioni correctament de la següent manera:
13. Fer el mateix procediment per a la taula.
14. Protegir les cel·les que convingui.
15. Dear el fitxer M6
NomiCognoms.ods
Visió gràfica de l'activitat
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
Treballar les relacions de parentesc.
Desenvolupament de l'activitat:
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P6 arbre genealògic
2. Fer que l'amplada de les cel·les del rang B1:O1 sigui d'1cm
3. Connectar les cel·les B5 i C5.
4. Copia la cel·la B5 a les cel·les F5, J5, N5, D8, L8, F11 i J11.
Assignar-hi a aquestes cel·les connectades els següents atributs:
Les línies d'enllaç de l'arbre genealògic es fan amb l'eina de Polígon
de la barra d'eines de dibuix.
5. Escriure a les cel·les del rang Q5:S18 el següent:
1a oració
6. Escriure a la cel·la Q20: =SI($A$1=0;ALEATENTRE(2;13))
7. Escriure a la cel·la R20: =CONSULTAV(Q20;$Q$5:$S$18;2)
8. Copiar la cel·la R20 i enganxar-la a la cel·la S20. Cal tenir en compte que després de fer la copia s'ha de canviar l'índex 2 pel 3 ja que es fa la cerca vertical a la tercera columna (S5:S18) i també caldrà canviar Q21 per Q20. Es a dir, el contingut de la cel·la S20seria: =CONSULTAV(Q20;$Q$5:$S$18;3)
Amb els passos 5 i 6 es mostra part de la primera oració aleatòria a la cel·la R20 que després es veurà a la cel·la B14 per ser completada per l'alumne en la cel·la I14. Amb el pas 7 es veu la segona part de l'oració a la cel·la S20 i que servirà de suport per a fer l'avaluació de la primera oració de l'activitat.
2a oració
9. Escriure a la cel·la Q21: =ALEATENTRE(1;Q20-1)
El segon número d'aquest aleatori, Q20-1, evita que es torni a repetir la primera oració.
10. Copiar la cel·la R20 i enganxar-la a la cel·la R21.
11. Copiar la cel·la R21 i enganxar-la a la cel·la S21. Recordar canviar l'index 2 pel 3.
Amb els passos 8, 9 i 10 es mostra la segona oració
3a oració
12. Escriure a la cel·la Q22: =ALEATENTRE(Q21+1;14)
El primer número d'aquest aleatori, Q21+1, evita que es torni a repetir la segona oració.
13. Copiar la cel·la R21 i enganxar-la a la cel·la R22.
14. Copiar la cel·la R22 i enganxar-la a la cel·la S22.Recordar canviar l'index 2 pel 3.
Amb els passos 11, 12 i 13 es mostra la tercera oració.
15. Escriure a la cel·la B14: =R20
16. Connectar les cel·les B14:H14 amb alineament horitzontal dreta.
17. Connectar les cel·les I14:J14 que serà on caldrà escriure per completar l'oració.
18. Formatar la cel·la I14 com es veu en el gràfic de la presentació de l'activitat.
19. Escriure a la cel·la K14: =SI(I14=””;””;SI(I14=S20;”bé”;”no”))
Amb aquesta fórmula es farà l'avaluació de la primera oració. Si la cel·la I14 no mostra cap valor, llavors la cel·la K14 no mostrarà cap valor; si no, i si el contingut de la cel·la I14 és igual al contingut de la cel·la S20, llavors apareixerà l'avaluador “bé”, en cas contrari apareixerà l'avaluador “no”.
20. Connectar les cel·les B16:H16 amb alineament horitzontal dreta.
21. Escriure a la cel·la B16: =R21
22. Connectar les cel·les I16:J16
23. Formatar la cel·la I16 com es veu en el gràfic de la presentació de l'activitat.
24. Escriure a la cel·la K16: =SI(I16=””;””;SI(I16=S21;”bé”;”no”))
Segueix el mateix procediment que l'explicat a la nota del pas 18.
25. Escriure a la cel·la B18: =R22
26. Connectar les cel·les B18:H18 amb alineament horitzontal dreta.
27. Connectar les cel·les I18:J18
28. Formatar la cel·la I18 com es veu en el gràfic de la presentació de l'activitat.
29. Escriure a la cel·la K18: =SI(I18=””;””;SI(I18=S22;”bé”;”no”))
Segueix el mateix procediment que l'explicat a la nota del pas 18.
30. Fer una macro amb les següent funcions:
31. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
32. Validar la cel·la A1 per al valor 0.
33. Protegir les cel·les que convingui.
34. Protegir la posició i mida de les línies poligonals.
35. Fer que els continguts de les cel·les del rang Q5:S22 no siguin visibles.
36. Comprovar que l'activitat funcioni correctament.
37. Desar el fitxer M6
NomiCognoms.ods
També es podria fer una activitat en la qual van canvian el noms de les cel·les de color gris de l'arbre genealògic així com es vagi fent clic a la macro
Presentació gràfica de l'activitat.
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
Ordenar paraules d'una oració.
Desenvolupament de l'activitat
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P7 ordenar paraules
2. Escriure a la cel·la B2 el següent text: Es tracta d'escriure a la cel·la de color gris una oració fent servir les paraules de les cel·les de color taronja. L'ordre de les paraules seguirà la següent pauta: escriure primer el subjecte, després el verb i a continuació el complement del verb. No oblidar de posar el punt final de l'oració.
3. Escriure en cada una de les cel·les del rang S3:X12 el següent:
Aquestes seran les oracions les paraules de les quals es presentaran desordenades.
4. Escriure a la cel·la R3: =SI(J2=0;ALEATENTRE(1;10))
Aquesta fórmula servirà de suport per triar una oració de les deu que s'escriuran al rang T3:X12.
5. Escriure a la cel·la k3: 1
6. Extendre la cel·la k3 fins la cel·la O3
Els números que hi ha a les cel·les del rang K3:03 (de l'1 al 5) serviran de base per triar números no repetits.
10. Escriure a la cel·la K4:=SI(J2=0;CONSULTAV(R3;S3:X12;2)).
Fa una CONSULTA vertical a la segona columna del rang S3:X12 en funció del número que hi ha a la cel·la R3. El número que hi ha a la cel·la R3 correspont a la fila de l'oració.
11. Escriure a la cel·la L4: =SI(J2=0;CONSULTAV(R3;S3:X12;3)). El mateix fent la CONSULTA a la columna 3.
12. Escriure a la cel·la M4: =SI(J2=0;CONSULTAV(R3;S3:X12;4)). El mateix fent la CONSULTA a la columna 4.
13. Escriure a la cel·la N4: =SI(J2=0;CONSULTAV(R3;S3:X12;5)). El mateix fent la CONSULTA a la columna 5.
14. Escriure a la cel·la O4: =SI(J2=0;CONSULTAV(R3;S3:X12;6)). El mateix fent la CONSULTA a la columna 6.
15. Escriure a la cel·la Q4: =K4&” ”&L4&” ”&M4&” ”&N4&” ”&O4
16. Escriure a la cel·la Q2 =Q4&”.”
Per presentar una oració amb les paraules desordenades es pot fer associant cada paraula a un número aleatori. D'aquesta manera si l'oració està formada per cinc paraules, caldrà presentar cinc números. Cal tenir en compte que les paraules es poden presentar desordenades però no repetides. Llavors es tracta de presentar cinc números aleatoris de l'1 al 5 que no estiguin repetits i que la majoria de vegades estiguin desordenats. Per resoldre aquesta qüestió es pot fer el següent:
17. Escriure en cada una de les cel·les del rang K5:O5 el següent: =SI(J2=0;ALEATENTRE(1;5)).
Aquests aleatoris serviran de base per a triar cinc números sense que hi hagi cap número repetit.
18. Escriure a la cel·la K6: =COMPTASI($K$5:$O$5;K5).
Aquesta fórmula permet saber quantes vegades està repetit el número que hi ha a la cel·laK5.
19. Copiar la cel·la K6 i enganxar-ho a les cel·les del rang L6:O6
Sabent quantes vegades es repeteix un número, caldrà fer una fórmula que permeti seleccionar els aleatoris no repetits (les cel·les del rang K6:O6 que tinguin el valor 1), fent així la primera tria de números no repetits.
20. Escriure a la cel·la K7: =SI(K6=1;K5;””). Aquesta fórmula permetrà seleccionar els números aleatoris no repetits fent així la primera tria.
21. Copiar la cel·la K7 i enganxar-ho a les cel·les del rang L7:O7.
Havent fet la primera tria del números no repetits del rang K7:O7, caldrà fer una segona tria comparant els rangs K7:O7 amb el rang K3:O3 i així fer la segona tria del números no repetits.
22. Escriure a la cel·la K8: =SI(COMPTASI($K$7:$O$7;K3)=0;K3;””)
23. Copiar la cel·la K8 i enganxar-ho a les cel·les del rang L8:O8
Havent fet la primera i la segona tria, es concatenen les cel·les del rang K7:O8 (pas 24) i així s'obté una cadena seguida de números no repetits.
24. Escriure a la cel·la K9: =K7&L7&M7&N7&O7&K8&L8&M8&N8&O8
Un cop estigui feta la concatenació a la cel·la K9 del rang K7:O8, caldrà fer l'extracció mitjançant la funció MIG de cada un dels números de la cel·la K9 i convertir-los en VALOR(passos 25, 26, 27, 28 i 29) per a ser reconeguts com a números quan es faci servir més endavant la funció CONSULTA.
.
25. Escriure a la cel·la K10: =VALOR(MIG(K9;1;1))
26. Escriure a la cel·la L10: =VALOR(MIG(K9;2;1))
27. Escriure a la cel·la M10: =VALOR(MIG(K9;3;1))
28. Escriure a la cel·la N10: =VALOR(MIG(K9;4;1))
29. Escriure a la cel·la O10: =VALOR(MIG(K9;5;1))
Una vegada estigui feta la l'extracció de cada un dels números de la cel·la K9 en cada una de les cel·les del rang K10:O10, es fa les següents consultes per obtenir les paraules desordenades.
30. Escriure a la cel·la B8: =CONSULTA(K10;$K$3:$O$3;$K$4:$O$4)
31. Copiar la cel·la B8 i enganxar-ho a les cel·les del rang C8:F8
32. Connectar les cel·les del rang B9:F9
33. Assignar a les cel·les del rang B8:F8 els següents atributs:
34. Assignar els següents atributs a les cel·les del rang B9:F9
35. Escriure a la cel·la G9: =SI(B9=””;””;SI(O(B9=Q2;B9=Q4);”bé”;”no”))
36. Escriure a la cel·la H9: =SI(B9=Q4;”(però manca el punt final de l'oració)”;””)
37. Fer una macro amb les següent funcions:
38. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
39. Validar la cel·la A1 per al valor 0.
40. Comprovar que l'activitat funcioni correctament.
41. Protegir les cel·les que convingui.
42. Fer que els continguts de les cel·les del rang J2:X12 no siguin visibles.
43. Desar el fitxer M6
NomiCognoms.ods
Hi ha una altra manera de fer un número aleatori de nou dígits sense repetir cap dígit. Observar els següents gràfics on a la cel·laC4 es veu el resultat.
Havent escrit aquestes fórmules, només caldria seleccionar el rang E2:E4 i s'estendre'l fins la columna K. El número aleatori de nou dígits no repetits es mostra a la cel·la C4
Fent algunes variacions, es podrien presentar oracions de més de nou paraules on cada oració podria tenir un número diferent de paraules. Observar l'exemple gràfic d'ordenar oracions on hi ha escrit Ordenar paraules de la pràctica 4 del mòdul 7.
Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
Fer un diccionari particular per traduir una paraula catalana a dos idiomes (anglès i castellà) mitjançant la funció CONSULTAV().
Desenvolupament de l'activita
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P8 diccionari 1
2. Escriure a les cel·les del rang G3:I5 les següents paraules:
En aquesta activitat només es poden consultar tres paraules perquè ja es suficient per mostrar com funciona l'activitat. Quan s'hagi estudiat com funciona l'activitat, es podran afegir tantes paraules com es vulgui i es podrà augmentar el número d'idiomes a consultar.
3. Formatar les cel·les del rang C6:E7 com es veu en el gràfic de presentació de l'activitat. A la cel·la C7 s'escriurà la paraula que es vol consultar.
4. Escriure a la cel·la D7: =SI(COMPTASI($G$3:$G$5;$C$7)=0;””;SI($C$7=””;””;CONSULTAV($C$7;$G$3:$I$5;2;0)))
La fórmula =SI(COMPTASI($G$3:$G$5;$C$7)=0;”“ permet que la cel·la no mostri cap valor en cas que no es trobi la paraula que hagi escrita a la cel·la C7. De no posar aquesta fórmula, apareixeria el valor #N/A donant a entendre que no es troba la paraula que hi ha a la cel·la E7.
La Fórmula SI($C$7=””;””;CONSULTAV($C$7;$G$3:$I$5;2;0)) permet fer la consulta de la paraula que hagi escrita a cel·la C7 en la segona columna del rang G3:I5 sempre i quan aquesta cel·la sigui tingui contingut.
5. Copiar la cel·la D7 a la cel·la E7 tenint en compte que cal canviar el número 2 pel 3 (fent així referència a la tercera columna del rang G3:I5)
6. Escriure a la cel·la F7: =SI(C7=””;””;SI(COMPTASI(G3:I5;C7)=0;”Aquesta paraula no està entrada en aquest diccionari particular.”;””))
En cas que a la cel·la C7 no hagi cap valor, la cel·la F7 no mostrarà cap valor; en cas contrari, i suposant que la paraula que hi hagi escrita a la cel·la C7 no es trobi (valor de repetició = 0), llavors es mostraria el text de “Aquesta paraula no està entrada en aquest diccinari particular”.
7. Fer una macro amb la funció d'esborrar el contingut de la cel·la C7.
8. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
9. Protegir les cel·les que convingui.
10. Fer no visibles les cel·les que convingui.
11. Comprovar que l'activitat funcioni correctament.
12. Desar el fitxer M6NomiCognoms.ods
Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat
Desenvolupament de l'activitat
Fer un diccionari particular per traduir una paraula catalana a dos idiomes (anglès i castellà) mitjançant camps d'opció.
Desenvolupament de l'activitat
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P8 diccionari 2
2. Escriure a les cel·les del rang F3:H5 les següents paraules:
3. Formatar les cel·les del rang D7:E9 com es veu en el gràfic de presentació de l'activitat.
4. Crear un camp d'opció enllaçant-lo a la cel·la B8. Col·locar aquest camp d'opció com es veu a l'activitat de presentació (cel·laD8)
Quan es fa clic al camp d'opció situat a la cel·la D8, apareix paraula VERITAT a la cel·la B8perquè aquest camp d'opció està enllaçat a la cel·la B8. Tenint en compte que la paraula VERITAT també es pot interpretar com valor 1, només caldrà fer servir la funció lògica =SI()i la funció CONSULATV() per trobar la paraula traduïda a l'idioma que correspongui en cas que la paraula consultada estigui al diccionari particular.
5. Escriure a la cel·la E8: =SI(COMPTASI($F$3:$F$5;$E$7)=0;””;SI(B8=1;CONSULTAV($E$7;$F$3:$H$5;2;0);””))
6. Seleccionar el camp d'opció creat anteriorment, fer una copia i enganxar-lo a la cel·la D9.
7. Enllaçar aquest segon camp d'opció a la cel·la B9.
8. Copiar la cel·la E8 i enganxar-la a la cel·la E9 tenint en compte que només cal canviar el numero 2 pel 3 (fent així referència a la tercera columna del rang de cel·les F3:H5)
9. Escriure a la cel·la F7: =SI(E7=””;””;SI(COMPTASI(F3:F5;E7)=0;”Aquesta paraula no està entrada en aquest diccionari particular”;””))
10. Desprotegir les cel·les B8:B9 perquè funcioni bé l'activitat una vegada s'hagi protegit el full.
11. Fer una macro la qual servirà per esborrar el contingut de la cel·la E7
12. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
13. Protegir les cel·les que convingui.
14. Fer no visibles les cel·les que convingui.
15. Comprovar que l'activitat funcioni correctament.
16. Desar el fitxer M6NomiCognoms.ods
Presentació gràfica de l'activitat
Funcions que es fan servir en aquesta activitat
Objectiu de l'activitat
Fer una breu descripció partint d'una pauta de preguntes.
Desenvolupament de l'activitat
1. Obrir el fitxer M6
NomiCognoms.ods i afegir un nou full amb el nom de M6P9 expressió escrita.
2. Escriure a la cel·la I3: =SI(O(D4=“nen”;D4=“noi”;D4=“xiquet”;D4=“home”);”El ”;”La ”)&D3
El pas 2 serveix per triar l'article El o l'article La
3. Escriure a la cel·la J3:=MIG(I3;1;2)
El pas 3 serveix de base per triar l'expressió “és un” o “és una” de la fórmula que hi ha al pas 4.
4. Escriure a la cel·la I4: =SI(J3=“El”;” és un ”&D4;SI(J3=“La”;” és una ”&D4))
5. Escriure a la cel·la I5: =” que té ”&D5&” anys”
6. Inserir una nota/comentari a la cel·la D6 en la qual hagi escrit: “Escriure el nom de la població”
Per inserir un comentari, anar al menú i clic en Insereix | Comentari i escriure-hi el comentari a la bafarada mostrada. En haver-ho fet, observar que es veu un petit quadradet de color vermell al vertex superiro dret del rectangle. En passar el punter del ratolí per la cel·la, es mostra el comentari escrit.
7. Escriure a la cel·la I6: =” i viu a ”&D6
8. Escriure a la cel·la I7: =” ”&D7&”.”
9. Escriure a la cel·la I8: =” ”&INICIALMAJUSC(D8)&” “
10. Escriure a la cel·la I9: =D9
11. Escriure a la cel·la I10: =” i li agrada ”&D10&”.”
12. Validar la cel·la D10 perquè mostri un llistat de paraules de les quals es pugui triar-ne una.
Per validar una cel·la amb un llistat, fer el següent:
13. Situar a la cel·la E12 una barra desplaçament i enllaçar-la amb la cel·la J12. Aquesta barra servirà per escriure l'altura.
14. Escriure a la cel·la D12: =1+(J12/100) i formatar-la perquè aquesta cel·la mostri dos decimals.
15. Escriure a la cel·la I12: =“Fa ”&D12&” m d'estatura”
16. Escriure a la cel·la I13: =“i ”&D13
17. Copiar la cel·la D10 a la cel·la D13 i al llistat escriure el seguent:
18. Copiar la cel·la D10 a la cel·la D14 i al llistat escriure el seguent:
19. Copiar la cel·la D10 a la cel·la E14 i al llistat escriure el seguent:
20. Copiar la cel·la D10 a la cel·la F14 i al llistat escriure el seguent:
21. Escriure a la cel·la I14: =“Té el cabell ”&D14
22. Escriure a la cel·la J14: =” ”&E14
23. Escriure a la cel·la K14: =” i de color ”&F14&”.”
24. Copiar la cel·la D14 a la cel·la D16 i al llistat escriure el seguent:
25. Copiar la cel·la D14 a la cel·la E16 i al llistat escriure el seguent:
26. Copiar la cel·la D14 a la cel·la F16 i al llistat escriure el seguent:
27. Escriure a la cel·la I16: =“Li agrada portar ”&D16&” i “
28. Escriure a la cel·la J16: =E16&” “
29. Escriure a la cel·la K16: =F16
30. Escriure a la ce·la C19: =SI(O(D3=””;D4=””;D5=””;D6=””;D7=””;D8=””;D9=””;D10=””);””;I3&I4&I5&I6&I7&I8&I9&I10)
Amb el primer argument d'aquesta fórmulaO(D3=””;D4=””;D5=””;D6=””;D7=””;D8=””;D9=””;D10=””) no es permet mostar res a la cel·la C19 fins que no hagi quelcom escrit en cada una de les cel·les del rang D3:D10
31. Fusionar les cel·les del rang C19:G19
32. Escriure a la cel·la C20: =I12&” ”&I13&”. ”&I14&”,”&J14&K14
33. Fusionar les cel·les del rang C20:G20
34. Escriure a la cel·la C21: =I16&J16&K16&”.”
35. Fusionar les cel·les del rang C21:G21
36. Fer una macro amb les següent funcions:
37. Crear un botó de prémer de Controls de formulari i assignar-li la macro feta anteriorment.
38. Protegir les cel·les que convingui.
39. Ocultar les cel·les que convingui.
40. Comprovar que l'activitat funcioni correctament.
41. Desar el fitxer M6
NomiCognoms.ods.