El objeto BBjInputN provee métodos para manipular un control InputN, usado para contener valores numéricos.
REM “[PRG21] Ejemplo de BBjInputN
REM “Mundo BBx (http://sites.google.com/site/mundobbx)
REM
REM “Obtiene una instancia del objeto BBjAPI
REM “=======================================
LET miAPI!=BBjAPI()
REM
REM “Abre el dispositivo SYSGUI
REM “==========================
SYSGUI=UNT
OPEN (SYSGUI) "X0"
REM
REM “Obtiene la instancia del objeto BBjSysGui
REM “=========================================
LET sysgui!=miAPI!.getSysGui()
REM
REM “Valores para crear una ventana
REM “==============================
X=10
Y=10
ANCHO=200
ALTO=200
TITULO$="Ejemplo de uso BBjInputN"
REM
REM “Establece el contexto actual
REM “============================
sysgui!.setContext(0)
REM
REM “Crea la ventana
REM “===============
window! = sysgui!.addWindow(X,Y,ANCHO,ALTO,TITULO$)
REM
REM “Agrega un control INPUTN que limita la entrada a 10 caracteres
REM “e inserta el valor 0 cuando el usuario pulsa la tecla restaurar
REM “(normalmente la tecla ESCAPE)
REM “===============================================================
valor1!=window!.addInputN(101,50,100,90,30,$0804$,"##,###,###.00",$$,1,0)
REM
REM “Registra rutinas en CALLBACKs
REM “=============================
CALLBACK(ON_EDIT_MODIFY,INPUTN_MODIFICADO,sysgui!.getContext(),valor1!.getID())
CALLBACK(ON_CLOSE,CIERRA_APLIC,sysgui!.getContext())
REM
REM “Procesa Eventos
REM “===============
PROCESS_EVENTS
REM
REM “Rutina Callback llamada cuando el contenido del control INPUTE cambia
REM “=====================================================================
INPUTN_MODIFICADO:
REM
REM “Muestra un mensaje con el contenido del control INPUTE
REM “------------------------------------------------------
MENSAJE$="El contenido del control INPUTN es: " + STR(valor1!.getValue())
LET X=MSGBOX(MENSAJE$)
RETURN
REM
REM “Rutina Callback llamada cuando el usuario cierra la ventana de la aplicación
REM “============================================================================
CIERRA_APLIC:
RELEASE
RETURN