multiplot -- potential and layer-projected DOS
set term postscript eps enhanced 16
set output 'sto_sro_VstPDOS.eps'
zcell = 47.36400000
Vvac = 8.36396
Vcnt = 3.620
CBM = 6.34060
BGC = 5.54535
VBM = 4.75010
dcell = 3.947
# Gap (eV) = 1.59050
# VBM, CBM (eV) = 4.75010 6.34060
# Fermi Energy (eV) = 5.54535
xtio4 = 0.00000 ; xsro4 = 1.972
xtio3 = 3.948 ; xsro3 = 5.913
xtio2 = 7.900 ; xsro2 = 9.830
xtio1 = 11.88 ; xsro1 = 13.7
set multiplot
ymin=-9 ; ymax=1
xmin=-1.5 ; xmax=18
set size 0.55,0.55
set origin 0.0,0.0
set xr[xmin:xmax]
set yr[ymin:ymax]
set xtics -20,4,35
set ytics -10,2,2
set xtics nomirror
set xlabel "Surface Normal Direction (Ang)"
set ylabel "V - V_{vac} (Volt)"
set y2tics (' ' 0)
set y2label " "
set key samplen 1
set nokey
set x2tics ("" xtio4,"" xsro4,"" xtio3,"" xsro3,"" xtio2,"" xsro2,"" xtio1,"" xsro1)
set tmargin 0
set label "TiO_{2}" at xtio4,ymax-2 rotate by 90
set label "SrO " at xsro4,ymax-2 rotate by 90
set label "TiO_{2}" at xtio3,ymax-2 rotate by 90
set label "SrO " at xsro3,ymax-2 rotate by 90
set label "TiO_{2}" at xtio2,ymax-2 rotate by 90
set label "SrO " at xsro2,ymax-2 rotate by 90
set label "TiO_{2}" at xtio1,ymax-2 rotate by 90
set label "SrO " at xsro1,ymax-2 rotate by 90
p 'sto_pbe_117_srosro.Vst.dat' u 1:($2-Vvac) w l lt 1 lw 3 lc 9 t 'V_{static}',\
'sto_pbe_117_srosro.Vst.dat' u 1:($4-Vvac) w l lt 1 lw 3 lc 7 t 'V@^{avg}_{static}' ,\
'sto_pbe_117_srosro.Vst.dat' u (-$1):($2-Vvac) w l lt 1 lw 3 lc 9 t 'V_{static}',\
'sto_pbe_117_srosro.Vst.dat' u (-$1):($4-Vvac) w l lt 1 lw 3 lc 7 t 'V@^{avg}_{static}'
###################################################################33
set nolabel
set size 0.5635,0.45
set origin 0.0,0.55
set noxlabel
set noy2tics
set noy2label
set xr[xmin:xmax]
set yr[ymin:ymax]
set y2range[ymin+Vvac-BGC:ymax+Vvac-BGC]
set noxtics
set ytics -10,2,2
set ytics nomirror
set y2tics -10,2,10
set ylabel "E-|e|V_{vac} (eV)"
set y2label "E - BGC (eV)"
set nox2tics
#set x2label "Layer-projected DOS (arb. unit)"
set arrow from xmin,CBM-Vvac to xmax,CBM-Vvac lt 1 lw 2 lc 9 nohead
set arrow from xmin,VBM-Vvac to xmax,VBM-Vvac lt 1 lw 2 lc 9 nohead
set bmargin 0
set tmargin 2
p 'pdos_brd100meV_1stlay.dat' u ($2*1.0+(xtio1+xsro1)*0.5):($1-Vvac) w l lt 1 lc 3 lw 3 ,\
'pdos_brd100meV_2ndlay.dat' u ($2*1.0+(xtio2+xsro2)*0.5):($1-Vvac) w l lt 1 lc 3 lw 3 ,\
'pdos_brd100meV_3rdlay.dat' u ($2*1.0+(xtio3+xsro3)*0.5):($1-Vvac) w l lt 1 lc 3 lw 3 ,\
'pdos_brd100meV_4thlay.dat' u ($2*1.0+(xtio4+xsro4)*0.5):($1-Vvac) w l lt 1 lc 3 lw 3