potential drop at the surface
Reference: Seungchul Kim, Ofer Sinai, Chan-Woo Lee, and Andrew M. Rappe, “Controlling oxide surface dipole and reactivity with intrinsic nonstoichiometric epitaxial reconstructions” Phys. Rev. B 92, 235431 (2015)
=========================================================================================================
set term postscript eps color enhanced
set encoding iso_8859_1
set output 'BTO_bulkterm_drho_avg.eps'
alat= 4.036
vacti=0.29994E+01
vacba=0.10850E+01
yrv=12
yrr=0.2
## BaO term
bba1 = 14.047138969 ; bti1 = 12.178400868
bba2 = 10.077888813 ; bti2 = 8.089691766
bba3 = 6.053999700 ; bti3 = 4.035999800
bba4 = 2.017999900 ; bti4 = 0.000000000
## TiO2 term
tba1 = 12.215359932 ; tti1 = 14.021126498
tba2 = 8.074538640 ; tti2 = 10.076364657
tba3 = 4.035999800 ; tti3 = 6.053999700
tba4 = 0.000000000 ; tti4 = 2.017999900
set size 0.8,0.8
set tmargin 3.5
set xr[alat*0.5:22]
set xlabel "{/Times-Itallic=18 z}{/Times-Roman=18, BaO termination}" tc lt 1
set xtics tc lt 1
set xtics font 'Helvetica'
set xtics ('TiO_2' bti1,'TiO_2' bti2,'TiO_2' bti3,'TiO_2' bti4 ,\
'BaO' bba1,'BaO' bba2,'BaO' bba3,'BaO' bba4 )
set xtics nomirror
set x2label "{/Times-Itallic=18 z}{/Times-Roman=18, TiO_2 termination}" tc lt 3
set x2tics ('TiO_2' tti1,'TiO_2' tti2,'TiO_2' tti3,'TiO_2' tti4,\
'BaO' tba1,'BaO' tba2,'BaO' tba3,'BaO' tba4)
set x2tics nomirror
set x2tics tc lt 3
set yr[-yrv:yrv]
set ylabel "{/Symbol {/=16 @^{{ } \276}}D}{/Times-Roman V (Volt)}"
set ytics ('-6' -yrv/2-6,'-4' -yrv/2-4,'-2' -yrv/2-2 , '0' -yrv/2, '2' -yrv/2+2,'4' -yrv/2+4 ,' ' -yrv/2+6 ,\
'-4' yrv/2-4,'-2' yrv/2-2 , '0' yrv/2, '2' yrv/2+2,'4' yrv/2+4, '6' yrv/2+6)
set ytics nomirror
set y2r[-yrr:yrr]
set y2label "{/Symbol {/=16 @^{{ } \276}}Dr} {/Times-Roman (|{/Times-Itallic e}|/u.c./\305)}"
set y2tics ('-0.1' -yrr/2-0.1,'-0.05' -yrr/2-0.05 , '0' -yrr/2, '0.05' -yrr/2+0.05,'0.1' -yrr/2+0.1 ,\
' ' yrr/2-0.1,'-0.05' yrr/2-0.05 , '0' yrr/2, '0.05' yrr/2+0.05,'0.1' yrr/2+0.1)
set y2tics nomirror
p 'bto_c2x2_tio2.drho.dat' u 1:((-$3)/2 + yrr/2) axe x1y2 w l lt 1 lc 3 lw 2 t "{/Symbol {/=16 @^{{ } \276}}Dr}, TiO_2" ,\
'bto_c2x2_tio2.dVst.dat' u 1:((-$3) + yrv/2 +vacti) axe x1y1 w l lt 4 lc 3 lw 2 t "{/Symbol {/=16 @^{{ } \276}}D{/Times-Roman V}}, TiO_2" ,\
'bto_c2x2_bao.drho.dat' u 1:((-$3)/2 -yrr/2) axe x1y2 w l lt 1 lc 1 lw 4 t "{/Symbol {/=16 @^{{ } \276}}Dr}, BaO" ,\
'bto_c2x2_bao.dVst.dat' u 1:((-$3) -yrv/2 +vacba) axe x1y1 w l lt 4 lc 1 lw 4 t "{/Symbol {/=16 @^{{ } \276}}D{/Times-Roman V}}, BaO" ,\
yrv/2 lt 1 lw 1 lc 7 t '',\
-yrv/2 lt 1 lw 1 lc 7 t ''