Cell contains specific text

Generic formula

=ISNUMBER(SEARCH(substring,text))

Explanation

To check if a cell contains specific text, you can use the SEARCH function together with the ISNUMBER function. In the generic version, substring is the specific text you are looking for, and text represents text in the cell you are testing. In the example shown, the formula in D5 is:

=ISNUMBER(SEARCH(C5,B5))

This formula returns TRUE if the substring is found, and FALSE if not.

Note: the SEARCH function will automatically find partial matches.

How the formula works

The SEARCH function returns the position of the search string when found, and the #VALUE! error if not found. We use this fact to test whether the search string is found by using the ISNUMBER function to "catch" valid numeric positions.

ISNUMBER returns TRUE for numbers and FALSE for anything else. So, if SEARCH finds the substring, it returns the position as a number, and ISNUMBER returns TRUE. If SEARCH doesn't find the substring, it returns a #VALUE! error, which causes the ISNUMBER to return FALSE.

Case sensitive version

If you want this formula to be case-sensitive, you can replace the SEARCH function with the FIND function like so:

=ISNUMBER(FIND(substring,text))

If cell contains

If you want to do something when a cell contains specific text, you can wrap the formula in an IF statement like this:

=IF(ISNUMBER(SEARCH(substring,text)), "Yes", "No")

Instead of returning TRUE or FALSE, the formula above, will return "Yes" if substring is found and "No" if not.

With hardcoded search string

To test a cell for a single hardcoded substring, just enclose the text in double quotes. For example, to check A1 for the text "apple" use:

=ISNUMBER(SEARCH("apple",A1))