VBM-CBM of various surfaces and oxides

Reference: Seungchul Kim, Ofer Sinai, Chan-Woo Lee, and Andrew M. Rappe, “Controlling oxide surface dipole and reactivity with intrinsic nonstoichiometric epitaxial reconstructions” Phys. Rev. B 92, 235431 (2015)

============================================================================================================

##  Change BoundingBox in eps file as "%%BoundingBox: 62 68 400 235"

set term postscript eps color enhanced  18

set output 'EngLv_U_expgap_EFpin.eps'

set multiplot

set size 1,0.75 ; set size ratio 0.55

ymin=-9.0 ; ymax = 0 ; llw = 32

set lmargin 3 ; set rmargin 6 ; set bmargin 4

set xr[0.3:27.8]

set noxtics

set ylabel "Vacuum-relative energy level (eV)"

set yr[ymin:ymax]

set ytics -10,1,0

set mytics 5

set y2r[0:-ymin+ymax]

set key at 21.0,1.55

set grid lt 1 lc 9 lw 1.0

## partitioning between BTO, STO, Rutile and LFO

set arrow from  9.5,ymin to  9.5,ymax  lt 1 lc rgb 'black' lw 2 nohead

set arrow from 14.5,ymin to 14.5,ymax  lt 1 lc rgb 'black' lw 2 nohead

set arrow from 18.5,ymin to 18.5,ymax  lt 1 lc rgb 'black' lw 2 nohead

set nokey

set boxwidth 0.84

p 'EngLv_U_expgap.dat' u 1:($9+$10)                w imp lt 1 lc rgb 'light-red'  lw llw ,\

  'EngLv_U_expgap.dat' u 1:($8+$10-ymin) axe x1y2  w imp lt 1 lc rgb 'royalblue'  lw llw    ,\

  'EngLv_EF_unpin.dat' u 1:9                  w boxes lt 1 lw 2 lc rgb 'black'  ,\

  'EngLv_EF_unpin.dat' u 1:($8-ymin) axe x1y2 w boxes lt 1 lw 2 lc rgb 'black'

###### writting labels of structures, x label, etc

set noarrow

set nokey

set nogrid

## BTO

lbl=-8.8

lbh=-2.8

set label at  1-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14x}2) BaO"

set label at  2-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 1{/Helvetica=14 x}1 BaO DL"

set label at  3-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 1{/Helvetica=14 x}1 Ti_{2}O_{2}"

set label at  4-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 2{/Helvetica=14 x}2 Ti_{7/4}O_{2}"

set label at  5-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 3{/Helvetica=14 x}1 Ti_{5/3}O_{2}"

set label at  6-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14 x}2) Ti_{3/2}O_{2}"

set label at  7-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 2{/Helvetica=14 x}2 Ti_{5/4}O_{2}"

set label at  8-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(2{/Helvetica=14 x}2) TiO_{2}"

set label at  9-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 2{/Helvetica=14 x}1 TiO_{2} DL"

## STO

set label at 10-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 1{/Helvetica=14 x}1 SrO"

set label at 11-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 1{/Helvetica=14 x}1 TiO_{2}"

set label at 12-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(4{/Helvetica=14 x}2) TiO_2 DL"

set label at 13-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(2{/Helvetica=14 x}2) TiO_2 DL"

set label at 14-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 2{/Helvetica=14 x}1 TiO_2 DL"

## Ruitle         

set label at 15-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 2{/Helvetica=14 x}1 Ti_{1/2}O_{3/4}"

set label at 16-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 2{/Helvetica=14 x}1 Ti_{3/4}O_{5/4}"

set label at 17-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 1{/Helvetica=14 x}2 TiO_{7/4}"

set label at 18-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 1{/Helvetica=14 x}1 TiO_{2}"

## LFO

set label at 19-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14x}2) LaO"

set label at 20-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14x}2) LaO_{3/2}"

set label at 21-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14x}2) LaO_{2}"

set label at 22-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14x}2) Fe"

set label at 23-0.1,lbl rotate by 90 tc rgb 'white' "{/Helvetica=12 c(2{/Helvetica=14x}2) FeO_{1/2}"

set label at 24-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(2{/Helvetica=14x}2) FeO"

set label at 25-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(2{/Helvetica=14x}2) FeO_{2}"

set label at 26-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(2{/Helvetica=14x}2) FeO_{7/2}"

set label at 27-0.1,lbh rotate by 90 tc rgb 'black' "{/Helvetica=12 c(2{/Helvetica=14x}2) FeO_{4}"

##  x label

set label at  2  ,-9.8  "{/Times-Roman=16 BaTiO_{3} (001)}"

set label at  9.8,-9.8  "{/Times-Roman=16 SrTiO_{3} (001)}"

set label at 14.8,-9.8  "{/Times-Roman=16 TiO_{2} (110)}"

set label at 21.0,-9.8  "{/Times-Roman=16 LaFeO_{3} (010)}"

## legend

#set arrow from  8.0,1.3 to 11,1.3 lt 1 lc rgb 'light-red' lw 20 nohead

#set arrow from  8.0,0.7 to 11,0.7 lt 1 lc rgb 'royalblue' lw 20 nohead

#set label at    5.0,1.3 "{/Helvetica=14 CBM_b}"

#set label at    5.0,0.7 "{/Helvetica=14 VBM_b}"

set ylabel " "

##  Bulk terminations

set label "{/=24 *}" tc rgb 'black' at  1-0.2,  0.1

set label "{/=24 *}" tc rgb 'black' at  8-0.2,  0.1

set label "{/=24 *}" tc rgb 'black' at 10-0.2,  0.1

set label "{/=24 *}" tc rgb 'black' at 11-0.2,  0.1

set label "{/=24 *}" tc rgb 'black' at 18-0.2,  0.1

set label "{/=24 *}" tc rgb 'black' at 19-0.2,  0.1

set label "{/=24 *}" tc rgb 'black' at 25-0.2,  0.1

## Metallic surface

set label "{/=12 M}" tc rgb 'black' at  3-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at  4-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at  5-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at  6-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at  7-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 15-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 16-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 17-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 20-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 21-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 22-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 24-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 25-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 26-0.3, -0.1

set label "{/=12 M}" tc rgb 'black' at 27-0.3, -0.1

set y2r[ymin:ymax]

set y2tics out

set y2tics ('O_{2}/H_{2}O' -5.266, 'H^{+}/H_{2}' -4.026, '' -3.79 ,'' -3.64, '' -3.41) font "Helvetica,14"

set label "CO_2/CH_4"    font "Helvetica,14" at 28.5,-3.2

set label "CO_2/CH_3OH"  font "Helvetica,14" at 28.5,-2.5

set label "CO_2/HCOOH"   font "Helvetica,14" at 28.5,-1.8

set arrow from 28.1, -3.79 to 28.45,-3.2 lt 1 lw 1 lc rgb 'black' nohead

set arrow from 28.1, -3.64 to 28.45,-2.5 lt 1 lw 1 lc rgb 'black' nohead

set arrow from 28.1, -3.41 to 28.45,-1.8 lt 1 lw 1 lc rgb 'black' nohead

p ymax+1