Belge içeriğindeki bir tabloya satır veya sütun eklemek, silmek.
Tablo hücrelerine ait oldukları satırlar veya sütunlar aracılığıyla erişmek.
Belgenin bir tablosuna Tables koleksiyon özelliğine sıra numarası vererek erişebilirsiniz.
Eriştiğiniz tablo aslında Table türü bir nesnedir.
Table nesnesinin Rows özelliği tablonun satırlar koleksiyonunu temsil eder.
Bu özellik değeri aslında Rows türünden bir koleksiyon nesnesidir.
Bu koleksiyondaki herhangi bir satıra bir sıra numarasıyla erişebilirsiniz; sonuç Row türü bir nesne olacaktır.
Rows koleksiyonunun Add fonksiyonuyla yeni bir satır ekleyebilirsiniz.
Bu fonksiyonu argümansız çağırırsanız yeni satırı tablonun sonuna ekler.
İsteğe bağlı BeforeRow argümanıyla ileteceğiniz bir Row nesnesiyle yeni satırın hangi satırdan önce gözükeceğini belirtirsiniz.
Bir tablo satırını temsil eden Row nesnesinin Range özelliği satırın içerik bölgesini temsil eder.
Bu özellik üzerinden Range türüne ait fonksiyonlarla satırın içerik bölgesine metin eklemeleri, paragraf düzenlemeleri veya yazı biçimlendirmeleri yapabilirsiniz.
Row nesnesinin Delete fonksiyonuyla satırı silebilirsiniz.
Row türü nesnesinin Cells özelliği aracılığıyla satırın hücreler koleksiyonuna erişebilirsiniz.
Bu özellik değeri aslında Cells türünden bir koleksiyon nesnesidirr.
Bir satırın hücrelerini Merge fonksiyonuyla birleştirerek satırı tek bir hücreye indirgeyebilirsiniz.
Table nesnesinin Columns özelliği tablonun sütunlar koleksiyonunu temsil eder.
Bu özellik değeri aslında Columns türünden bir koleksiyon nesnesidir.
Bu koleksiyondaki herhangi bir sütuna bir sıra numarasıyla erişebilirsiniz; sonuç Column türü bir nesne olacaktır.
Columns koleksiyon nesnesine ait Add fonksiyonuyla tabloya yeni bir sütun ekleyebilirsiniz.
Bu fonksiyonu argümansız çağırırsanız yeni sütunu tablonun sağına ekler.
İsteğe bağlı BeforeColumn argümanıyla ileteceğiniz bir Column nesnesiyle yeni sütunun hangi sütundan önce gözükeceğini belirtirsiniz.
Bir tablo sütununu temsil eden Column nesnesinin Delete fonksiyonuyla o sütunu silebilirsiniz.
Bir tablo sütununu temsil eden Column nesnesinin Cells özelliği sütunun hücreler koleksiyonunu temsil eder.
Boş veya içeriği olan bir Word belgesi açın.
Belge içeriğine elle veya VBA kodlarıyla boş bir tablo ekleyin.
“ThisDocument” VBA projesinde bir altyordam yaratın.
Table türü bir nesne tanımı ekleyin:
Dim tablo As Table
Bu nesneyle yeni eklediğiniz bir tabloya –ki önermiyoruz:
Set tablo = Me.Tables.Add(tabloKonum, 2, 2)
veya sıra numarasıyla var olan bir tabloya –ki doğrusu budur:
Set tablo = Me.Tables(1)
erişin.
Tabloya bir veya daha fazla satır ekleyecek komutlar veya bir döngü yazın:
Dim i As Integer
For i = 1 To 6
tablo.Rows.Add
Next
Row türü bir nesne tanımlayın:
Dim satir As Row
Bu nesne aracılığıyla bir tablo satırına erişin ve onun içerik bölgesi üzerinde yazı tipi biçimlendirmek gibi işlemler yapan komutlar ekleyin:
Set satir = tablo.Rows(1)
satir.Range.Font.Size = 14
Sıra numaralarıyla eriştiğiniz satır hücrelerine metin aktaracak komutlar ekleyin:
satir.Cells(1).Range.Text = "1. Satır 1. Hücre"
Column türü bir nesne tanımlayın:
Dim sutun As Column
Bu nesne aracılığıyla bir tablo sütununa erişin ve sütun hücrelerine metinler aktaracak komutlar veya bir döngü yazın:
Set sutun = tablo.Columns(1)
For i = 2 To 8
sutun.Cells(i).Range.Text = WeekdayName(i - 1)
Next
İsteğe bağlı olarak, tabloda araya bir satır ekleyecek,
Set satir = tablo.Rows.Add(tablo.Rows(1))
satır hücrelerini birleştirecek,
satir.Cells.Merge
ve satır paragraflarında düzenleme yapacak
satir.Range.Paragraphs(1).Alignment = wdAlignParagraphCenter
komutlar da ekleyebilirsiniz.
Deneme amacıyla bir paragraf veya sütunu sildirecek bir komut da ekleyebilirsiniz:
tablo.Rows(8).Delete
Aşağıdaki altyordam belgenin sondaki paragraf sonu karakterinden önceki konumda 2 satırlı ve 2 sütunlu bir tablo yaratacak, bu tabloya eklediği satırlara haftanın günlerinin adlarını ve o günlere ait hayali satış geliri değerlerini yerleştirecek, sonradan en üste eklediği bir satırın hücrelerini birleştirip paragraf düzenlemesi yapacak ve aradan da bir satır silecektir.
Kaynak Dosya: “TablodaSatirSutunDuzenlemeleri.docm”
Unutmayın; kitap veya ekran satırına sığmayan komut satırları alta sarkmış olabilir. Siz onları tek satır olarak yazacaksınız!
Sub TablodaSatirSutunDuzenlemeleri()
Dim tabloKonum As Range
Set tabloKonum = Me.Range(Me.Content.End - 1, Me.Content.End - 1)
Dim tablo As Table
Set tablo = Me.Tables.Add(tabloKonum, 2, 2)
Dim i As Integer
For i = 1 To 6
tablo.Rows.Add
Next
Dim satir As Row
Set satir = tablo.Rows(1)
satir.Range.Font.Size = 14
satir.Range.Font.Bold = True
satir.Cells(1).Range.Text = "Gün"
satir.Cells(2).Range.Text = "Satış"
Dim sutun As Column
Set sutun = tablo.Columns(1)
For i = 2 To 8
sutun.Cells(i).Range.Text = WeekdayName(i - 1)
Next
Set sutun = tablo.Columns(2)
For i = 2 To 8
sutun.Cells(i).Range.Text = FormatCurrency(Expression:=1000 + 9000 * Rnd(), NumDigitsAfterDecimal:=2)
Next
Set satir = tablo.Rows.Add(tablo.Rows(1))
satir.Cells.Merge
satir.Cells(1).Range.Text = "Günlük Satışlar"
satir.Range.Paragraphs(1).Alignment = wdAlignParagraphCenter
tablo.Rows(8).Delete
End Sub