BBjSlider
El objeto BBjSlider provee métodos para manipular un control Slider.
REM “[PRG37] Ejemplo de BBjSlider
REM “Mundo BBx (http://sites.google.com/site/mundobbx)
REM
REM “Obtiene una instancia del objeto BBjAPI
REM “=======================================
LET miAPI!=BBjAPI()
REM
REM “Abre el dispositivo SYSGUI
REM “==========================
SYSGUI=UNT
OPEN (SYSGUI) "X0"
REM
REM “Obtiene la instancia del objeto BBjSysGui
REM “=========================================
LET sysgui!=miAPI!.getSysGui()
REM
REM “Valores para crear una ventana
REM “==============================
X=10
Y=10
ANCHO=200
ALTO=200
TITULO$="Ejemplo de uso BBjSlider"
REM
REM “Establece el contexto actual
REM “============================
sysgui!.setContext(0)
REM
REM “Crea la ventana
REM “===============
window! = sysgui!.addWindow(X,Y,ANCHO,ALTO,TITULO$)
REM
REM “Agrega un Slider vertical en la ventana
REM “=======================================
slider1! = window!.addVerticalSlider(101,180,0,20,200,$0000$)
REM
REM “Registra rutinas en CALLBACKs
REM “=============================
CALLBACK(ON_CONTROL_SCROLL,SLIDER_DESPLAZA,sysgui!.getContext(),slider1!.getID())
CALLBACK(ON_CLOSE,CIERRA_APLIC,sysgui!.getContext())
REM
REM “Procesa Eventos
REM “===============
PROCESS_EVENTS
REM
REM “Rutina Callback llamada cuando el Slider es desplazado
REM “======================================================
SLIDER_DESPLAZA:
REM “Despliega un mensaje informando el desplazamiento del Slider
MENSAJE$="El Slider ha sido desplazado"
LET X=MSGBOX(MENSAJE$)
RETURN
REM “Rutina Callback llamada cuando el usuario cierra la ventana de la aplicación
REM “============================================================================
CIERRA_APLIC:
RELEASE
RETURN