Final Project Journal

The design mainly consists of laser-cut plywood parts with supportive 3D-printed brackets. 

 Now, I'll walk you through the design process.  

Before using this code we had a problem with the FSR readings as it was not stable and It changed readings dramatically even without interaction. 

The code reads an analog sensor value, smooths it using both moving average and exponential moving average techniques and activates a random LED on the NeoPixel ring if there’s a significant change in the readings. The program continuously prints the moving averages to the Serial Monitor for monitoring purposes. 

#include <Adafruit_NeoPixel.h>

#define SENSOR_PIN A0   // Pin connected to the analog sensor

#define NEOPIXEL_PIN 3  // Pin connected to the NeoPixel ring

#define NUM_LEDS 24     // Number of LEDs on your NeoPixel ring

Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, NEOPIXEL_PIN, NEO_GRB + NEO_KHZ800);

const int numReadings = 5;  // Number of readings for moving average

int readings[numReadings];  // Array to store readings

int index = 0;              // Current index in the array

long total = 0;             // Sum of readings

long average = 0;           // Average value

const long baseline = 650;  // Baseline value for drift correction

const int ledPin = 13;      // Internal LED pin

// Exponential Moving Average Parameters

float alpha = 0.2;         // Smoothing factor (adjust for quicker response)

float filteredValue = 0;   // Filtered value

long previousReading = 0;  // Previous reading for sudden change detection

bool ledState = false;     // LED state

void setup() {

  Serial.begin(9600);       // Initialize serial communication

  pinMode(ledPin, OUTPUT);  // Set LED pin as output

  strip.begin();  // Initialize the NeoPixel ring

  strip.show();   // Turn off all pixels by default

  for (int i = 0; i < numReadings; i++) {

    readings[i] = 0;  // Initialize readings array

  }

  filteredValue = analogRead(A0);    // Initialize filtered value with first reading

  previousReading = analogRead(A0);  // Initialize previous reading

}

void loop() {

  // For Moving Average Filter

  total = total - readings[index];    // Subtract oldest reading

  readings[index] = analogRead(A0);   // Read new value

  total = total + readings[index];    // Add new reading to total

  index = (index + 1) % numReadings;  // Move to next index

  average = total / numReadings;      // Calculate average

  // For Exponential Moving Average Filter

  float newValue = analogRead(A0);                                 // Read new value

  filteredValue = alpha * newValue + (1 - alpha) * filteredValue;  // Apply filter

  // Check for sudden change in the current reading

  long currentReading = analogRead(A0);

  long movingAvg = average - baseline;

  long expAvg = filteredValue - baseline;

  if (abs(movingAvg - expAvg) > 5) {

    randomSpark();

  }

  // Update previous reading

  previousReading = currentReading;

  // Print the values corrected for baseline drift

  Serial.print("Moving Avg: ");

  Serial.print(movingAvg);  // Subtract baseline for moving average

  Serial.print(" | Exp Avg: ");

  Serial.println(expAvg);  // Subtract baseline for exponential average

  delay(100);              // Wait before the next reading

}

void randomSpark() {

  int ledIndex = random(0, NUM_LEDS);            // Random LED position

  uint32_t color = strip.Color(random(0, 255),   // Random Red value

                               random(0, 255),   // Random Green value

                               random(0, 255));  // Random Blue value

  strip.setPixelColor(ledIndex, color);          // Set the color of the random LED

  strip.show();

  delay(100);                        // Brief delay before turning off the LED

  strip.setPixelColor(ledIndex, 0);  // Turn off the LED

  strip.show();

}

I had trouble visualizing the design and with the help of my instructor, we came up with the final design.

 The FSR was a very new component for me to work with. I had some trouble trying to make it work, but again with the help of my instructor, we figured it out.