EL objeto BBjInputE provee métodos para manipular un control InputE.
REM “[PRG19] Ejemplo de BBjInputE
REM “Mundo BBx (http://sites.google.com/site/mundobbx)
REM
REM “Obtiene una instancia del objeto BBjAPI
REM “=======================================
LET miAPI!=BBjAPI()
REM
REM “Abre el dispositivo SYSGUI
REM “==========================
SYSGUI=UNT
OPEN (SYSGUI) "X0"
REM
REM “Obtiene la instancia del objeto BBjSysGui
REM “=========================================
LET sysgui!=miAPI!.getSysGui()
REM
REM “Valores para crear una ventana
REM “==============================
X=10
Y=10
ANCHO=200
ALTO=200
TITULO$="Ejemplo de uso BBjInputE"
REM
REM “Establece el contexto actual
REM “============================
sysgui!.setContext(0)
REM
REM “Crea la ventana
REM “===============
window! = sysgui!.addWindow(X,Y,ANCHO,ALTO,TITULO$)
REM
REM “Agrega un control INPUTE que solo acepta caracteres alfabeticos
REM “y los convierte a mayusculas, limitando el ingreso a 10 caracteres
REM “e insertando el valor "STANDARD" cuando el usuario usa la tecla
REM “de restaurar (normalmente la tecla ESCAPE)
REM “==================================================================
texto1!=window!.addInputE(101,50,100,90,30,$0804$,"AAAAAAAAAA","",1,"STANDARD","")
REM
REM “Registra rutinas en CALLBACKs
REM “=============================
CALLBACK(ON_EDIT_MODIFY,INPUTE_MODIFICADO,sysgui!.getContext(),texto1!.getID())
CALLBACK(ON_CLOSE,CIERRA_APLIC,sysgui!.getContext())
REM
REM “Procesa Eventos
REM “===============
PROCESS_EVENTS
REM
REM “Rutina Callback llamada cuando el contenido del control INPUTE cambia
REM “=====================================================================
INPUTE_MODIFICADO:
REM
REM “Muestra un mensaje con el contenido del control INPUTE
REM “------------------------------------------------------
MENSAJE$="El contenido del control INPUTE es: " + STR(texto1!.getText())
LET X=MSGBOX(MENSAJE$)
RETURN
REM
REM “Rutina Callback llamada cuando el usuario cierra la ventana de la aplicación
REM “============================================================================
CIERRA_APLIC:
RELEASE
RETURN