Unidade 3

Script para ler todos os áudio de uma pasta

#algoritmo1

for i from 1 to 17

teste_diretorio=fileReadable ("/home/samuel/Documentos/curso_praat/basecurso/VGE'i'.wav")

if teste_diretorio=1

Read from file: "/home/samuel/Documentos/curso_praat/basecurso/VGE'i'.wav"

endif

endfor

Vídeo: unidade3 aula 1 parte 1

#algoritmo2

#chooseFolder$ comando do praat para o usuários escolhar a pasta com os arquivos

pastaentrada$=chooseFolder$: "Escolha a pasta onde estão seus arquivos de voz"

#teste para verificar se o diretório tem "\" ou "/" que depende dos sistema operacional

if windows = 1

ultima_string=endsWith(pastaentrada$, "\")

else

ultima_string=endsWith(pastaentrada$, "/")

endif

#teste para acrescentar "\" ou "/" que depende dos sistema operacional

if ultima_string = 0

if windows = 1

pastaentrada$=pastaentrada$ + "\"

else

pastaentrada$=pastaentrada$ + "/"

endif

#criando um objeto de lista de strings dos arquivos de áudio da pasta escolhida

lista_audio=Create Strings as file list: "lista_audio", pastaentrada$+"*.wav"

#seleciona objeto lista_audio

select lista_audio

#Quantidade de posições da lista

num_audio = Get number of strings

#laço p/ ler todos os audios de uma pasta

for cont_audio from 1 to num_audio

#seleciona o objeto audio

select lista_audio

#variavel recebe string referente a posição cont_audio

nome_audio$ = Get string: cont_audio

#ler aquivo de audio

audio = Read from file: pastaentrada$+nome_audio$

endfor

Vídeo: unidade 3 aula 1 parte 2

Script para padronizar duração do áudio

#Padronizar duração do áudio em 3 segundos e aplicar um filtro rejeita faixas

#chooseFolder$ comando do praat para o usuários escolhar a pasta com os arquivos

pastaentrada$=chooseFolder$: "Escolha a pasta onde estão seus arquivos de voz"

#teste para verificar se o diretório tem "\" ou "/" que depende dos sistema operacional

if windows = 1

ultima_string=endsWith(pastaentrada$, "\")

else

ultima_string=endsWith(pastaentrada$, "/")

endif

#teste para acrescentar "\" ou "/" que depende dos sistema operacional

if ultima_string = 0

if windows = 1

pastaentrada$=pastaentrada$ + "\"

else

pastaentrada$=pastaentrada$ + "/"

endif

#chooseFolder$ comando do praat para o usuários escolhar a pasta em que as vozes padronizada serão salvas

pastasaida$=chooseFolder$: "Escolha a pasta para salvar seus arquivos de voz padronizado"

#teste para verificar se o diretório tem "\" ou "/" que depende dos sistema operacional

if windows = 1

ultima_string=endsWith(pastasaida$, "\")

else

ultima_string=endsWith(pastasaida$, "/")

endif

#teste para acrescentar "\" ou "/" que depende dos sistema operacional

if ultima_string = 0

if windows = 1

pastasaida$=pastasaida$ + "\"

else

pastasaida$=pastasaida$ + "/"

endif

#teste para informar que as pastas devem ser diferentes para não sobrescrever o arquivo original

if pastaentrada$ = pastasaida$

exitScript: "ERRO: Diretório igual ao arquivo original"

endif

#lista de strings

lista_audio=Create Strings as file list: "lista_audio", pastaentrada$+"*.wav"

#seleciona objeto lista_audio

select lista_audio

#Quantidade de posições da lista

num_audio = Get number of strings

#laço p/ ler, padronizar e aplicar filtro rejeita faixa p/ todos os audios de uma pasta

for cont_audio from 1 to num_audio

#selecionando a lista

select lista_audio

#variavel recebe string referente a posição cont_audio

nome_audio$ = Get string: cont_audio

#abrir aquivo de audio

audio = Read from file: pastaentrada$+nome_audio$

#selecionando áudio

select audio

#variável p/ amrzenar a duração total do áudio

total=Get total duration

#teste p/ padronizar

if total > 3

#chamando o procedimento padronizar

@padronizar: total

endif

#selecionando e Removendo o objeto áudio

select audio

Remove

endfor

#Selecionando e removendo o objeto lista

select lista_audio

Remove

procedure padronizar: .total

#variável que armazenar o valor central da duração do áudio

.meio=.total/2

#duração do novo áudio

.trecho=3

#Metade da duração do novo áudio

.trecho_metade=.trecho/2

#início do novo áudio

.novo_inicio=.meio-.trecho_metade

#fim do novo áudio

.novo_fim=.meio+.trecho_metade

#extraindo o áudio com tamanho padronizado

.audio_novo = Extract part: .novo_inicio, .novo_fim, "rectangular", 1, "no"

#selecionando o objeto .audio_novo

select .audio_novo

#chamando o procedimento para filtrar o sinal de voz

@rejeitafaixa

#Selecionando e removendo o objeto .audio_novo

select .audio_novo

Remove

endproc

#procedimento criado para aplicar um filtro rejeita faixa entre 0 até 63 Hz

procedure rejeitafaixa

#variável que recebe o áudio após aplicado o filtro rejeita faixa

.audio_novo_filtro=Filter (stop Hann band): 0, 63, 0.1

#selecionando o áudio padronizado e após aplicação do filtro

select .audio_novo_filtro

#Salvando o áudio padronizado e após aplicação do filtro

Save as WAV file: pastasaida$ + nome_audio$

#selecionando e removendo o objeto .audio_novo_filtro

select .audio_novo_filtro

Remove

endproc

Vídeo: unidade 3 aula 2

Script para extrair f0

#Salvar arquivo como diretorio.praat

pastaentrada$=chooseFolder$: "Escolha a pasta onde estão seus arquivos de voz"

if windows = 1

ultima_string=endsWith(pastaentrada$, "\")

else

ultima_string=endsWith(pastaentrada$, "/")

endif

if ultima_string = 0

if windows = 1

pastaentrada$=pastaentrada$ + "\"

else

pastaentrada$=pastaentrada$ + "/"

endif

pastasaida$=chooseFolder$: "Escolha a pasta para salvar o relatatório acústico"

if windows = 1

ultima_string=endsWith(pastasaida$, "\")

else

ultima_string=endsWith(pastasaida$, "/")

endif

if ultima_string = 0

if windows = 1

pastasaida$=pastasaida$ + "\"

else

pastasaida$=pastasaida$ + "/"

endif

include diretorio.praat

lista_audio=Create Strings as file list: "lista_audio", pastaentrada$+"*.wav"

#seleciona objeto lista_audio

select lista_audio

#Quantidade de strings(audios)

num_audio = Get number of strings

f0_tabela_columns$ = "Indice Mediaf0 DPf0 CVf0 Medianaf0 1ªquartil 3ªquartil Maxf0 Minf0 Amplitude ProporcaoMinMAxf0"

f0_tabela = Create Table with column names: "f0_tabela", 0, f0_tabela_columns$

for cont_audio from 1 to num_audio

select lista_audio

#variavel recebe string referente a posição cont_audio

nome_audio$ = Get string: cont_audio

#abrir aquivo de audio

audio = Read from file: pastaentrada$+nome_audio$

piso=75

teto=600

select audio

@medidasf0: piso, teto

@tabmedidasf0

select audio

Remove

endfor

select f0_tabela

Save as comma-separated file: pastasaida$ + "f0.csv"

select f0_tabela

plus lista_audio

Remove

procedure medidasf0: .piso, .teto

.f0lista=To Pitch (cc): 0, .piso, 15, "no", 0.03, 0.45, 0.01, 0.35, 0.14, .teto

select .f0lista

.min=Get minimum: 0, 0, "Hertz", "parabolic"

.max=Get maximum: 0, 0, "Hertz", "parabolic"

.mediana=Get quantile: 0, 0, 0.5, "Hertz"

.media=Get mean: 0, 0, "Hertz"

.dp=Get standard deviation: 0, 0, "Hertz"

.q1=Get quantile: 0, 0, 0.25, "Hertz"

.q3=Get quantile: 0, 0, 0.75, "Hertz"

.cv=(.dp/.media)*100

.amplitude=.max-.min

.propminmax=.min/.max

select .f0lista

Remove

endproc

procedure tabmedidasf0

select f0_tabela

Append row

.r = Get number of rows

Set string value: .r,"Indice", nome_audio$

Set numeric value: .r, "Mediaf0", medidasf0.media

Set numeric value: .r, "DPf0", medidasf0.dp

Set numeric value: .r, "CVf0", medidasf0.cv

Set numeric value: .r, "Medianaf0", medidasf0.mediana

Set numeric value: .r, "1ªquartil", medidasf0.q1

Set numeric value: .r, "3ªquartil", medidasf0.q3

Set numeric value: .r, "Maxf0", medidasf0.max

Set numeric value: .r, "Minf0", medidasf0.min

Set numeric value: .r, "Amplitude", medidasf0.amplitude

Set numeric value: .r, "ProporcaoMinMAxf0", medidasf0.propminmax

endproc

Mais informações sobre configurações de f0

Vídeo: unidade 3 aula 3 parte 1

Vídeo: unidade 3 aula 3 parte 2

Início da Implementação do Relatório Acústico

#Início da implementação do relatório acústico

#chamando o script diretorio.praat

include diretorio.praat

#Criando lista de strings com o caminho especificado pelo usuário

lista_audio=Create Strings as file list: "lista_audio", pastaentrada$+"*.wav"

#seleciona objeto lista_audio

select lista_audio

#quantidade de arquivos de audio

num_audio = Get number of strings

#Criando os nomes dos atributos das medidas que serão alocadas na tabela

tabela_medidas_columns$ = "Indice f0CPP Mediaf0 DPf0 CVf0 Medianaf0 1ªquartil 3ªquartil Maxf0 Minf0 Amplitude ProporcaoMinMAxf0"

# Criando tabela e colocando os nomes dos atributos

tabela_medidas = Create Table with column names: "tabela_medidas", 0, tabela_medidas_columns$

#Início da estrutura de repetição

for cont_audio from 1 to num_audio

#selecionando a lista de áudio

select lista_audio

#variável recebe string referente a posição cont_audio

nome_audio$ = Get string: cont_audio

#ler aquivo de áudio

audio = Read from file: pastaentrada$+nome_audio$

#argumentos para serem preenchidos de f0

piso=75

teto=600

oitava=0.01

saltooitava=0.35

#chamando o procedimento medidasf0

@medidasf0: piso, oitava, saltooitava,teto

#chamando o procedimento f0cpp

@f0cpp

#Teste para atualizar argumentos de f0 e a rerência é f0cpp

#Primeira condição verifica o min e max de f0 e os compara com o valor de f0cpp

if (medidasf0.min < (0.65*f0cpp.f0)) or (medidasf0.max > (1.65*f0cpp.f0))

#atualizando argumentos custo de oitava e salto de oitava

oitava=0.04

saltooitava=0.5

#chamando o procedimento medidasf0

@medidasf0: piso, oitava, saltooitava, teto

endif

#realizado o teste com as mesmas condições novamente

#o objetivo é atualizar valores de referência de frequência inferior e superior

#caso o teste anterior não tenha sido eficiente

if (medidasf0.min < (0.65*f0cpp.f0)) or (medidasf0.max > (1.65*f0cpp.f0))

#atualizando argumentos de limites inferior e superior de f0, custo de oitava e salto de oitava

piso=0.6 * f0cpp.f0

teto=1.4 * f0cpp.f0

oitava=0.04

saltooitava=0.5

#chamando o procedimento medidasf0

@medidasf0: piso, oitava, saltooitava, teto

endif

#chamando o procedimento oscilograma

@oscilograma

#chamando o procedimento contornof0

@contornof0

#chamando o procedimento imprimirmedidas

@imprimirmedidas

#chamando o procedimento tabmedidasf0

@tabmedidasf0

#selecionado e removendo o objeto áudio

select audio

Remove

#fim da estrutura for

endfor

#selecionado a tabela com os valores das medidas

select tabela_medidas

#salvando essa tabela em uma planhilha .csv

Save as comma-separated file: pastasaida$ + "medidas.csv"

#Selecionando a tabela com as medidas

select tabela_medidas

#adicionando na seleção a lista das strings

plus lista_audio

plus medidasf0.f0lista

# removendo os objetos selecionados

Remove

#procedimento para extrair f0 e suas medidas

procedure medidasf0: .piso, .oitava, .saltooitava, .teto

if variableExists(".f0lista")

select .f0lista

Remove

endif

select audio

#armazenando na variável .f0lista os valores de f0

.f0lista=To Pitch (cc): 0, .piso, 15, "no", 0.03, 0.45, .oitava, .saltooitava, 0.14, .teto

#selecionando o objeto .f0lista

select .f0lista

#valor mínimo de f0

.min=Get minimum: 0, 0, "Hertz", "parabolic"

#valor máximo de f0

.max=Get maximum: 0, 0, "Hertz", "parabolic"

#valor da mediana de f0

.mediana=Get quantile: 0, 0, 0.5, "Hertz"

#valor da média de f0

.media=Get mean: 0, 0, "Hertz"

#valor do desvio padrão de f0

.dp=Get standard deviation: 0, 0, "Hertz"

#valor do 1ª quartil de f0

.q1=Get quantile: 0, 0, 0.25, "Hertz"

#valor do 3ª quartil de f0

.q3=Get quantile: 0, 0, 0.75, "Hertz"

#cálculo do coeficiente de variação de f0

.cv=(.dp/.media)*100

#cálculo da amplitude de f0

.amplitude=.max-.min

#relação de proporção en o mínino e o máximo de f0

.propminmax=.min/.max

endproc

#procedimento para calcular f0 com o cpp

procedure f0cpp

#selecionando o objeto áudio

select audio

#variável que armazena o objeto cepstrograma

.cepstrograma =noprogress To PowerCepstrogram: 60, 0.002, 5000, 50

#selecionando o objeto cepstrograma

select .cepstrograma

#variável que armazana o objeto cepstro

.cepstrogramamarginal=To PowerCepstrum (slice): 0.1

#selecionando o objeto cepstro

select .cepstrogramamarginal

#extraindo a quefrency

.quefrency=Get quefrency of peak: 60, 333.3, "parabolic"

#calculando f0 do cpp

.f0=1/.quefrency

#Selecionando e removendo os objetos cepstrograma e cepstrogramamarginal

select .cepstrograma

plus .cepstrogramamarginal

Remove

endproc

#procedimento para desenhar o oscilograma

procedure oscilograma

#seleciona o objeto áudio

select audio

#duração total do áudio

.duracaotot = Get total duration

#valor mínimo da amplitude do áudio

.amplitudemin = Get minimum: 0, 0, "sinc70"

#valor máximo da amplitude do áudio

.amplitudemax = Get maximum: 0, 0, "sinc70"

#apagando tudo da janela Praat Picture

Erase all

#selecionado o tipo de linha

Solid line

#Largura da linha

Line width: 1

#selecionando cor

Black

#selecionando fonte

Helvetica

#selecionando área da janela Praat Picture

Select inner viewport: 1, 5.5, 0.5, 1

#tamanho da fonte

Font size: 12

#selecioando eixos

Axes: 1.5, 5.5, 0.5, 0.8

#texto que será impresso com seus parâmetros

Text: 2.7, "Left", 0.5, "Half", "##Relatório acústico do arquivo de voz 'nome_audio$'"

#tamanho da fonte

Font size: 8

#selecionando área da janela Praat Picture

Select inner viewport... 1 7.5 1.1 2.1

#seleção do objeto áudio

select audio

#desenhado o objeto áudio

Draw: 0, 0, 0, 0, "no", "Curve"

#desenha uma caixa (retângulo) no contorno da figura

Draw inner box

#Os comandos abaixo são para escrever os parâmetros referentes aos eixos vertical e horizontal do oscilograma

One mark left: .amplitudemin, "no", "yes", "no", "'.amplitudemin:2'"

One mark left: .amplitudemax, "no", "yes", "no", "'.amplitudemax:2'"

Text left: "no", "Amplitude (Pa)"

One mark bottom: 0, "no", "yes", "no", "0.00"

One mark bottom: .duracaotot, "no", "yes", "no", "'.duracaotot:2'"

Text bottom: "no", "Tempo (s)"

endproc

#procedimento para desenhar o contorno de f0 no tempo

procedure contornof0

#tamanho da fonte

Font size: 8

#selecionando área da janela Praat Picture

Select inner viewport: 1, 7.5, 2.5, 3.5

#seleção do objeto com os valores de f0

select medidasf0.f0lista

#Cor do contorno

Colour: "red"

#desenhando o contorno

Draw: 0, 0, 0, 500, "no"

#desenha uma caixa (retângulo) no contorno da figura

Draw inner box

#Os comandos abaixo são para escrever os parâmetros referentes aos eixos vertical e horizontal do contorno de f0

One mark left: 0, "no", "yes", "no", "0"

One mark left: 100, "no", "yes", "no", "100"

One mark left: 200, "no", "yes", "no", "200"

One mark left: 300, "no", "yes", "no", "300"

One mark left: 400, "no", "yes", "no", "400"

One mark left: 500, "no", "yes", "no", "500"

Colour: "black"

Text right: "no", "f0 (Hz)"

One mark bottom: 0, "no", "yes", "no", "0.00"

One mark bottom: oscilograma.duracaotot, "no", "yes", "no", "'oscilograma.duracaotot:2'"

Text bottom: "no", "Tempo (s)"

endproc

#procedimento para imprimir as medidas no Praat Picture

procedure imprimirmedidas

#tamanho da fonte

Font size: 8

#selecioando uma área no Praat Picture

Select inner viewport: 1, 7.5, 9.2, 11.1

#selecionando os eixos

Axes: 1, 7.7, 9.2, 0

#comandos abaixo são as medidas que serão impressas no Praat Picture

Text: 1.1, "Left", 0.5, "Half", "f0 CPP: ##'f0cpp.f0:2' Hz#"

Text: 1.1, "Left", 1.5, "Half", "Média f0: ##'medidasf0.media:2' Hz#"

Text: 1.1, "Left", 2.5, "Half", "Desvio padrão f0: ##'medidasf0.dp:2' Hz#"

Text: 1.1, "Left", 3.5, "Half", "Coeficiente de variação f0: ##'medidasf0.cv:2'\% #"

Text: 1.1, "Left", 4.5, "Half", "1ª quartil f0: ##'medidasf0.q1:2' Hz#"

Text: 1.1, "Left", 5.5, "Half", "Mediana f0: ##'medidasf0.mediana:2' Hz#"

Text: 1.1, "Left", 6.5, "Half", "3ª quartil f0: ##'medidasf0.q3:2' Hz#"

Text: 1.1, "Left", 7.5, "Half", "Mínimo f0: ##'medidasf0.min:2' Hz#"

Text: 1.1, "Left", 8.5, "Half", "Máximo f0: ##'medidasf0.max:2' Hz#"

Text: 3.1, "Left", 0.5, "Half", "Amplitude f0: ##'medidasf0.amplitude:2' Hz#"

#selecioando uma área no Praat Picture

Select inner viewport: 1, 7.5, 9.2, 11.1

#desenha uma caixa (retângulo) no contorno da área selecionada

Draw inner box

#selecioando uma área do tamanho de um folha A4 no Praat Picture

Select inner viewport: 0, 8.26, 0, 11.69

#criando variável e retirando a string ".wav"

.nome$=nome_audio$ - ".wav"

#salvar imagem do Praat Picture em PDF

#Save as PDF file: pastasaida$ + .nome$ + ".pdf"

#salvar imagem do Praat Picture em PNG com 600 dpi

#Save as 600-dpi PNG file: pastasaida$ + .nome$ +".png"

#salvar imagem do Praat Picture em PNG com 300 dpi

Save as 300-dpi PNG file: pastasaida$ + .nome$ +".png"

endproc

#procedimento p/ inserir os valores das medidas na tabela

procedure tabmedidasf0

#selecionando tabela

select tabela_medidas

#Comando p/ acrescentar linha

Append row

#variável que recebe o número da linha

.r = Get number of rows

# Comandos p/ preencher tabela com strings e valores das medidas

Set string value: .r,"Indice", nome_audio$-".wav"

Set numeric value: .r, "f0CPP", f0cpp.f0

Set numeric value: .r, "Mediaf0", medidasf0.media

Set numeric value: .r, "DPf0", medidasf0.dp

Set numeric value: .r, "CVf0", medidasf0.cv

Set numeric value: .r, "Medianaf0", medidasf0.mediana

Set numeric value: .r, "1ªquartil", medidasf0.q1

Set numeric value: .r, "3ªquartil", medidasf0.q3

Set numeric value: .r, "Maxf0", medidasf0.max

Set numeric value: .r, "Minf0", medidasf0.min

Set numeric value: .r, "Amplitude", medidasf0.amplitude

Set numeric value: .r, "ProporcaoMinMAxf0", medidasf0.propminmax

endproc

Vídeo: Relatório Acústico parte 1

Relatório Acústico (construção)

Script para extrair jitter, RAP, PPQ5

include diretorio.praat

lista_audio=Create Strings as file list: "lista_audio", pastaentrada$+"*.wav"

#seleciona objeto lista_audio

select lista_audio

#Quantidade de strings(audios)

num_audio = Get number of strings

jitter_tabela_columns$ = "Indice jitter_local RAP PPQ5"

jitter_tabela = Create Table with column names: "jitter_tabela", 0, jitter_tabela_columns$

for cont_audio from 1 to num_audio

select lista_audio

#variavel recebe string referente a posição cont_audio

nome_audio$ = Get string: cont_audio

#abrir aquivo de audio

audio = Read from file: pastaentrada$+nome_audio$

piso=75

teto=600

select audio

@medidasjitter: piso, teto

@tabmedidasjitter

select audio

plus medidasjitter.f0lista

plus medidasjitter.pontos

Remove

endfor

select jitter_tabela

Save as comma-separated file: pastasaida$ + "jitter.csv"

select jitter_tabela

plus lista_audio

Remove

procedure medidasjitter: .piso, .teto

select audio

.f0lista=To Pitch (cc): 0, .piso, 15, "no", 0.03, 0.45, 0.01, 0.35, 0.14, .teto

select audio

plus .f0lista

.pontos=noprogress To PointProcess (cc)

select .pontos

.jitter_loc=Get jitter (local): 0, 0, 0.0001, 0.02, 1.3

.jitter_loc_perc=.jitter_loc*100

.jitter_rap=Get jitter (rap): 0, 0, 0.0001, 0.02, 1.3

.jitter_rap_perc=.jitter_rap*100

.jitter_ppq5=Get jitter (ppq5): 0, 0, 0.0001, 0.02, 1.3

.jitter_ppq5_perc=.jitter_ppq5*100

endproc

procedure tabmedidasjitter

select jitter_tabela

Append row

.r = Get number of rows

Set string value: .r,"Indice", nome_audio$

Set numeric value: .r, "jitter_local", medidasjitter.jitter_loc_perc

Set numeric value: .r, "RAP", medidasjitter.jitter_rap_perc

Set numeric value: .r, "PPQ5", medidasjitter.jitter_ppq5_perc

endproc

Mais informações sobre jitter

Vídeo: unidade 3 aula 4

Acrescentando medidas do jitter no Relatório Acústico

#incrementando o relatório com as medidas de jitter

#chamando o script diretorio.praat

include diretorio.praat

#Criando lista de strings com o caminho especificado pelo usuário

lista_audio=Create Strings as file list: "lista_audio", pastaentrada$+"*.wav"

#seleciona objeto lista_audio

select lista_audio

#quantidade de arquivos de audio

num_audio = Get number of strings

#Criando os nomes dos atributos das medidas que serão alocadas na tabela

tabela_medidas_columns$ = "Indice f0CPP Mediaf0 DPf0 CVf0 Medianaf0 1ªquartil 3ªquartil Maxf0 Minf0 Amplitude

... ProporcaoMinMAxf0 jitter_local RAP PPQ5"

# Criando tabela e colocando os nomes dos atributos

tabela_medidas = Create Table with column names: "tabela_medidas", 0, tabela_medidas_columns$

#Início da estrutura de repetição

for cont_audio from 1 to num_audio

#selecionando a lista de áudio

select lista_audio

#variável recebe string referente a posição cont_audio

nome_audio$ = Get string: cont_audio

#ler aquivo de áudio

audio = Read from file: pastaentrada$+nome_audio$

#argumentos para serem preenchidos de f0

piso=75

teto=600

oitava=0.01

saltooitava=0.35

#chamando o procedimento medidasf0

@medidasf0: piso, oitava, saltooitava,teto

#chamando o procedimento f0cpp

@f0cpp

#Teste para atualizar argumentos de f0 e a rerência é f0cpp

#Primeira condição verifica o min e max de f0 e os compara com o valor de f0cpp

if (medidasf0.min < (0.65*f0cpp.f0)) or (medidasf0.max > (1.65*f0cpp.f0))

#atualizando argumentos custo de oitava e salto de oitava

oitava=0.04

saltooitava=0.5

#chamando o procedimento medidasf0

@medidasf0: piso, oitava, saltooitava, teto

endif

#realizado o teste com as mesmas condições novamente

#o objetivo é atualizar valores de referência de frequência inferior e superior

#caso o teste anterior não tenha sido eficiente

if (medidasf0.min < (0.65*f0cpp.f0)) or (medidasf0.max > (1.65*f0cpp.f0))

#atualizando argumentos de limites inferior e superior de f0, custo de oitava e salto de oitava

piso=0.6 * f0cpp.f0

teto=1.4 * f0cpp.f0

oitava=0.04

saltooitava=0.5

#chamando o procedimento medidasf0

@medidasf0: piso, oitava, saltooitava, teto

endif

#chamando o procedimento medidasjitter

@medidasjitter

#chamando o procedimento oscilograma

@oscilograma

#chamando o procedimento contornof0

@contornof0

#chamando o procedimento imprimirmedidas

@imprimirmedidas

#chamando o procedimento tabmedidasf0

@tabmedidasf0

#selecionado e removendo o objeto áudio

select audio

Remove

#fim da estrutura for

endfor

#selecionado a tabela com os valores das medidas

select tabela_medidas

#salvando essa tabela em uma planhilha .csv

Save as comma-separated file: pastasaida$ + "medidas.csv"

#Selecionando a tabela com as medidas

select tabela_medidas

#adicionando na seleção a lista das strings

plus lista_audio

plus medidasf0.f0lista

plus medidasjitter.pontos

# removendo os objetos selecionados

Remove

#procedimento para extrair f0 e suas medidas

procedure medidasf0: .piso, .oitava, .saltooitava, .teto

if variableExists(".f0lista")

select .f0lista

Remove

endif

select audio

#armazenando na variável .f0lista os valores de f0

.f0lista=To Pitch (cc): 0, .piso, 15, "no", 0.03, 0.45, .oitava, .saltooitava, 0.14, .teto

#selecionando o objeto .f0lista

select .f0lista

#valor mínimo de f0

.min=Get minimum: 0, 0, "Hertz", "parabolic"

#valor máximo de f0

.max=Get maximum: 0, 0, "Hertz", "parabolic"

#valor da mediana de f0

.mediana=Get quantile: 0, 0, 0.5, "Hertz"

#valor da média de f0

.media=Get mean: 0, 0, "Hertz"

#valor do desvio padrão de f0

.dp=Get standard deviation: 0, 0, "Hertz"

#valor do 1ª quartil de f0

.q1=Get quantile: 0, 0, 0.25, "Hertz"

#valor do 3ª quartil de f0

.q3=Get quantile: 0, 0, 0.75, "Hertz"

#cálculo do coeficiente de variação de f0

.cv=(.dp/.media)*100

#cálculo da amplitude de f0

.amplitude=.max-.min

#relação de proporção en o mínino e o máximo de f0

.propminmax=.min/.max

endproc

#procedimento para calcular f0 com o cpp

procedure f0cpp

#selecionando o objeto áudio

select audio

#variável que armazena o objeto cepstrograma

.cepstrograma =noprogress To PowerCepstrogram: 60, 0.002, 5000, 50

#selecionando o objeto cepstrograma

select .cepstrograma

#variável que armazana o objeto cepstro

.cepstrogramamarginal=To PowerCepstrum (slice): 0.1

#selecionando o objeto cepstro

select .cepstrogramamarginal

#extraindo a quefrency

.quefrency=Get quefrency of peak: 60, 333.3, "parabolic"

#calculando f0 do cpp

.f0=round(1/.quefrency)

#Selecionando e removendo os objetos cepstrograma e cepstrogramamarginal

select .cepstrograma

plus .cepstrogramamarginal

Remove

endproc

procedure medidasjitter

if variableExists(".pontos")