El objeto BBjCheckBox provee métodos para manipular un control GUI tipo casilla de verificación. El siguiente ejemplo con funcionalidad completa (cópialo y pégalo en un nuevo programa y ejecútalo) te permite observarlo en acción. He destacado en otro color la instrucción que contiene la creación del objeto.
REM “[PRG06] Ejemplo de BBjCheckBox
REM “Mundo BBx
REM
REM “Obtiene una instancia del objeto BBjAPI
REM “=======================================
LET miAPI!=BBjAPI()
REM
REM “Abre el dispositivo SYSGUI
REM “==========================
SYSGUI=UNT
OPEN (SYSGUI) "X0"
REM
REM “Obtiene la instancia del objeto BBjSysGui
REM “=========================================
LET sysgui!=miAPI!.getSysGui()
REM
REM “Valores para crear una ventana
REM “==============================
X=10
Y=10
ANCHO=400
ALTO=300
TITULO$="Ejemplo de uso BBjCheckBox"
REM
REM “Establece el contexto actual
REM “============================
sysgui!.setContext(0)
REM
REM “Crea la ventana
REM “===============
window! = sysgui!.addWindow(X,Y,ANCHO,ALTO,TITULO$)
REM
REM “Agrega una casilla de verificacion a la ventana
REM “===============================================
casilla1!=window!.addCheckBox(101,50,100,140,30,"Casilla de verificacion",$0004$)
REM
REM “Agrega una etiqueta en la ventana
REM “=================================
etiqueta1! = window!.addStaticText(102,10,150,200,30,"")
REM
REM “Registra rutinas en CALLBACKs
REM “=============================
CALLBACK(ON_CHECK_ON,CASILLA_MARCADA,sysgui!.getContext(),casilla1!.getID())
CALLBACK(ON_CHECK_OFF,CASILLA_DESMARCADA,sysgui!.getContext(),casilla1!.getID())
CALLBACK(ON_CLOSE,CIERRA_APLIC,sysgui!.getContext())
REM
REM “Procesa Eventos
REM “===============
PROCESS_EVENTS
REM
REM “Rutina Callback llamada cuando la casilla esta marcada
REM “======================================================
CASILLA_MARCADA:
REM
REM “Muestra un mensaje en la etiqueta creada vacia al comienzo
REM “----------------------------------------------------------
etiqueta1!.setText("La casilla se encuentra marcada")
RETURN
REM
REM “Rutina Callback llamada cuando la casilla esta marcada
REM “======================================================
CASILLA_DESMARCADA:
REM
REM “Muestra un mensaje en la etiqueta creada vacia al comienzo
REM “----------------------------------------------------------
etiqueta1!.setText("La casilla se encuentra desmarcada")
RETURN
REM
REM “Rutina Callback llamada cuando el usuario cierra la ventana de la aplicación
REM “============================================================================
CIERRA_APLIC:
RELEASE
RETURN