CDC Action Zone

Post date: 29-Jul-2014 14:34:03

วันนี้ลุงจะให้ระบบใหม่ที่เพิ่มการ ซื้อ/ขาย เมื่อเกิด Pullbacks ใน Up trend และ Rallies ใน Down trend ลุงตั้งชื่อระบบนี้ว่า CDC Action Zone

{CDC Action Zone}

{Chaloke 20140514}

{Variables}

X:=9; {Fast}

Y:=21; {Slow}

{Fast Moving Average}

Fst:=Mov(C,X,E); Fst;

{Slow Moving Average}

Slw:=Mov(C,Y,E);

Slw:=Ref(Slw,(X-Y)); Slw;

{Trend}

Bullish:=Fst>Slw;

Bearish:=Fst<Slw;

{PreBuy}{Blue}

PreBuy:=Bearish AND C>Max(Fst,Slw);

{Buy}{Green}

Buy:=Bullish AND C>Max(Fst,Slw);

{Correction}{Yellow}

Correction:=Bullish AND C<Fst AND C>Slw;

{PreSell}{Black}

PreSell:=Bullish AND C<Min(Fst,Slw);

{Sell}{Red}

Sell:=Bearish AND C<Min(Fst,Slw);

{Rally}{Pink}

Rlly:=Bearish AND C>Fst AND C<Slw;

Area ในระหว่างเส้นสีแดงและเส้นสีน้ำเงิน เป็น Action Zone คือเป็น Zone ที่นักลงทุนสามารถมี Action พิเศษนอกเหนือจากการซื้อขายตามระบบ เขียว/แดง ลูกศรแรกจะปลอดภัยกว่าลูกศรต่อๆมา นักลงทุนควรพิจารณาความเสี่ยงเอาเองจาก Indicators อื่นๆ

กำหนดสีต่างๆให้สอดคล้องกับสภาพของตลาด

{PreBuy}{Blue}

{Buy}{Green}

{Pull back}{Yellow}

{PreSell}{Black}

{Sell}{Red}

{Rally}{Pink}

เมื่อตลาดอยู่ใน Bullish หลังจากเข้าซื้อตามสัญญาณ เขียว/แดง แล้ว สามารถซื้อเพิ่มได้ที่สัญญาณ Pull back สีเหลือง สำหรับมือใหม่ให้ซื้อที่ Pull back ครั้งแรกครั้งเดียว แต่ผู้ที่เก่งแล้วก็สามารถใช้สัญญาณอื่นๆได้ แต่ต้องพิจารณาความเสี่ยงจากความกว้างของ Action Zone และตำแหน่งของ RSI ประกอบ และเมื่อตลาด Bearish ก็ Short เพิ่มตามสัญญาณ Rally

สำหรับสมาชิกที่เขียนสูตรเป็นแล้ว ก็สามารถทำ Action Zone ให้เป็นสีอ่อนเป็น Area ได้ โดยใช้สูตรนี้

{Zone}{White}

Odd:=Cum(1)/2=Int(Cum(1)/2);

BullO:=If(Fst>Slw,If(Odd=1,Fst,Slw),Slw); BullO;

BullE:=If(Fst>Slw,If(Odd=0,Fst,Slw),Slw); BullE;

BearO:=If(Fst<Slw,If(Odd=1,Fst,Slw),Slw); BearO;

BearE:=If(Fst<Slw,If(Odd=0,Fst,Slw),Slw); BearE;

สัญญาณซื้อครั้งแรกใน Action Zone มีเป้าหมายระยะสั้นที่ 61.8% และระยะปานกลางที่ 100% การ ซื้อ/ขาย ใน Action Zone ควรเป็นการลงทุนระยะสั้น โดยใช้เงินกู้ยืมจากบัญชีจริงตามระบบ

สัญญาณซื้อครั้งที่สองใน Action Zone มีเป้าหมายระยะสั้นที่ 61.8% และระยะปานกลางที่ 100% เช่นเดียวกัน ส่วนสัญญาณซื้อครั้งต่อๆไป ก็จะเพิ่มความเสี่ยงขึ้นเรื่อยๆ ดังนั้นจึงต้องระวังเรื่อง Position sizing ให้ดี อย่าโลภ อย่า over-trade

http://www.chaloke.com/content/pullbacks-and-rallies