Photo of our team, our client Drayton, and his mother Nancy the day of our final critique.

Introduction

We first meet with our client Drayton at the CLASS facilities to learn more about his daily routine through an interview to identify any issues he had in his daily life. This led us to prototyping our Bedside Pocket sorter for Drayton. To ensure that the device had all of the features and functions Drayton wanted, we designed two cardboard prototypes for him to review. We also reached out to his mother Nancy to gain more detailed information about his likes, dislikes and alternative music that we could use for the music portion of our device's functions. Drayton offered various information such as, but not limited to: his favorite color (orange) his love for sushi and the Pittsburgh Penguins, and a desire for our team to place our signatures on the device. This collaborative effort with our client helped us make informed discussions about the device's design so that it could not only address his needs but also to appeal to his aesthetic wants.

What We Built 

Our device holds a watch, a wallet, and a phone, and has an screen that will display which items do not have something in their assigned slot. When each slot is filled, our device shines blue lights and plays Farewell, a soothing piece of music composed by Nelson Foltz, before shutting off a minute later. 

Brief video showing the interactions and functions of the device: placing wallet, phone and watch in their designated areas, blue light turning on, and client's brother's music Nelson Band's song "Farewell" playing.

Detailed Images

How We Got Here 

Our greatest challenge as a team was trying to create a device that would both be small enough to please our client and be useful to him, while also being able to hold all of our wiring. We were told at first that the available space was so small that our final product ought to be about the size of a deck of cards; however, we explained why that wasn't a realistic goal, and ended up with a relatively small box that could still handle a lot of what we wanted it to.

Our second greatest challenge was the MP3 player and speaker. Try as we might, it took us two separate videos and three different libraries and coding attempts to get it to work; and even then, we had to change speakers to get the sound to come out properly. With help from classmates and the professor, though, we managed to get it to play "Farewell" correctly.

We planned for our final product to hold everything Drayton might have in his pockets, to remind him to store his items before he went to bed, and to play relaxing music and shine soft blue lights to help him go to sleep once he'd finished his nighttime routine. In the end, we were able to accomplish all of those goals; By talking to Drayton, we learned that the main things he needed to store were his phone, wallet, keys, and watch. As he kept his keys in his watch, we knew we would only need three receptacles in total.  

Another source of inspiration and help for us was Drayton's mother, Nancy Foltz. She was an enormous help, and we can't thank her enough; she gave us excellent constructive criticism to keep the box both useable and useful, as well as giving us the music our device ultimately would play for Drayton- "Farewell", by his brother Nelson. Staying in email contact with her was a huge boon.

Prototype & Process

Process Images

Technical information

/*

Bedside Pocket Sorter

Detects the presence of objects and plays a sequence (shines an LED strip and plays a song) when all the objects are detected

Code written for an Arduino Uno circuit board.

pin mapping:

Arduino pin |   role | macro name | description

___________________________________________________________________

A0          input     SENSOR_PHONE  Reads phone proximity sensor

A1          input     SENSOR_WALLET Reads wallet proximity sensor

A2          input     SENSOR_WATCH  Reads watch proximity sensor

6           output    LED_PIN       Sends Data to the LED strip

10          input     SPEAKER_RX    Receives data from the speaker

11          output    SPEAKER_TX     Transmits data to the speaker

Credit to:

   NeoPixel Ring simple sketch (c) 2013 Shae Erisson

Code released to the public domain by the author, 04/03/2024

Aiden Magee, amagee@andrew.cmu.edu

*/

#include <LiquidCrystal_I2C.h>

#include <mp3tf16p.h>

#include <Adafruit_NeoPixel.h>

#ifdef __AVR__

#include <avr/power.h>

#endif

#define LED_PIN        6

#define NUM_PIXELS 27

#define SENSOR_PHONE A0

#define SENSOR_WALLET A1

#define SENSOR_WATCH A2

#define SPEAKER_RX 10

#define SPEAKER_TX 11

#define PHONE_RANGE 100

#define WALLET_RANGE 100

#define WATCH_RANGE 100

#define printInterval 2000

bool prevItemsPlaced = false;

bool itemsPlaced = false;

float lastPrintTime = 0;

bool ledsOn = false;

float sequenceStart;

// Keep the leds on for a minute

const float ledDuration = 60.0*1000.0;

MP3Player mp3(SPEAKER_RX, SPEAKER_TX);

Adafruit_NeoPixel pixels(NUM_PIXELS, LED_PIN, NEO_GRB + NEO_KHZ800);

LiquidCrystal_I2C lcd(0x27,20,4);

void lcd_print(bool phoneDetected, bool walletDetected, bool watchDetected)

{

 lcd.clear();

 lcd.home();

 if (itemsPlaced){

   lcd.print("Goodnight Drayton");

 }

 else{

   String firstRow = "Missing: ";

   String secondRow = "";

   if (!phoneDetected){

     firstRow += "PHONE ";

   }

   if (!walletDetected){

     secondRow += "WALLET ";

   }

   if (!watchDetected){

     secondRow += "WATCH";

   }

   lcd.print(firstRow);

   lcd.setCursor(0,1);

   lcd.print(secondRow);

 }

}

void setup() {

 delay(1000);

 lcd.init();

 lcd.backlight();

  pixels.begin(); // INITIALIZE NeoPixel strip object (REQUIRED)

 mp3.initialize();

 pinMode(SENSOR_PHONE, INPUT);

 pinMode(SENSOR_WALLET, INPUT);

 pinMode(SENSOR_WATCH, INPUT);

 Serial.begin(9600); // starts serial communication at 9,600 baud (the rate)

}

void loop() {

 int phoneVal = analogRead(SENSOR_PHONE);

 int walletVal = analogRead(SENSOR_WALLET);

 int watchVal = analogRead(SENSOR_WATCH);

 bool phoneDetected = (phoneVal > PHONE_RANGE);

 bool walletDetected = (walletVal > WALLET_RANGE);

 bool watchDetected = (watchVal > WATCH_RANGE);

 Serial.println("phoneVal");

 itemsPlaced = phoneDetected && walletDetected && watchDetected;

 if (itemsPlaced && !prevItemsPlaced){

   ledsOn = true;

   sequenceStart = millis();

   // Initiate the sequence

   pixels.fill(0x0000FF, 0, 27);

   pixels.show();

   mp3.playTrackNumber(1,100, false);

 }

 else if (prevItemsPlaced && !itemsPlaced){

   ledsOn = false;

   // Stop the sequence

   pixels.clear();

   pixels.show();

   // Is there a better way to stop the song?

   mp3.initialize();

   delay(500);

 }

 // If the leds have been on for longer than the set duration

 if (ledsOn && (millis() - sequenceStart) > ledDuration){

   pixels.clear();

   pixels.show();

 }

 if (millis() - lastPrintTime > printInterval){

   lcd_print(phoneDetected, walletDetected, watchDetected);

   lastPrintTime = millis();

 }

 //lcd_print(phoneDetected, walletDetected, watchDetected);

 Serial.println(phoneVal); // push the most recent value to the computer

 prevItemsPlaced = itemsPlaced;

 delay(100); // slow the loop down a bit before it repeats

}