Double Transducer: Distance to Light/Color

FINAL PROTOTYPE

DETAIL SHOTS

DEMO VIDEOS

NARRATIVE DESCRIPTION

PROCESS

DISCUSSION

FUNCTIONAL BLOCK + ELECTRICAL SCHEMATICS

Electrical Schematic

CODE

/*

 Project 1: Double Transducer

 60-223 Intro to Physical Computing

 A time of flight sensor reads the distance between itself and an object. This is used to drive a servo motor from 0-180 degree range. The servo's rotation is converted to linear motion, driven by a metal rod that pushes and pull the plunger of a syringe. The syringe transfers water into and out of another syringe. The varying weight of the syringe is recorded with a load cell that is fixed underneath it. This value is then used to change the color of an LED (smart neopixel). When the pushbutton is pressed the distance values drives the color of the LED ignoring the middle step of the transducer.

 Pin mapping:

 Arduino pin | role  |  description

 -------------------------------------

 2             input    load cell (DOUT)

 3             input    load cell (SCK)

 A4            input    tof sensor (SDA)

 A5            input    tof sensor (SCL)

 7             input    skip the middle part button

 5             output   servo motor (Pushes syringe)

 9             output   RGB LED

 code by Constantine Westerink and Isabel Fleck

 February 2025

*/

#include <Servo.h>

#include <Wire.h>

#include <VL53L0X.h>

#include "HX711.h"

#include <PololuLedStrip.h>

#include <LiquidCrystal_I2C.h>

const int SYRINGE_SERVO_PIN = 5,

         RGB_LED_PIN = 9,

         BUTTON_PIN = 7,

         LOADCELL_DOUT_PIN = 2,

         LOADCELL_SCK_PIN = 3;

const int LOADCELL_CALIBRATION_FACTOR = 3475; // Unique for each load cell

// MIN and MAX weight of syringe in grams

const float MIN_LOADCELL_VALUE = 0,

         MAX_LOADCELL_VALUE = 7.45;

// input data variables

float distanceVal, loadcellVal;

int buttonVal; // HIGH, LOW

// internal mapping values (0 - 99)

int mappedDistanceVal, mappedLoadcellVal, mappedSyringeServoPos;

// output values

int syringeServoPos;

rgb_color color[1];

VL53L0X distanceSensor;

Servo syringeServo;

HX711 loadCell;

PololuLedStrip<RGB_LED_PIN> led;

LiquidCrystal_I2C screen(0x27, 16, 2);

void setupScreen() {

 screen.init();

 screen.backlight();

 screen.home();

 screen.print("Hello, world!");

}

void setupLoadcell() {

 loadCell.begin(LOADCELL_DOUT_PIN, LOADCELL_SCK_PIN);

 loadCell.set_scale(LOADCELL_CALIBRATION_FACTOR);

 loadCell.tare();

}

void setupSyringeServo() {

 syringeServo.attach(SYRINGE_SERVO_PIN);

 syringeServo.write(180); // Extended position

 delay(1000);

}

void setupLED() {

 rgb_color initColor;

 initColor.red = 0;

 initColor.green = 100;

 initColor.blue = 0;

 color[0] = initColor;

 led.write(color, 1);

}

void setupButton() {

 pinMode(BUTTON_PIN, OUTPUT);

}

void setupDistanceSensor() {

 Wire.begin();

 distanceSensor.setTimeout(500);

 if (!distanceSensor.init())

 {

   Serial.println("Error Distance sensor not working");

   while (1) {}

 }

}

void setup() {

 Serial.begin(9600);

 Serial.println("Setup Begin");

 setupSyringeServo();

 setupScreen();

 setupLED();

 setupLoadcell();

 setupButton();

 setupDistanceSensor();

 Serial.println("Setup Complete");

}

void readInputs() {

  distanceVal = distanceSensor.readRangeSingleMillimeters();

 loadcellVal = loadCell.get_units(1);

 buttonVal = digitalRead(BUTTON_PIN);

}

void updateInternalState() {

 // map the photoresistor value to a range of 0 to 99

 int constrainedDistanceVal = constrain(distanceVal, 50, 150);

 mappedDistanceVal = map(constrainedDistanceVal, 50, 150, 0, 99);

 // map the potentiometer value to a range of 0 to 99

 int constrainedLoadcellVal = constrain(loadcellVal, MIN_LOADCELL_VALUE, MAX_LOADCELL_VALUE); // TODO

 mappedLoadcellVal = map(constrainedLoadcellVal, MIN_LOADCELL_VALUE, MAX_LOADCELL_VALUE, 0, 99);

 Serial.println(loadcellVal);

 syringeServoPos = map(mappedDistanceVal, 0, 99, 0, 180);

 mappedSyringeServoPos = map(syringeServoPos, 0, 180, 0, 99);

 // // make a decision about driving the buzzer output based on the button state

 if (buttonVal == HIGH) {

   color[0] = getColor(mappedDistanceVal);

 } else {

   color[0] = getColor(mappedLoadcellVal);

 }

}

rgb_color getColor(int value) {

 rgb_color color;

 color.blue = 200;

 color.red = 100;

 color.green = map(value, 0, 99, 0, 255);

 return color;

}

void driveOutputs() {

 if (buttonVal == LOW) {

   syringeServo.write(syringeServoPos);

 }

 led.write(color, 1);

}

void loop() {

 readInputs();

 updateInternalState();

 driveOutputs();

 logToScreen();

 delay(50);

}

void logToScreen() {

 screen.clear();

 // Print Input value

 screen.print('i');

 screen.print(':');

 screen.print(mappedDistanceVal);

 // Print middle step values

 screen.setCursor(6,0);

 screen.print('m');

 screen.print(':');

 screen.print(mappedSyringeServoPos);

 screen.setCursor(8,1);

 screen.print(99 - mappedLoadcellVal);

 // Print output value

 screen.setCursor(12,1);

 screen.print('o');

 screen.print(':');

 screen.display();

}