Smart Sticker-Device A 

Smart Sticker-Device B

This project helps me keep track of tasks more effectively, especially for people who have short attention spans or struggle with memory. Each “intelligent sticky note” represents one item on the to-do list, so the first note is for the current task, the next one over is for the following task, and so on. Five minutes before a task is set to begin, the sticky note generates noise and flashes a red light to draw the user’s attention. Once the user presses a button to indicate they have started working on the task, the note automatically shifts focus to the next item in the sequence. This way, users can easily stay on top of their responsibilities without forgetting what comes next. 

This video demonstrates the process of signal transmission synchronization. 

Process

Don't forget that this section also needs a brief bit of text, ~100–300 words describing any aspect(s) of your process you'd like your readers to know about. You can interleave this with the images or put it all at the top or bottom or however you'd like.

Discussion

• I really appreciate the suggestions regarding the noise output.

       While implementing actual spoken phrases might be complicated, I can certainly explore playing pre-recorded audio clips or incorporating more pleasant music.

       I also agree with the idea of making the device one-way while turning the other unit into a wearable—this is an exciting concept that would let me keep the device on me at all times, so that updates and notifications are seamless. 

• As for the signal and communication issues, I found that debugging radio transmission was indeed very tricky.

I spent a great deal of time attempting to address packet loss, but unfortunately, many of my efforts didn’t succeed as well as I had hoped.

Although the final result wasn’t perfect, I learned a lot throughout the process.

Hardware development often comes with unexpected hurdles, yet I enjoyed tackling them and discovering different approaches. 

• From a technical standpoint, coding was my biggest challenge.

       Even for seemingly simple circuits, I found myself spending considerable effort writing and debugging code.

       Often, I underestimated the importance of certain steps and only realized too late how critical they were.

       If I could go back, I would try a unidirectional communication approach sooner, rather than getting stuck on bidirectional attempts for too long.

       also recognize that my time management could have been better; when repeated efforts failed, I should have shifted focus to completing the laser-cut enclosure or exploring    alternative methods instead of doubling down on a single solution.

       Next time, I’d like to experiment with incorporating 3D-printed elements into my design so I can push my prototyping skills even further. 

• I might try to improve this project in the future by making the communication more efficient and incorporating some of the feedback to better serve specific user groups. 

Technical information

//Smart Sticky Notes

//Siyu Ou

//This code manages a task reminder system using an LCD, NeoPixel LED, buzzer, RTC, and a transceiver module for wireless communication. It tracks tasks and checks if a task is due within 5 minutes. If so, the LED turns red, and the buzzer sounds. Pressing the button once starts the task, turning the LED yellow and stopping the buzzer. Pressing it again marks the task as complete, switching the LED to green and moving to the next task. If a task remains unfinished for 5 minutes, the reminder reactivates. The transceiver sends and receives task updates wirelessly, allowing remote task management. The system continuously updates the display, checks time, and synchronizes tasks. 

#include <LiquidCrystal_I2C.h>

#include <Adafruit_NeoPixel.h>

#include <RTClib.h>

#define BUTTON_PIN 3

#define LED_PIN 6

#define NUM_LEDS 1

#define BUZZER_PIN 4

LiquidCrystal_I2C lcd(0x27, 16, 2);

Adafruit_NeoPixel strip = Adafruit_NeoPixel(NUM_LEDS, LED_PIN, NEO_GRB + NEO_KHZ800);

RTC_DS3231 rtc;

// Global variables

struct Task {

  const char* name;

  const char* time;

};

Task tasks[] = {

  {"do the laundry", "13:08"},

  {"finish the assignment1", "13:10"},

  {"boil some water", "13:13"},

  {"draw the diagram", "13:16"},

  {"drink water", "13:20"}

};

const int numTasks = sizeof(tasks) / sizeof(tasks[0]);

int currentTaskIndex = 0;

bool taskStarted = false;

unsigned long taskStartTime;

unsigned long taskReminderTime = 5UL * 60UL * 1000UL; // 5 minutes

bool taskCompleted = false;

bool isRed = false; // showing if it is red

bool buzzerActive = false; // buzzer control

void setup() {

  pinMode(BUTTON_PIN, INPUT_PULLUP);

  pinMode(BUZZER_PIN, OUTPUT);

  strip.begin();

  strip.show();

  lcd.init();

  lcd.backlight();

  Serial.begin(9600);

  if (!rtc.begin()) {

    Serial.println("Couldn't find RTC");

    while (1);

  }

  rtc.adjust(DateTime(2025, 2, 24, 13, 6, 0)); //set time

  // make sure the buzzer is off

  noTone(BUZZER_PIN);

  displayCurrentTask();

  checkImmediateReminder(); // check the initial one

}

void loop() {

  if (digitalRead(BUTTON_PIN) == LOW) {

    handleButtonPress();

    delay(500); // debounce

  }

  checkReminder();

  displayCurrentTime();

  controlBuzzer();

}

void displayCurrentTask() {

  lcd.clear();

  lcd.setCursor(0, 0);

  lcd.print(tasks[currentTaskIndex].name);

  lcd.setCursor(0, 1);

  lcd.print("Due: ");

  lcd.print(tasks[currentTaskIndex].time);

}

void displayCurrentTime() {

  DateTime now = rtc.now();

  lcd.setCursor(0, 2);

  lcd.print("Time: ");

  lcd.print(now.hour());

  lcd.print(":");

  if (now.minute() < 10) {

    lcd.print("0");

  }

  lcd.print(now.minute());

}

void handleButtonPress() {

  if (!taskStarted) {

    taskStarted = true;

    taskCompleted = false;

    taskStartTime = millis();

    setLEDColor(255, 255, 0); // Yellow for ongoing task

    isRed = false; // ban the red light

    buzzerActive = false; // stop buzzer

    noTone(BUZZER_PIN);

    Serial.println("Task started");

  } else if (!taskCompleted) {

    taskCompleted = true;

    taskStarted = false;

    setLEDColor(0, 255, 0); // Green for completed task

    Serial.println("Task completed");

    advanceToNextTask();

  }

}

void advanceToNextTask() {

  currentTaskIndex++;

  if (currentTaskIndex >= numTasks) {

    currentTaskIndex = 0;

  }

  taskStarted = false;

  taskCompleted = false;

  checkImmediateReminder(); //check the task

  displayCurrentTask();

  Serial.println("Advanced to next task");

}

void checkReminder() {

  DateTime now = rtc.now();

  String currentTime = String(now.hour()) + ":" + String(now.minute());

  if (taskStarted && !taskCompleted) {

    unsigned long elapsedTime = millis() - taskStartTime;

    if (elapsedTime >= taskReminderTime) {

      setLEDColor(255, 0, 0); // Red for reminder

      tone(BUZZER_PIN, 1000); // Play tone

      delay(1000);

      noTone(BUZZER_PIN);

      Serial.println("Reminder: Task is ongoing for 5 minutes.");

    }

  }

  if (!taskStarted && isTimeWithinFiveMinutes(currentTime, tasks[currentTaskIndex].time)) {

    setLEDColor(255, 0, 0); // Red for task due within 5 minutes

    isRed = true;

    buzzerActive = true; // active buzzer

    Serial.println("Immediate reminder: Task is within 5 minutes.");

  } else if (!taskStarted) {

    setLEDColor(0, 255, 0); // green

  }

}

bool isTimeWithinFiveMinutes(String currentTime, String taskTime) {

  int currentHour = currentTime.substring(0, currentTime.indexOf(':')).toInt();

  int currentMinute = currentTime.substring(currentTime.indexOf(':') + 1).toInt();

  int taskHour = taskTime.substring(0, taskTime.indexOf(':')).toInt();

  int taskMinute = taskTime.substring(taskTime.indexOf(':') + 1).toInt();

  int currentTotalMinutes = currentHour * 60 + currentMinute;

  int taskTotalMinutes = taskHour * 60 + taskMinute;

  return (taskTotalMinutes - currentTotalMinutes) <= 5 && (taskTotalMinutes - currentTotalMinutes) >= 0;

}

void checkImmediateReminder() {

  DateTime now = rtc.now();

  String currentTime = String(now.hour()) + ":" + String(now.minute());

  if (isTimeWithinFiveMinutes(currentTime, tasks[currentTaskIndex].time)) {

    setLEDColor(255, 0, 0); // Red for immediate reminder

    isRed = true;

    buzzerActive = true; // active buzzer

    Serial.println("Immediate reminder: Task is already within 5 minutes.");

  } else if (!taskStarted) {

    setLEDColor(0, 255, 0); // if its not within 5 mins, turns green

  }

}

void controlBuzzer() {

  if (buzzerActive && !taskStarted) {

    tone(BUZZER_PIN, 1500); //start noise

    Serial.println("Buzzer Active");

  } else {

    noTone(BUZZER_PIN); // stop buzzer

  }

}

void setLEDColor(int r, int g, int b) {

  strip.clear();

  strip.setPixelColor(0, strip.Color(r, g, b));

  strip.show();

}