Chrome ユーザープロファイルデータベース最適化

Chrome User Profile database optimizer

About this command.

Summary

Chrome User Profile, sqlite3 data base の vacume を一括で実行.

Required

http://www.sqlite.org/download.html から Precompiled Binaries for Windows の zip を download

Usage

• >chm-db-optz [chrome user profile directory]

まとめて管理しているなら, root directory を CHROME_PROFILE_ROOT に埋め込んでもよいでしょう(私はそうしている

Code

chm-db-optz.bat

1. @echo off
2. rem REVISION LOG ENTRY
3. rem
4. rem File name : chm-db-optz.bat
5. rem Revision By: (C) Copyright 2013 Hiroyuki Tominaga, All Rights Reserved.
6. rem
7. rem Revised on: 2013-09-26 02:10:36
8. rem Summary : chrome user profile の sqlite db 最適化を行う bat file.
11. SETLOCAL EnableDelayedExpansion
13. set DEBUG=
14. set CHROME_PROFILE_ROOT=%1
16. set list=
17. rem
18. rem 厳密にするなら, "SQLite format 3" としたほうがよい.
19. rem
20. set CML=findstr /sbm /c:"SQLite format"
21. rem unused
22. set CURRENT_ROOT=
24. set path=%path%;%~dp0
26. rem move to working directory.
27. pushd %CHROME_PROFILE_ROOT%
29. for /d %%i in (*) do (
30. set list="%%i" !list!
31. )
32. echo ------------------------------------------------------------------------------
33. echo.
34. echo Start Google Chrome sqlite db optimize task.
35. echo.
36. echo known profile directories are:
37. echo ^<%list%^>
38. echo.
39. echo Okay, Get started now!
40. echo.
42. for %%i in (%list%) do (
44. echo ***********************************************************
45. echo Directory is %%i, you want optimize this?
46. set USERKEY=
47. set /p USERKEY= [any key] ^(skip^), [y] optimize, [x] exit tool :
50. if not '!USERKEY!'=='' set USERKEY=!USERKEY:~0,1!
51. if '!USERKEY!'=='y' (
52. echo OK, now optimize of [%%~fi]
53. call :OPTIMIZE_DB "%%~fi"
54. )
55. if '!USERKEY!'=='x' (
56. goto :END
57. )
58. )
59. goto :END
62. rem -----------------------------------------------------------------------------------
63. :OPTIMIZE_DB
64. rem echo DEUBG_LOOP: directory is [!CURRENT_ROOT!]
65. set COUNT=0
66. echo OPTIMIZE_DB:
67. echo Directory is [%1] ^(quoted
68. echo Directory is [%~1]
69. for /F "delims=" %%x in ('%CML% "%~1\*.*"') do (
70. if not "%DEBUG%"=="" (
71. rem echo [%%x]
72. echo [%~n1] name [%%~nx]
73. ) else (
74. echo [%~n1] optimize of [%%~nx]
75. sqlite3 "%%x" vacuum
76. )
77. set /a COUNT+=1
78. )
79. echo Number of db file :!COUNT!
80. goto :EOF
83. :END
84. echo ------------------------------------------------------------------------------
85. echo.
86. echo Finish Google Chrome sqlite db optimize task...
87. echo.
88. echo ------------------------------------------------------------------------------
90. popd
91. endlocal
93. rem pause