Self-Regulating Isopod Enclosure

Project Outcome

Process & Review

My process for creating my final prototype consisted of two rounds of ideation sketching and the creation of cardboard prototypes for the ultrasonic humidifier and the peristaltic pump. 

The sketches gave me a visual layout of how these components would be integrated into the isopods' enclosure:

• The temperature and humidity sensor

• The ultrasonic humidifier

• The soil moisture sensor

• The irrigation system 

The physical cardboard prototypes allowed me to find an optimal size for the clear acrylic "shelf" where the ultrasonic sensor's water supply source would be placed. I chose to make this shelf out of clear acrylic so as not to obstruct my view of the enclosure from a bird's eye view and to prevent molding, which I was worried about when initially considering using wood for the "shelf's" material. Additionally, the other cardboard prototype allowed me to measure the circumference of the peristaltic pump so it could be propped up above the water supply source and allow for greater flow for the irrigation system inside the tank. 

While mocking up the physical aspects of my design, I also worked on wiring up the hardware and conducting software testing. For the most part, this part went well and without little issues until I started soldering the project's wires onto a perf board. One problem, which was a simple fix after my classmate Nenna pointed out, was that my prototype was not working because I had soldered the power to my Arduino to ground and my ground to power; thankfully, this did not harm my computer or any of the other components in any way. Another issue that I was having trouble with was correctly mapping the values of the temperature sensor to the LCD (as seen in the outcomes photo above); when I first began mapping out the temperature and humidity, everything seemed to display accurately, but this may have been an issue because I might have inserted old error-riddled code into my final code.

This is the second round of ideation sketching for prototype components, placement, and containers to house additional hardware.

Cardboard physical prototype(s) to house part of the ultrasonic humidifier (right) and prototype to support the peristaltic pump, LCD, and additional hardware (left).

Testing ultrasonic humidity sensor with Arduino and small water dish.

Technical Information

Code

/* 

 Physical Computing Project 2: Self-Regulating Isopod Enclosure | Audrey Reiley

The project aims to maintain optimal conditions within my isopod enclosure by automatically regulating soil moisture levels, monitoring temperature and humidity, and administering water if necessary through a humidifier. This code initializes sensor instances, pins for controlling the pump and humidifier, and sets up the OLED display. In the loop() function, my code continuously reads sensor data, updates sensor readings, displays the data on both the OLED display and the serial monitor, adjusts humidity if necessary, checks soil moisture, controls the pump accordingly, and then turns off the pump after a delay.

Sources:

https://learn.adafruit.com/monochrome-oled-breakouts/arduino-library-and-examples

https://learn.sparkfun.com/tutorials/soil-moisture-sensor-hookup-guide/all#soil-moisture-sensing-project

https://www.circuitbasics.com/how-to-set-up-the-dht11-humidity-sensor-on-an-arduino/ 

https://chat.openai.com/ (for slight trouble shooting)

Pin Mapping:

Arduino pin | Role        | Details

--------------------------------

DHT_PIN     | Input       | DHT11 sensor pin

pumpPin     | Output      | Relay control pin for pump

soilMoisturePin | Input   | Analog pin to read soil moisture

HUMIDIFIERPIN | Output    | Relay control pin for humidifier

*/

#include <DHT.h>

#include <SPI.h>

#include <Wire.h>

#include <Adafruit_GFX.h>

#include <Adafruit_SSD1306.h>

// Pin definitions

const int DHT_PIN = 2;

const int pumpPin = 3;

const int soilMoisturePin = A3;

const int HUMIDIFIERPIN = 4;

// Create DHT sensor instance

DHT myDHT(DHT_PIN, DHT11);

// Variables to store sensor readings

float tempC = 0;

float tempF = 0;

float humidity = 0;

int moisturePercentage = 0;

// Ideal humidity and moisture levels

const float IDEAL_HUMIDITY_MIN = 45.0;

const float IDEAL_HUMIDITY_MAX = 55.0;

const int IDEAL_MOISTURE_THRESHOLD = 70;

// OLED display parameters

#define SCREEN_WIDTH 128

#define SCREEN_HEIGHT 64

#define OLED_RESET -1

#define SCREEN_ADDRESS 0x3C

// Create display instance

Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);

// Setup function

void setup() {

  Serial.begin(9600); // Start serial communication

  Serial.println("Hi");

  // Initialize DHT sensor

  myDHT.begin();

  // Set pump and humidifier pins as outputs

  pinMode(pumpPin, OUTPUT);

  pinMode(HUMIDIFIERPIN, OUTPUT);

  // Initialize OLED display

  if (!display.begin(SSD1306_SWITCHCAPVCC, SCREEN_ADDRESS)) {

    Serial.println(F("SSD1306 allocation failed"));

    for (;;);

  }

  // Clear and display the OLED

  display.display();

  delay(2000);

  display.clearDisplay();

  display.display();

}

// Loop function

void loop() {

  // Read soil moisture sensor

  int soilMoistureValue = analogRead(soilMoisturePin);

  moisturePercentage = map(soilMoistureValue, 0, 1023, 0, 100);

  // Update sensor readings

  updateSensorReadings();

  // Display sensor data on OLED and serial monitor

  displaySensorData();

  // Adjust humidity if necessary

  adjustHumidity();

  // Check soil moisture and control pump accordingly

  checkSoilMoisture();

  // Turn off pump after delay and display OLED

  turnOffPump();

  display.display();

  delay(1000);

}

// Function to update sensor readings

void updateSensorReadings() {

  tempC = myDHT.readTemperature();

  tempF = myDHT.readTemperature(true);

  humidity = myDHT.readHumidity();

}

// Function to display sensor data

void displaySensorData() {

  Serial.print("Soil Moisture: ");

  Serial.print(moisturePercentage);

  Serial.println("%");

  Serial.print("Temperature (C): ");

  Serial.print(tempC);

  Serial.print(" Temperature (F): ");

  Serial.print(tempF);

  Serial.print(" Humidity (%): ");

  Serial.println(humidity);

  delay(2000);

  // Display data on OLED

  display.clearDisplay();

  display.setTextSize(1);

  display.setTextColor(SSD1306_WHITE);

  display.setCursor(0, 0);

  display.print("Temp: ");

  display.print(tempC);

  display.println(" C");

  display.print("Humidity: ");

  display.print(humidity);

  display.println("%");

  display.print("Soil Moisture: ");

  display.print(moisturePercentage);

  display.println("%");

}

// Function to adjust humidity

void adjustHumidity() {

  if (humidity < IDEAL_HUMIDITY_MIN || humidity > IDEAL_HUMIDITY_MAX) {

    Serial.println("Adjust humidity...");

    if (humidity < IDEAL_HUMIDITY_MIN) {

      digitalWrite(HUMIDIFIERPIN, HIGH);

      Serial.println("Humidifier is ON");

    }

  }

}

// Function to check soil moisture and control pump

void checkSoilMoisture() {

  if (moisturePercentage < IDEAL_MOISTURE_THRESHOLD) {

    Serial.println("Soil moisture below threshold - Turning ON pump");

    turnOnPump();

    delay(5000);

  }

  if (moisturePercentage > IDEAL_MOISTURE_THRESHOLD) {

    turnOffPump();

    Serial.println("Pump turned OFF");

  }

}

// Function to turn on the pump

void turnOnPump() {

  digitalWrite(pumpPin, HIGH);

}

// Function to turn off the pump

void turnOffPump() {

  digitalWrite(pumpPin, LOW);

}