相当温位の水平分布

[2016年 9月 20日 火曜日 16:56:18 JST]

[~/2016.PolarLow/ERA-I/PT+EPT]

[am@aofd165]

$ srcdump.sh EPT.gs plev.ctl sfc.ctl

aofd165.bio.mie-u.ac.jp

/work1/am/2016.PolarLow/ERA-I/PT+EPT

Tue Sep 20 16:57:26 JST 2016

======================

EPT.gs

======================

#

# Adakudlu, M. and Barstad, I. (2011), Impacts of the ice-cover and sea-surface temperature on a polar low over the Nordic seas: a numerical case study. Q.J.R. Meteorol. Soc., 137: 1716?1730. doi:10.1002/qj.856

# p. 208

'open sfc.ctl'

'open plev.ctl'

#'q ctlinfo 1'

#say result

plev=975

header='ERA-I.Barents110116-110126'

varname='EPT'plev

outdir='Fig/'varname

'!mkdir -p 'outdir

#'set mproj latlon'

'set mproj nps'

'set lat 60 85'

'set lon -45 50'

'set grid off'

i=1

while (i <= 34 )

'set t ' i

'cc'

'set mpdset mres'

'set frame off'

'q dims'

line=sublin(result,5)

datetime=subwrd(line,6)

'set strsiz 0.2 0.25'

'set string 1 c 5'

'draw string 4.5 8.5 'datetime

'mul 1 4 1 1 -yini 1'

var1=sst.1'-273'

'set gxout shade2'

'set grads off'

'color -1 18 2 -kind white->rainbow -xcbar 1 1.1 0.5 2.7 -fh 0.12 -fw 0.11 -edge triangle -line on'

'draw string 0.9 2.8 degC'

# 'set strsiz 0.2 0.22'

'draw string 1.8 0.6 SST'

'set clab off'

'd maskout(' var1 ',' var1 '+3)'

'set gxout contour'

'set cthick 3'

'set ccolor 0'

'set cmin -1'

'set cmax 18'

'set cint 2'

'd maskout(' var1 ',' var1 '+3)'

'circlat 5 55 0.1'

'circlon 10 0.1'

'tile ' ci.1 ' 0.2 1'

'set gxout contour'

levs1='960 965 970 975 980 985 990 995 1000 1005 1010 1015 1020'

'set clevs 'levs1

'set clab off'

'set cthick 5'

'set ccolor 0'

'd ' msl.1 '/100'

'color -gxout contour -kind purple->thistle -levs ' levs1 ;#' -xcbar 7.5 7.6 6.0 8.2 -fh 0.12 -fw 0.11 -edge triangle -line on'

# 'draw string 7.5 8.3 hPa'

'set cthick 2'

'd ' msl.1 '/100'

'set gxout vector'

'set z 1'

sclv=15

lngv=0.1

'set gxout vector'

'set arrscl 'lngv' 'sclv

'set arrlab off'

'set ccolor 0'

'set cthick 10'

'set grads off'

'd skip(u10.1,10,5);skip(v10.1,10,5)'

'set ccolor 1'

'set cthick 3'

'set arrscl 0.1 'sclv

'set arrlab on' ;*off'

'set grads off'

sclv2=sclv*2

lngv2=lngv*2

'vec.gs skip(u10.1,10,5);skip(v10.1,10,5) -SCL ' lngv2 ' ' sclv2 ' -P 6.5 0.6 -SL m/s -HDSZ 0.5'

plev2=plev

'mul 1 4 1 2 -yini 0.1'

'set z 1'

temp'='t.2 '(lev=' plev2 ')*pow(1000/' plev2 ',0.2857)'

rh=r.2 '(lev=' plev2 ')'

'es=6.1173*exp(((2.501*pow(10,6))/461.50)*(1/273.16 - 1/' temp '))'

'ws=621.97*(es/(' plev2 '-es))'

'w=(' rh '*ws)/(100*1000)'

ept'=(' temp '+((2.501*pow(10,6))/1004)*' w' )*pow((1000/' plev2 '),287/1004)'

var2'='ept

'set gxout shade2'

'color 260 330 10 -kind white->blue->cyan->yellow->tomato -xcbar 1 1.1 3.3 5.5 -fh 0.12 -fw 0.11 -edge triangle -line on'

'draw string 0.9 5.6 K'

# 'set strsiz 0.2 0.22'

# 'draw string 1.8 3.4 `3z`0`be'plev2

'draw string 1.8 3.4 EPT'plev2

'set clab off'

'set grads off'

'd maskout(' var2 ',' sp.1 '-' plev2 '*100)'

'set gxout contour'

'set grads off'

'set clab off'

'set cthick 1'

'set ccolor 0'

'set grads off'

'd maskout(' var2 ',' sp.1 '-' plev2 '*100)'

'set gxout contour'

'set z 1'

'set clevs 'levs1

'set clab off'

'set cthick 5'

'set ccolor 0'

'set grads off'

'd ' msl.1 '/100'

'color -gxout contour -kind indigo->plum -levs ' levs1 ' -xcbar 7.5 7.6 2.3 6.5 -fh 0.12 -fw 0.11 -edge triangle -line on'

'draw string 7.5 6.6 hPa'

'set cthick 2'

'set grads off'

'd ' msl.1 '/100'

'set lev 'plev2

sclv=15

lngv=0.1

'set gxout vector'

'set arrscl 'lngv' 'sclv

'set arrlab off'

'set ccolor 0'

'set cthick 10'

'set grads off'

'd skip(u.2,10,5);skip(v.2,10,5)'

'set ccolor 1'

'set cthick 3'

'set arrscl 0.1 'sclv

'set arrlab on' ;*off'

'set grads off'

sclv2=sclv*2

lngv2=lngv*2

'vec.gs skip(u.2,10,5);skip(v.2,10,5) -SCL ' lngv2 ' ' sclv2 ' -P 6.5 3.4 -SL m/s -HDSZ 0.5'

'circlat 5 55 0.1'

'circlon 10 0.1'

plev2=plev

'mul 1 4 1 3 -yini 0.1'

km100=100000

'set z 1'

pi=3.14159265359

dtr=pi'/'180

a=6.371e6

dx '=' a '*cos(' dtr '*' lat ')*' dtr '*cdiff(' lon ',' x')'

dy '=' a '*' dtr '*cdiff(' lat ',' y ')'

dtdx '=cdiff(' ept ',' x ')/' dx

dtdy '=cdiff(' ept ',' y ')/' dy

grad '=mag(' dtdx ',' dtdy ')*'km100

'set gxout shade2'

'color 2 10 2 -kind white->blue->cyan->yellow->tomato -xcbar 1 1.1 6.0 8.2 -fh 0.12 -fw 0.11 -edge triangle -line on'

'draw string 0.9 8.3 K/'100'km'

# 'set strsiz 0.2 0.22'

# 'draw string 1.8 6.1 `37z`0`be'plev2

'draw string 1.8 6.1 `37`0EPT'plev2

'set clab off'

'set grads off'

'd maskout(' grad ',' sp.1 '-' plev2 '*100)'

'set gxout contour'

'set clab off'

'set cthick 10'

'set ccolor 0'

'set cstyle 1'

'set cint 10'

'set grads off'

'd maskout(' ept ',' sp.1 '-' plev2 '*100)'

'set gxout contour'

'set clab off'

'set cthick 4'

'set ccolor 1'

'set cstyle 3'

'set cint 10'

'set grads off'

'd maskout(' ept ',' sp.1 '-' plev2 '*100)'

'set gxout contour'

'set z 1'

'set clevs 'levs1

'set clab off'

'set cthick 5'

'set ccolor 0'

'set grads off'

'd ' msl.1 '/100'

'color -gxout contour -kind indigo->plum -levs ' levs1 ' -xcbar 7.5 7.6 2.3 6.5 -fh 0.12 -fw 0.11 -edge triangle -line on'

'draw string 7.5 6.6 hPa'

'set cthick 2'

'set grads off'

'd ' msl.1 '/100'

'circlat 5 55 0.1'

'circlon 10 0.1'

num=''

if (i<10)

num='00'i

endif

if (i>=10 & i<100)

num='0'i

endif

if (i>100)

num=i

endif

figfile=outdir '/' header '_' varname '_' num '_' datetime '.png'

say 'Output: ' figfile

'gxprint ' figfile

i=i+1

endwhile

'allclose'

exit

#'quit'

----------------------

End of EPT.gs

----------------------

======================

plev.ctl

======================

dset /work4/data/ERA-Interim/ERA-I.Barents_110116-26_plev.nc

title

undef -9.99e+33

dtype netcdf

UNPACK scale_factor add_offset

OPTIONS yrev zrev

xdef 480 linear -180 0.75

ydef 81 linear 30 0.75

zdef 27 levels 1000 975 950 925 900 875 850 825

800 775 750 700 650 600 550 500 450 400

350 300 250 225 200 175 150 125 100

tdef 44 linear 00Z16JAN2011 360mn

vars 10

pv=>pv 27 t,z,y,x Potential vorticity

z=>z 27 t,z,y,x Geopotential

t=>t 27 t,z,y,x Temperature

q=>q 27 t,z,y,x Specific humidity

w=>w 27 t,z,y,x Vertical velocity

r=>r 27 t,z,y,x Relative humidity

clwc=>clwc 27 t,z,y,x Specific cloud liquid water content

ciwc=>ciwc 27 t,z,y,x Specific cloud ice water content

u=>u 27 t,z,y,x U component of wind

v=>v 27 t,z,y,x V component of wind

endvars

----------------------

End of plev.ctl

----------------------

======================

sfc.ctl

======================

dset /work4/data/ERA-Interim/ERA-I.Barents_110116-26_sfc.nc

title

undef -9.99e+33

dtype netcdf

UNPACK scale_factor add_offset

OPTIONS yrev

xdef 480 linear -180 0.75

ydef 81 linear 30 0.75

zdef 1 linear 0 1

tdef 44 linear 00Z16JAN2011 360mn

vars 8

ci=>ci 0 t,y,x Sea-ice cover

sst=>sst 0 t,y,x Sea surface temperature

sp=>sp 0 t,y,x Surface pressure

msl=>msl 0 t,y,x Mean sea level pressure

u10=>u10 0 t,y,x 10 metre U wind component

v10=>v10 0 t,y,x 10 metre V wind component

t2m=>t2m 0 t,y,x 2 metre temperature

d2m=>d2m 0 t,y,x 2 metre dewpoint temperature

endvars

----------------------

End of sfc.ctl

----------------------