データを人間が判読できる ASCII テキストとしてシリアル ポートに出力します。このコマンドにはさまざまな形式があります。数字は各桁に ASCII 文字を使用して印刷されます。浮動小数点数も同様に ASCII 数字として出力され、デフォルトでは小数点以下 2 桁になります。バイトは 1 文字として送信されます。文字や文字列はそのまま送信されます。例えば-
Serial.print(78)「78」を与える
Serial.print(1.23456)「1.23」が得られます
Serial.print('N')「N」を与える
Serial.print("Hello world.")「Hello world」を返します。
オプションの 2 番目のパラメーターは、使用するベース (形式) を指定します。許可される値はBIN(binary, or base 2)、、、、、です。浮動小数点数の場合、このパラメータは使用する小数点以下の桁数を指定します。例えば-OCT(octal, or base 8)DEC(decimal, or base 10)HEX(hexadecimal, or base 16)
Serial.print(78, BIN)「1001110」を与える
Serial.print(78, OCT)「116」を与える
Serial.print(78, DEC)「78」を与える
Serial.print(78, HEX)「4E」になります
Serial.print(1.23456, 0)「1」を与える
Serial.print(1.23456, 2)「1.23」が得られます
Serial.print(1.23456, 4)「1.2346」が得られます
フラッシュメモリベースの文字列をF()Serial.print()でラップすることで、 に渡すことができます。例えば：
Serial.print(F("Hello World"))
データを文字表現に変換せずに送信するには、Serial.write()を使用します。
Serial.print(val)
Serial.print(val, format)
Serial: シリアルポートオブジェクト。各ボードで利用可能なシリアル ポートのリストについては、シリアル メイン ページを参照してください。
val: 出力する値。許可されるデータ型: 任意のデータ型。
print()書き込まれたバイト数を返しますが、その数値の読み取りはオプションです。データ・タイプ：size_t。
/*
Uses a for loop to print numbers in various formats.
*/
void setup() {
Serial.begin(9600); // open the serial port at 9600 bps:
}
void loop() {
// print labels
Serial.print("NO FORMAT"); // prints a label
Serial.print("\t"); // prints a tab
Serial.print("DEC");
Serial.print("\t");
Serial.print("HEX");
Serial.print("\t");
Serial.print("OCT");
Serial.print("\t");
Serial.print("BIN");
Serial.println(); // carriage return after the last label
for (int x = 0; x < 64; x++) { // only part of the ASCII chart, change to suit
// print it out in many formats:
Serial.print(x); // print as an ASCII-encoded decimal - same as "DEC"
Serial.print("\t\t"); // prints two tabs to accomodate the label length
Serial.print(x, DEC); // print as an ASCII-encoded decimal
Serial.print("\t"); // prints a tab
Serial.print(x, HEX); // print as an ASCII-encoded hexadecimal
Serial.print("\t"); // prints a tab
Serial.print(x, OCT); // print as an ASCII-encoded octal
Serial.print("\t"); // prints a tab
Serial.println(x, BIN); // print as an ASCII-encoded binary
// then adds the carriage return with "println"
delay(200); // delay 200 milliseconds
}
Serial.println(); // prints another carriage return
}