Fields of moduli of algebraic curves

Here is the Magma code used in the paper:

"Fields of moduli and fields of definition of odd signature curves",

by Michela Artebani and Saúl Quispe.

Copy the following code and past it in a Magma session

//To find the tangency points $b_{j,1}, b_{j,2}$ on $X$:

K<rho>:=CyclotomicField(12);

i:=rho^3;

R<x>:=PolynomialRing(K);

p:=(x^2-1)^2-4*(x-(1+i))*(x+1/(1-i))*(x-2*(i-1))*(x-1/(2*(1+i)));

L<a>:=ext<K|p>;

S<x>:=PolynomialRing(L);

p1:=Factorization(S!p)[2][1];

T<b>:=ext<L|S!p1>;

M<x>:=PolynomialRing(T);

p2:=Factorization(M!p1)[2][1];

U<c>:=ext<T|p2>;

N<x>:=PolynomialRing(U);

Factorization(N!p);

A<u,v>:=AffineSpace(U,2);

Q:=Scheme(A,u^4+u^2*(v^2-1)+(v-(1+i))*(v+1/(1-i))*(v-2*(i-1))*(v-1/(2*(i+1))));

I:=Q meet Scheme(A,v-a);

PrimeComponents(I);

//and to prove that $\gamma$ is not an automorphism of $X$:

W<bi>:=ext<U|x^2 + 1/2*a^2 - 1/2>;

P<g,h,l,t>:=PolynomialRing(W,4);

F:=FieldOfFractions(P);

R<x,y,z>:=PolynomialRing(F,3);

A:=Matrix(R,3,3,[a*g,a*g,h,bi*g,-bi*g,0,g,g,l]);

D:=Matrix(F,3,3,[rho^4,0,0,0,rho^8,0,0,0,1]);

M:=A*D*A^(-1)*Determinant(A);

E:=Eltseq(M*Matrix(R,3,1,[x,y,z]));

m:=hom<R->R|E>;

Q:=y^4+y^2*(x^2-z^2)+(x-(1+i)*z)*(x+1/(1-i)*z)*(x-2*(i-1)*z)*(x-1/(2*(i+1))*z);

C:=Coefficients(m(Q)-t^(12)*Q);

H:=[P!C[n]:n in [1..15]];

G:=Proj(P);

S:=Scheme(G,H);

Z:=Scheme(G,P!t^(12));

Difference(S,Z);