Belge içeriğindeki bir tabloda satır ve sütunları boyutlandırmak ve kenarlık özelliklerini belirlemek.
Bir tabloyu temsil eden Table nesnesinin Borders özeliği tablonun kenarlıklar koleksiyonunu temsil eder.
Bu özellik aslında Borders türünden bir koleksiyon nesnesidir.
Borders nesnesinin OutsideLineStyle özelliği dış kenarlık tipini seçmek içindir.
Yine Borders nesnesinin InsideLineStyle özelliği de iç kenarlıklar tipini belirlemek içindir.
Dış ve iç kenarlıklar tipleri için WdLineStyle adlandırılmış değerler grubundaki bir seçeneği atarsınız. Bunlardan bazıları şunlardır:
wdLineStyleNone (kenarlık yok)
wdLineStyleSingle (tek kenarlık)
wdLineStyleDouble (çift kenarlık)
wdLineStyleDot (noktalı kenarlık)
wdLineStyleDashDot (kesikli noktalı kenarlık)
Borders nesnesinin OutsideLineWidth ve InsideLineWidth özellikleri aracılığıyla da kenarlık çizgisi kalınlığını belirleyebilirsiniz. Kalınlık değerini punto cinsinden bir değer olarak belirtirsiniz.
Bu özellikleri tablonun Borders özelliği aracılığıyla kullanırsanız, kenarlık özelliklerini tüm tablo için belirlemiş olursunuz. Bir satırı veya bir sütunu temsil eden bir nesnenin Borders özelliği aracılığıyla kullanırsanız, tablonun yalnızca o kısmı için kenarlıkları belirlemiş olursunuz.
Bir tablo satırını temsil eden Row nesnesinin SetHeight fonksiyonuyla satırın yüksekliğini belirleyebilirsiniz.
Fonksiyonun ilk (zorunlu) argümanı RowHeight için punto cinsinden yükseklik değerini verirsiniz.
Fonksiyonun ikinci (zorunlu) argümanı HeightRule ile de satır yüksekliğini belirleme kuralını seçersiniz. Bu argüman için WdRowHeightRule adlandırılmış değerler grubundan şu seçenekleri kullanabilirsiniz:
wdRowHeightAtLeast : Satır yüksekliği en az belirtilen değer kadar olacaktır.
wdRowHeightAuto : Satır yüksekliği içeriği sığdıracak şekilde otomatik ayarlanacaktır.
wdRowHeightExactly : Satır yüksekliği tam belirtilen değer kadar olacaktır.
Bu değer seçeneklerinden yalnızca üçüncüsü satır yüksekliğini tam sizin belirttiğiniz değere ayarlar. Diğerlerinde son karar Word programının otomatik boyutlandırma ayarlarına göre verilir. Satır yüksekliğini tablo üzerinde elle ayarlamayı deneyin. Aynı seçenekleri orada görüp deneyerek farklarını öğrenebilirsiniz.
SetHeight fonksiyonunu bir tablo sütununun hücreler koleksiyonunu temsil eden Cells özelliği üzerinde kullanırsanız, sütundaki tüm hücrelerin yüksekliklerini belirlemiş olursunuz.
Bu yolla yapacağınız değişiklik o sütunla kesişen tüm satırların yüksekliğini değiştirecektir.
Bir tablo satırını temsil eden Row nesnesinin Borders özelliği aracılığıyla satırın dış ve iç kenarlıklarını belirleyebilirsiniz.
Column nesnesinin SetWidth fonksiyonuyla o sütunun genişliğini belirleyebilirsiniz.
Fonksiyonun ilk (zorunlu) argümanı ColumnWidth için punto cinsinden genişlik değerini verirsiniz.
Fonksiyonun ikinci (zorunlu) argümanı RulerStyle ile de diğer tablo sütunlarının bu değişiklikten nasıl etkileneceğini seçersiniz. Bu argüman için WdRulerStyle adlandırılmış değerler grubundan şu seçenekleri kullanabilirsiniz:
wdAdjustNone (başka sütunlarda değişiklik yok)
wdAdjustFirstColumn (değişiklik ilk sütunda)
wdAdjustProportional (değişiklikler orantılı olacak)
wdAdjustEqual (değişiklikler eşit olacak)
Bu seçeneklerin farklı sonuçlarını ancak bazı özel durumlarda görürsünüz. İşi kolaydan almak için ilk seçeneği tercih etmekle yetinebilir, ya da sütun genişlikleriyle hiç oynamamayı seçebilirsiniz.
SetWidth fonksiyonunu bir tablo satırının hücreler koleksiyonunu temsil eden Cells özelliği üzerinde kullanırsanız, satırdaki tüm hücrelerin genişliklerini belirlemiş olursunuz.
Bu yolla yapacağınız bir değişiklik yalnızca üzerinde işlem yaptığınız satırın hücrelerini etkileyecektir. Bu hücreler artık değişiklikten etkilenmeyen hücrelerle aynı hizada olmayacaktır.
·Bir tablo sütununu temsil eden Column türü nesnesinin Borders özelliğiyle o sütunun dış ve iç kenarlıklarının özelliklerini belirleyebilirsiniz.
Kenarlık özelliklerini tablo, satır veya sütun düzeylerinde belirleyen komutlarınızın sırasına dikkat edin; hangisi en son işleme konmuşsa, o komutun belirlediği özellikler son görünümü belirler.
İçeriğinde en az bir tablo olan bir belge açın.
Table türü bir nesne tanımlayın ve onunla seçtiğiniz bir tabloya erişin:
Dim tablo As Table
Set tablo = Me.Tables(1)
Bu nesne aracılığıyla tablo kenarlıklarını düzenleye komutlar ekleyebilirsiniz:
tablo.Borders.InsideLineStyle = wdLineStyleSingle
Row türü bir nesne tanımlayın ve onunla seçtiğiniz bir tablo satırına erişin:
Dim satir As Row
Set satir = tablo.Rows(1)
Bu nesne aracılığıyla satır yüksekliği belirleyen bir komut ekleyebilirsiniz:
satir.SetHeight RowHeight:=CentimetersToPoints (1.5), HeightRule:=wdRowHeightExactly
Column türü bir nesne tanımlayın ve onun aracılığıyla seçtiğiniz bir tablo sütununa erişin:
Dim sutun As Column
Set sutun = tablo.Columns(1)
Bu nesne aracılığıyla sütun genişliğini belirleyen bir komut ekleyebilirsiniz:
sutun.SetWidth ColumnWidth:=CentimetersToPoints(4), RulerStyle:=wdAdjustNone
İsterseniz, hücre yüksekliklerini (tüm satırları etkileyecek şekilde) sütun bazında değiştiren,
sutun.Cells.SetHeight RowHeight:=CentimetersToPoints (1), HeightRule:=wdRowHeightExactly
veya hücre genişliklerini belli bir satır için değiştiren,
satir.Cells.SetWidth ColumnWidth:=CentimetersToPoints(2), RulerStyle:=wdAdjustNone
ve tabi ki kenarlıkları belli bir satır veya belli bir sütun için farklı şekilde belirleyen komutlar da ekleyebilirsiniz:
satir.Borders.OutsideLineStyle = wdLineStyleDouble
sutun.Borders.InsideLineStyle = wdLineStyleDot
Aşağıdaki altyordam önceki altyordam örneklerinde oluşturulmuş hayali haftalık satışlar tablosu üzerinde çalışacaktır. Hücre boyutları değiştiren komutların sıralamasına dikkat edin. Hücre genişliklerini satır bazında değiştiren bir komuttan sonra sütunlar artık alt alta gelmeyecektir; ondan sonra sütun bazında boyutlandırma yapacak bir komutu işleme koyamazsınız.
Kaynak Dosya: “TabloKenarlıklarBoyutlandırmalar.docm”
Unutmayın; kitap veya ekran satırına sığmayan komut satırları alta sarkmış olabilir. Siz onları tek satır olarak yazacaksınız!
Sub TabloKenarlıklarBoyutlandırmalar()
Dim tablo As Table
Set tablo = Me.Tables(1)
tablo.Borders.OutsideLineStyle = wdLineStyleDouble
tablo.Borders.InsideLineStyle = wdLineStyleSingle
Dim sutun As Column
Set sutun = tablo.Columns(1)
sutun.Cells.SetHeight RowHeight:=CentimetersToPoints(1), HeightRule:=wdRowHeightExactly
Dim satir As Row
Set satir = tablo.Rows(1)
satir.SetHeight RowHeight:=CentimetersToPoints(1.5), HeightRule:=wdRowHeightExactly
satir.Borders.OutsideLineStyle = wdLineStyleDouble
Set sutun = tablo.Columns(1)
sutun.SetWidth ColumnWidth:=CentimetersToPoints (3), RulerStyle:=wdAdjustNone
Set sutun = tablo.Columns(2)
sutun.SetWidth ColumnWidth:=CentimetersToPoints(4), RulerStyle:=wdAdjustNone
sutun.Borders.InsideLineStyle = wdLineStyleDot
Set satir = tablo.Rows(1)
satir.Cells.SetWidth ColumnWidth:=CentimetersToPoints(2), RulerStyle:=wdAdjustNone
End Sub