Obtener datos históricos, datos tiempo de cotización, variación al precio de cierre, (SMA), (RSI), (R/S), máximo, mínimo, promedio, enlace, mini gráfico y seguimiento de compra.

Ⓐ Propuesta plantilla datos históricos:

TickerHistroy!A1:

=LAMBDA(getValueStatic;getValueStatic)

(LET(getTicker;Ticker!$A$1;

getDatasHistory;GOOGLEFINANCE(getTicker;"all";DATE(1930;1;1);TODAY();"DAILY");

getToday;GOOGLEFINANCE(getTicker;"tradetime");

getDateLast;MAX(CHOOSECOLS(getDatasHistory;1));

IF(TEXT(getToday;"dd/mm/yyyy")=TEXT(getDateLast;"dd/mm/yyyy");

getDatasHistory;

{getDatasHistory;

getToday\GOOGLEFINANCE(getTicker;"priceopen")\GOOGLEFINANCE(getTicker;"high")\GOOGLEFINANCE(getTicker;"low")\GOOGLEFINANCE(getTicker;"price")\GOOGLEFINANCE(getTicker;"volume")}

))) 

Ⓐ Propuesta detalle:

Insertar la fórmula en la hoja y celda TickerHistory!A1: 

• Crear una hoja cuyo nombre es «TickerHistory» Insertar fórmula celda A1. La función LET() asigna nombres descriptivos para clarificar su cometido. Su utilización parte de guardar las variables para no tener que volver a repetir funciones, en caso de modificar la fórmula meses después es práctico comprobar la estructura de la fórmula. Asignación «getTicker» obtiene el símbolo del índice bursátil seguido de dos puntos y después símbolo de cotización. Ejemplo «NASDAQ:GOOG» ubicado en hoja y celda «Ticker!$A$1».

• Asignación «getDatasHistory» mediante la función GOOGLEFINANCE(), obtiene los datos históricos con el parámetro «all». Función DATE() convierte los valores en fecha. Empezado desde los principios hasta la fecha actual con la función TODAY(). Parámetro «DAILY» frecuencia diaria para conseguir los datos.

• Asignación «getToday» logramos la fecha y hora en tiempo de cotización.

• Asignación «getDateLast» obtenemos la última fecha de los datos históricos de la asignación «getDatasHistory» que se encuentra en la primera columna por CHOOSECOLS() y calcule la fecha máxima utilizando la función MAX(). Función IF() si la expresión lógica «getToday = getDateLast» comparación de igualdad con el mismo patrón de fecha mediante TEXT() y eliminado la hora predeterminada. Si es TRUE() muestra los datos históricos. Si es FALSE() entonces creamos una matriz con llaves {}. El primer parámetro son los datos históricos. Punto y coma «;»crea otra línea. los demás parámetros son de fecha, precio apertura, precio máximo, precio mínimo, precio actual con retraso y volumen obtenidos por la llamada a la función GOOGLEFINANCE() exento al fecha que ya estaba asignada con «getToday». Están separados con barra de dividir inversa «\» para generar la matriz como columna. Finalmente e insertado LAMBDA() elimina a veces el mensaje de calculado.....

Ⓑ Propuesta celdas criterios:

Reservar celdas para criterios.

Ⓑ Propuesta detalle:

• Crear una hoja cuyo nombre es «Ticker».

• «Ticker!A1» reservado para escribir el nombre del ticket. Ejemplo «NASDAQ:GOOG». Utilizar el orden, símbolo índice bursátil seguido de dos puntos y finalmente símbolo de cotización. Formato de número personalizado «0;0;0;"📌"@» (opcional).

• «Ticker!A2» reservado para escribir el número de días a mostrar en la hoja. Formato de número personalizado «"🗓"#,##0" Días"» (opcional).

• «Ticker!I2» reservado para escribir el número de periodos a calcular la media móvil simple. Formato de numérico personalizado «" 📏 "#,##0" Longitud"» (opcional).

• «Ticker!J2» reservado para escribir el número de periodos a calcular el índice de fuerza relativa. Formato de numérico personalizado «" 📐 "#,##0" longitud"» (opcional).

• «Ticker!K2» reservado para escribir el número de periodos a calcular las resistencias. Formato de número personalizado  «"⟰ "#,##0" Longitud"» (opcional). Combinar celdas en horizontal rango «Ticker!K2:L2».

• «Ticker!M2» reservado para escribir el número de periodos a calcular soportes. Formato de número personalizado «"⟱ "#,##0" Longitud"» (opcional). Combinar celdas en horizontal rango «Ticker!M2:N2».

• Inmovilizar las tres primeras líneas.

• Color relleno a su criterio.

Ⓒ  Propuesta datos históricos: 

Ticker!A3:

=LET(getRangeDatasHistory;TickerHistory!$A:$F; getDays;$A$2; 

getCountShowResults;QUERY(getRangeDatasHistory;"select count(Col1) where Col1 >= date '"&TEXT(TODAY()-getDays;"yyyy-mm-dd")&"' label count(Col1) ''");

getDatasHistoryOperate;QUERY(getRangeDatasHistory;"order by Col1 desc limit "&getCountShowResults;1);

getShowResults;QUERY(getDatasHistoryOperate;"order by Col1 desc 

label Col1 '📆Fecha', Col2 '🔓Apertura', Col3 '📈Máximo', Col4 '📉Mínimo', Col5 '🔒Cierre', Col6 '📊Volumen' 

format Col1 'dd/mm/yyyy', Col2 '#,##0.00', Col3 '#,##0.00', Col4 '#,##0.00', Col5 '#,##0.00', 

Col6 '[>=1000000000000]#,##0.00,,,,"&CHAR(34)&"B"&CHAR(34)&";[>=1000000]#,##0.00,,"&CHAR(34)&"M"&CHAR(34)&";#,##0.00,"&CHAR(34)&"K"&CHAR(34)&"'";1);

HSTACK(getShowResults)) 

Ⓓ Propuesta variación de precio y variación porcentual del precio de cierre:

Ticker!G3:

=LET(getRangeDatasHistory;TickerHistory!$A:$F; getDays;$A$2;

getCountShowResults;QUERY(getRangeDatasHistory;"select count(Col1) where Col1 >= date '"&TEXT(TODAY()-getDays;"yyyy-mm-dd")&"' label count(Col1) ''");

getDatasHistoryOperate;QUERY(getRangeDatasHistory;"select Col5 order by Col1 desc limit "&getCountShowResults+1;1);

getPriceClose;getDatasHistoryOperate;

getPriceClosePrevious;QUERY(getDatasHistoryOperate;"offset 1";1);

getVar;QUERY(HSTACK(getPriceClose;getPriceClosePrevious);"select (Col1-Col2) ";1);

getVarPercent;QUERY(HSTACK(getPriceClose;getPriceClosePrevious);"select (1-(Col2/Col1))";1);

getShowResults;QUERY(HSTACK(getVar;getVarPercent);"limit "&getCountShowResults&

" label Col1 '🧮Var', Col2 '🧮Var %' format Col1 '[blue]+#,##0.00;[red]-#,##0.00;0.00', Col2 '[blue]+#,##0.00%;[red]-#,##0.00%;0.00%'";1);

HSTACK(getShowResults))

Ⓓ Propuesta detalle:

Inserta la fórmula en hoja y celda «Ticker!G3».

• La función LET() asigna nombres descriptivos para clarificar su cometido. Su utilización parte de guardar las variables para no tener que volver a repetir funciones, en caso de modificar la fórmula meses después es práctico comprobar la estructura de la fórmula.

• Asignación «getRangeDatasHistory» obtiene el historial de datos históricos. Según ticket en la celda A1 y vinculada en la hoja «TickerHistory!A:F»

• Asignación «getDay» intervalo de días a mostrar los datos históricos. según días en la celda A2.

• Asignación «getCountShowResults» número de periodos que se muestran mediante QUERY(): Aggregation Function count(). La condición QUERY(): Clause where muestra los días mediante el cálculo de la fecha actual TODAY() restando los días asignados y convirtiendo el patrón de fecha para el lenguaje consulta con la función TEXT(). La QUERY(): Clause label elimina la etiqueta.

• Asignación «getDatasHistoryOperate» obtenemos los valores a operar seleccionando la columna «Close» con un índice Col5 en QUERY(): Clause select, en orden descendente mediante QUERY(): Clause order by y limitado los resultados a calcular con QUERY(): Clause limit.

• Asignación «getPriceClose» asignamos «getDatasHistoryOperate», son los precios del cierre

• Asignación «getPriceClosePrevious» obtenemos los precios del cierre con un desfase de un periodo mediación de QUERY(): Clause offset.

• Asignación «getVar» resultado de restar las asignaciones anteriores por QUERY(): Clause select. Creando primero una matriz alineando precio y precio desfase con HSTACK().

• Asignación «getVarPercent» resultado de la división asignaciones anteriores restando uno. Creando primero una matriz alineando precio y precio desfase con HSTACK().

• Asignación «getShowResults» obtiene los resultados a mostrar creando matriz en horizontal HSTACK(),  limitando los los resultados QUERY(): Clause limit, creando encabezados con símbolos unicode QUERY(): Clause label y danto formato numérico de dos decimales y porcentual QUERY(): Clause format. Para activar los colores, copie el formato sin las comillas simples, seleccione la columna, pega el formato en formato numérico personalizado.

• Finalmente la función HSTACK() muestra los resultados de la asignación de nombre «getShowResults» en una matriz con la condición, si matriz no es cuadrada rellena para convertirla.

Ⓔ Propuesta Media móvil simple (SMA):

Ticker!I3:

=LET(getRangeDatasHistory;TickerHistory!A:F; getDays;A2; getLengthSma;I2;

getCountShowResults;QUERY(getRangeDatasHistory;"select count(Col1) where Col1 >= date '"&TEXT(TODAY()-getDays;"yyyy-mm-dd")&"' label count(Col1) ''");

getDatasHistoryOperate;QUERY(getRangeDatasHistory;"select Col5 order by Col1 desc limit "&getCountShowResults+getLengthSma;1);

getSma;MAP(SEQUENCE(getCountShowResults+getLengthSma;1;0;1);LAMBDA(getOffsetNext;LET(

getDataNext;QUERY(getDatasHistoryOperate;"Col1 limit "&getLengthSma&" offset "&getOffsetNext);

QUERY(getDataNext;"select avg(Col1) label avg(Col1) ''"))));

getShowResults;QUERY(getSma;"limit "&getCountShowResults&" label Col1 '🧱Sma: "&getLengthSma&"' format Col1 '#,##0.00'";1);

HSTACK(getShowResults))

 Ⓔ Propuesta detalle: 

Inserta la fórmula en «Ticker!I3».

• La función LET() asigna nombres descriptivos para clarificar su cometido. Su utilización parte de guardar las variables para no tener que volver a repetir funciones, en caso de modificar la fórmula meses después es práctico comprobar la estructura de la fórmula.

• Asignación «getRangeDatasHistory» obtiene el historial de datos históricos. Según ticket en la celda A1 y vinculada en la hoja «TickerHistory!A:F»

• Asignación «getDay» intervalo de días a mostrar los datos históricos. según días en la celda A2.

• Asignación «getLengthSma» periodos a calcular la media móvil simple. según criterio en celda I2

• Asignación «getCountShowResults» número de periodos que se muestran mediante QUERY(): Aggregation Function count(). La condición QUERY(): Clause where muestra los días mediante el cálculo de la fecha actual TODAY() restando los días asignados y convirtiendo el patrón de fecha para el lenguaje consulta con la función TEXT(). La QUERY(): Clause label elimina la etiqueta.

• Asignación «getDatasHistoryOperate» obtenemos los valores a operar seleccionando la columna «Close» con un índice Col5 en QUERY(): Clause select, en orden descendente mediante QUERY(): Clause order by y limitado los resultados a calcular con QUERY(): Clause limit.

• Asignación «getSma» obtenemos la media móvil simple. La función MAP() crea una matriz de números consecutivos usando SEQUENCE() limitando las operaciones solamente de los datos mostrados más un periodo para la última posición. LAMBDA() asignación «getOffsetNext» recorre la matriz de números consecutivos convertidos en valores (SMA). Creamos otra asignación de nombres interna empleado LET(). Asignación «getDataNext»  logramos el periodo de precio cierre limitado el periodo QUERY(): Clause limit de la longitud según criterio en Ticker!I2 y QUERY(): Clause offset logrando el desfase de cada periodo anterior. Finalmente la QUERY(): Aggregation Function avg() calcula la media y eliminamos la etiqueta que se genera automáticamente con QUERY(): Clause label.

• Asignación «getShowResults» obtiene los resultados a mostrar creando matriz en horizontal HSTACK(),  limitando los los resultados QUERY(): Clause limit, creando encabezados con símbolos unicode QUERY(): Clause label y danto formato numérico de dos decimales  QUERY(): Clause format..

• Finalmente la función HSTACK() muestra los resultados de la asignación de nombre «getShowResults» en una matriz con la condición, si matriz no es cuadrada rellena para convertirla.

Ⓕ Propuesta Índice de fuerza relativa (RSI) :

Insertar fórmula en Ticker!J3:

=LET(getRangeDatasHistory;TickerHistory!$A:$F; getDays;$A$2; getLengthRsi;$J$2;

getCountShowResults;QUERY(getRangeDatasHistory;"select count(Col1) where Col1 >= date '"&TEXT(TODAY()-getDays;"yyyy-mm-dd")&"' label count(Col1) ''");

getDatasHistoryOperate;QUERY(getRangeDatasHistory;"select Col5 order by Col1 desc limit "&getCountShowResults+getLengthRsi;1);

getPriceClose;getDatasHistoryOperate;

getPriceClosePrevious;QUERY(getDatasHistoryOperate;"offset 1";1);

getVar;QUERY(HSTACK(getPriceClose;getPriceClosePrevious);"select (Col1-Col2) label (Col1-Col2) ''");

getRsi;MAP(SEQUENCE(getCountShowResults+getLengthRsi;1;0;1);LAMBDA(getOffsetNext;LET(

getVarOperate;QUERY(getVar;"limit "&getLengthRsi&" offset "&getOffsetNext&" label Col1 ''");

getVarPositiveAvg;QUERY(getVarOperate;"select avg(Col1) where  Col1 > 0 label avg(Col1) ''");

getVarNegativeAvg;ABS(QUERY(getVarOperate;"select avg(Col1) where  Col1 < 0 label avg(Col1) ''"));

100-100/(1+(getVarPositiveAvg/getVarNegativeAvg)))));

getShowResults;QUERY(getRsi;"limit "&getCountShowResults&" label Col1 '💪Rsi: "&getLengthRsi&"' format Col1 '#,##0.00;#,##0.00;0.00'";1);

HSTACK(getShowResults))

Ⓕ Propuesta detalle:

Inserta la fórmula en «Ticker!J3».

• La función LET() asigna nombres descriptivos para clarificar su cometido. Su utilización parte de guardar las variables para no tener que volver a repetir funciones, en caso de modificar la fórmula meses después es práctico comprobar la estructura de la fórmula.

• Asignación «getRangeDatasHistory» obtiene el historial de datos históricos. Según ticket en la celda A1 y vinculada en la hoja «TickerHistory!A:F»

• Asignación «getDay» intervalo de días a mostrar los datos históricos. según días en la celda A2.

• Asignación «getLengthRsi» períodos a calcular el índice de fuerza relativa. según criterio en celda J2.

• Asignación «getCountShowResults» número de periodos que se muestran mediante QUERY(): Aggregation Function count(). La condición QUERY(): Clause where muestra los días mediante el cálculo de la fecha actual TODAY() restando los días asignados y convirtiendo el patrón de fecha para el lenguaje consulta con la función TEXT(). La QUERY(): Clause label elimina la etiqueta.

• Asignación «getDatasHistoryOperate» obtenemos los valores a operar seleccionando la columna «Close» con un índice Col5 en QUERY(): Clause select, en orden descendente mediante QUERY(): Clause order by y limitado los resultados a calcular con QUERY(): Clause limit.

• Asignación «getPriceClose» asignamos «getDatasHistoryOperate», son los precios del cierre

• Asignación «getPriceClosePrevious» obtenemos los precios del cierre con un desfase de un periodo mediación de QUERY(): Clause offset.

• Asignación «getVar» resultado de restar las asignaciones anteriores por QUERY(): Clause select. Creando primero una matriz alineando precio y precio desfase con HSTACK().

• Asignación «getRsi» obtenemos el índice de fuerza relativa. La función MAP() crea una matriz de números consecutivos usando SEQUENCE() limitando las operaciones solamente de los datos mostrados más un periodo para la última posición. LAMBDA() asignación «getOffsetNext» recorre la matriz de números consecutivos convertidos en valores (SMA). Creamos otra asignación de nombres interna empleado LET(). Asignación «getVarOperate» logramos cada periodo de precio cierre limitado el periodo QUERY(): Clause limit de la longitud según criterio en Ticker!I2 y QUERY(): Clause offset logrando el desfase de cada periodo anterior. Asignación «getVarPositiveAvg» calculamos la media QUERY(): Aggregation Function avg() con la condición de ser número positivo QUERY(): Clause where mayor de cero y eliminamos la etiqueta generada con QUERY(): Clause label. Asignación «getVarPositiveAvg» calculamos la media QUERY(): Aggregation Function avg() con la condición de ser número negativo QUERY(): Clause where menor de cero y eliminamos la etiqueta generada con QUERY(): Clause label. y convertimos en valor absoluto ABS(). Por último damos valor a «getRsi» en una matriz con la media ponderada para crear la relatividad y sumandole uno dividido entre cien y restar cien para dar el índice del uno a cien.

• Asignación «getShowResults» obtiene los resultados a mostrar creando matriz en horizontal HSTACK(),  limitando los los resultados QUERY(): Clause limit, creando encabezados con símbolos unicode QUERY(): Clause label y danto formato numérico de dos decimales

• Finalmente la función HSTACK() muestra los resultados de la asignación de nombre «getShowResults» en una matriz con la condición, si matriz no es cuadrada rellena para convertirla.

Ⓖ Propuesta resistencias (S/R) :

Ticker!K3:

=LET(getRangeDatasHistory;TickerHistory!$A:$F; getDays;$A$2; getLengthResistance;$K$2;

getCountShowResults;QUERY(getRangeDatasHistory;"select count(Col1) where Col1 >= date '"&TEXT(TODAY()-getDays;"yyyy-mm-dd")&"' label count(Col1) ''");

getLimitOperate;getDays*getLengthResistance;

getDatasHistoryOperate;QUERY(getRangeDatasHistory;"select Col3 order by Col1 desc limit "&getLimitOperate&" label Col3 ''";1);

getResistance;MAP(SEQUENCE(getCountShowResults+1;1;0;getLengthResistance);LAMBDA(getOffsetNext;LET(

getDataNext;QUERY(getDatasHistoryOperate;"limit "&getOffsetNext);

HSTACK(QUERY(getDataNext;"select max(Col1) label max(Col1) ''");getOffsetNext))));

getShowResults;QUERY(getResistance;" limit "&getCountShowResults&" label Col1 '⏫Resistencia', Col2 '🕗Periodo' format Col1 '#,##0.00', Col2 '(#,##0)'";1);

HSTACK(getShowResults) 

Ⓖ Propuesta detalle:

Inserta la fórmula en «Ticker!K3».

• La función LET() asigna nombres descriptivos para clarificar su cometido. Su utilización parte de guardar las variables para no tener que volver a repetir funciones, en caso de modificar la fórmula meses después es práctico comprobar la estructura de la fórmula.

• Asignación «getRangeDatasHistory» obtiene el historial de datos históricos. Según ticket en la celda A1 y vinculada en la hoja «TickerHistory!A:F»

• Asignación «getDay» intervalo de días a mostrar los datos históricos. según días en la celda A2.

• Asignación «getLengthResistance» períodos a calcular las resistencias (precio máximos según periodo celda K2.

• Asignación «getCountShowResults» número de periodos que se muestran mediante QUERY(): Aggregation Function count(). La condición QUERY(): Clause where muestra los días mediante el cálculo de la fecha actual TODAY() restando los días asignados y convirtiendo el patrón de fecha para el lenguaje consulta con la función TEXT(). La QUERY(): Clause label elimina la etiqueta.

• Asignación «getDatasHistoryOperate» obtenemos los valores a operar seleccionando la columna «High» con un índice Col3 en QUERY(): Clause select, en orden descendente mediante QUERY(): Clause order by índice Col1 pertenece a la columna «Date» y limitado los resultados a calcular con QUERY(): Clause limit.

• Asignación «getResistances» obtenemos las resistencias. La función MAP() crea una matriz de números consecutivos con un incremento de «getLengthResistance» usando SEQUENCE() limitando las operaciones solamente de los datos mostrados más un periodo para la última posición.  LAMBDA() asignación «getOffsetNext» recorre la matriz de números consecutivos con su incremento y convertirlos en en valores máximos. Creamos otra asignación de nombres interna empleado LET(). Asignación «getDataNext» obtenemos la cotización en el periodo con QUERY(): Clause limit que irá incrementado periodo + periodo ect. Finalmente creamos la matriz en horizontal  HSTACK() el cual obtenemos el valor máximo QUERY(): Aggregation Function max(). Eliminamos la etiqueta generada QUERY(): Clause label e incluimos al periodo que pertenece «getOffsetNext».

• Asignación «getShowResults» obtiene los resultados a mostrar, limitando los los resultados QUERY(): Clause limit, creando encabezados con símbolos unicode QUERY(): Clause label y danto formato numérico de dos decimales a la resistencia y sin decimales entre paréntesis a los periodos.

• Finalmente la función HSTACK() muestra los resultados de la asignación de nombre «getShowResults» en una matriz con la condición, si matriz no es cuadrada rellena para convertirla.

Ⓗ Propuesta soportes (S/R):

Ticker!M 3:

=LET(getRangeDatasHistory;TickerHistory!$A:$F; getDays;$A$2; getLengthResistance;$K$2;

getCountShowResults;QUERY(getRangeDatasHistory;"select count(Col1) where Col1 >= date '"&TEXT(TODAY()-getDays;"yyyy-mm-dd")&"' label count(Col1) ''");

getLimitOperate;getDays*getLengthResistance;

getDatasHistoryOperate;QUERY(getRangeDatasHistory;"select Col3 order by Col1 desc limit "&getLimitOperate&" label Col3 ''";1);

getResistance;MAP(SEQUENCE(getCountShowResults+1;1;0;getLengthResistance);LAMBDA(getOffsetNext;LET(

getDataNext;QUERY(getDatasHistoryOperate;"limit "&getOffsetNext);

HSTACK(QUERY(getDataNext;"select max(Col1) label max(Col1) ''");getOffsetNext))));

getShowResults;QUERY(getResistance;" limit "&getCountShowResults&" label Col1 '⏫Resistencia', Col2 '🕗Periodo' format Col1 '#,##0.00', Col2 '(#,##0)'";1);

HSTACK(getShowResults)) 

Ⓘ Propuesta media del precio apertura en resultados mostrados:

Fórmula enTicker!B2

=LET(getRangePriceOpen;B4:B;

getAveragePriceOpen;QUERY(getRangePriceOpen;"select avg(Col1) label avg(Col1) '' format avg(Col1) '🔄#,##0.00'");

getAveragePriceOpen) 

Ⓙ Propuesta precio máximo en resultados mostrados:

Formula en Ticker!C2

=LET(getRangePriceHigh;C4:C;

getMaxPriceHigh;QUERY(getRangePriceHigh;"select max(Col1) label max(Col1) '' format max(Col1) '⤴️#,##0.00'");

getMaxPriceHigh) 

Ⓚ Propuesta precio mínimo en resultados mostrados:

Formula en Ticker!D2

=LET(getRangePriceLower;D4:D;

getMinPriceLower;QUERY(getRangePriceLower;"select min(Col1) label min(Col1) '' format min(Col1) '⤵️#,##0.00'");

getMinPriceLower) 

Ⓛ Propuesta promedio precio cierre en los resultados:

Formula en Ticker!E2:

=LET(getRangePriceClose;$E$4:$E;

getAveragePriceClose;QUERY(getRangePriceClose;"select avg(Col1) label avg(Col1) '' format avg(Col1) '🔄#,##0.00'");

getAveragePriceClose) 

Ⓜ Propuesta promedio volumen en los resultados mostrados:

Formula en Ticker!F2

=LET(getRangeVolume;$F$4:$F;

getAverageVolume;QUERY(getRangeVolume;"select avg(Col1) label avg(Col1) '' format avg(Col1) '[>=1000000000000]🔄#,##0.00,,,,"&CHAR(34)&"B"&CHAR(34)&";[>=1000000]🔄#,##0.00,,"&CHAR(34)&"M"&CHAR(34)&";🔄#,##0.00,"&CHAR(34)&"K"&CHAR(34)&"'";1);

getAverageVolume)

Ⓝ Propuesta variación del precio de cierre. Respecto primer resultado y último resultado.

Formula en Ticker!G2:

=LET(getRangePriceClose;$E4:$E;

getFirstPriceClose;INDEX(getRangePriceClose;1;1);

getLastPriceClose;INDEX(getRangePriceClose;COUNT(getRangePriceClose);1);

getVarPriceClose;QUERY(MINUS(getFirstPriceClose;getLastPriceClose);"format Col1 '[blue]∆ +#,##0.00;[red]∆ -#,##0.00;∆ 0.00'");

getVarPercent;QUERY(1-(getLastPriceClose/getFirstPriceClose);"format Col1 '[blue]∆ +#,##0.00%;[red]∆ -#,##0.00%;∆ 0.00%'");

HSTACK(getVarPriceClose;getVarPercent))

Ⓞ Propuesta enlace cotización en Google Finance web.

Formula en Ticker!B1:

=LET(getTicker;$A$1;

getSymbolShare;CHOOSECOLS(SPLIT(getTicker;":");2);

getSymbolIndex;CHOOSECOLS(SPLIT(getTicker;":");1);

getLink;"https://www.google.com/finance/quote/";

getQuote;CONCATENATE(getSymbolShare;":";getSymbolIndex);

HYPERLINK(CONCAT(getLink;getQuote);"🌍Web")) 

Ⓟ Propuesta mini gráfico de barras.

Formula en Ticker!C1:

=LET(getRangePriceClose;E4:E;

getSizeCellHorizontal;4;

getMinPriceClose;min(getRangePriceClose);

getMaxPriceClose;max(getRangePriceClose);

HSTACK("⤵️🔒"&getMinPriceClose;

SPARKLINE(getRangePriceClose;{"charttype"\"column";"color"\"blue";"lowcolor"\"red";"highcolor"\"green";"empty"\"ignore";"nan"\"ignore";"ymin"\getMinPriceClose;"ymax"\getMaxPriceClose;"rtl"\TRUE()});

WRAPROWS(;getSizeCellHorizontal;);

"⤴️🔒"&getMaxPriceClose)) 

Ⓠ Propuesta Obtener compra ficticia: 

Formula en Ticker!I2: 

Resultados:

Demo Agradecimientos ScreenToGif :

Videos:

Descarga hoja cálculo Google: 

Referencias: