$ phonopy-bandplot --gnuplot band.yaml > band.dat
$ phonopy -c POSCAR-unitcell -p -s mesh.conf
$ phonopy-pdosplot -i '1 2, 3 4, 5 6' -o 'pdos.pdf' projected_dos.dat
$ gnuplot phband_pdos.gnu
set terminal pdf enhanced color size 4,3 font "Arial,20"
set output 'phband_pdos.pdf'
if (!exists("MP_LEFT")) MP_LEFT = .06
if (!exists("MP_RIGHT")) MP_RIGHT = .97
if (!exists("MP_BOTTOM")) MP_BOTTOM = .15
if (!exists("MP_TOP")) MP_TOP = .97
if (!exists("MP_xGAP")) MP_xGAP = 0.06
if (!exists("MP_yGAP")) MP_yGAP = 0.10
set multiplot layout 1,2 rowsfirst #\
# margins screen MP_LEFT, MP_RIGHT, MP_BOTTOM, MP_TOP spacing screen MP_xGAP, MP_yGAP
## phband
set style data lines
#set key at 1.8, 3.5 samplen 0
set grid
set xrange [0: 0.89809160]
set yrange [ -25.0 : 200]
set ytics -50.0, 50.0, 300.0
set mytics 5
set ylabel "Frequency [cm^{-1}]"
set border lw 3
set arrow from 0.12254900, -25.0 to 0.12254900, 200 nohead lw 3
set arrow from 0.24509800, -25.0 to 0.24509800, 200 nohead lw 3
set arrow from 0.41840850, -25.0 to 0.41840850, 200 nohead lw 3
set arrow from 0.47968300, -25.0 to 0.47968300, 200 nohead lw 3
set arrow from 0.60223210, -25.0 to 0.60223210, 200 nohead lw 3
set arrow from 0.72478110, -25.0 to 0.72478110, 200 nohead lw 3
set arrow from 0.00000, 0.0 to 0.89809160, 0.0 nohead lc "magenta" dt "--" lw 2
set origin 0.00, 0.05
set size 0.8, 0.95
set xtics ("{/Symbol G}" 0.00000, "X" 0.12254900, "M" 0.24509800, "{/Symbol G}" 0.41840850, "Z" 0.47968300, "R" 0.60223210, "A" 0.72478110, "Z" 0.89809160)
#set label "(a) CuTlSe" at 0.05, 3.8 font "Arial-Bold," front
plot "~/calc/VASP/CuTlSe/PBE0_prelax/PBE0_ph444/phband.dat" u 1:($2*33.356) w l lw 2 lt rgb "red" notitle
## phdos
reset
set style data lines
set key at 5.5, 140 samplen 1 font ",18" reverse
#set nokey
set grid
set xrange [0: 6.0]
set yrange [ -25.0 : 200]
set ytics -50.0, 50.0, 300.0
set ytics format ""
set mytics 5
set xtics 0.0, 2.0, 10.0
set mxtics 2
set xlabel "PDOS" offset 0.0, 0.5 font ",20"
#set ylabel "{/Symbol e} - {/Symbol e}_{F} [eV]" offset 0.5, 0.0
set border lw 3
set arrow from 0.0, 0.0 to 5.0, 0.0 nohead lc "magenta" dt "--" lw 2
set origin 0.70, 0.00
set size 0.35, 1.0
#set label "(a) CuTlSe" at 0.05, 3.7 font "Arial-Bold," front
plot "~/calc/VASP/CuTlSe/PBE0_prelax/PBE0_ph444/projected_dos.dat" u ($2+$3):($1*33.356) w l lw 3 lt rgb "green" title "Cu", "" u ($4+$5):($1*33.356) w l lw 3 lt rgb "magenta" title "Tl", "" u ($6+$7):($1*33.356) w l lw 3 lt rgb "blue" title "Se"