*
* do PL_TFP_decomp_web_20111014.DO
*
* This program decomposes aggregate labor/multifactor productivity in
"Explaining Reallocation's Apparent Negative Contribution to Growth," by Mitsukuni
Nishida, Amil Petrin, and Saso Polanec
* Written by Mitsukuni Nishida, November 14 2011
*=============
* Set Up
*==============
clear
capture log close
set more off
version 8.0
set scheme s1mono
set memory 500m
*-----------------------
* Read the Data
*-----------------------
if flg_colombia == 1{
cd Colombia
use NPS_Colombia_20110223.dta, clear
cd logfile
log using PL_TFP_decomp_web_Colombia_20111014_emp_shr.txt, text replace
gen id = plant
gen year = datayear
gen valadded = va
gen def_op85 = def_op
gen rmatusd2 = e4
gen rva_1 = valadded*(100/def_op85)
ren pg gross_output
}
else if flg_colombia == 0{
cd Chile
use mergecap_3.dta, clear
drop if year == 1996
cd logfile
log using PL_TFP_decomp_web_Chile_20111014_emp_shr.txt, text replace
gen rva_1 = groutput*(100/def_op85) - (totipurc+elecbval -(finvrm-iinvrm))*(100/def_mat)
gen sic3 = floor(ciiu/10) /* Define the 3 digit sic code.*/
ren groutput gross_output
}
else {
cd Slovenia
use NPS_Slovenia_20110610.dta, clear
cd logfile
if flg_utilization == 1 {
cd cap_util
}
if flg_modified == 1 {
cd modified
}
log using PL_TFP_decomp_web_Slovenia_20111014_emp_shr.txt, text replace
drop skwages unskwages
ren gws skwages
ren gwu unskwages
ren emps sklab
ren empu unsklab
ren sal gross_output
gen tnkall = k*(100/ipi)
if flg_utilization == 1 {
replace tnkall = tnkall*cap_util if cap_util ~=.
}
gen rmatusd2 = (matc -serv)*(100/ppi)
gen valadded = gross_output - (matc-serv)
gen rva = valadded*(100/ppi)
gen rva_1 = rva
gen rva_2 = gross_output*(100/pfi)-(matc-serv)*(100/ppi) /* firm-level price */
if flg_modified == 1 {
replace rva_1 = rva_2 if pfi ~=. & pfi >0.5 & rva_2 ~=.
}
ren ppi def_op85
}
drop if tnkall<=1 | rva_1 <=1 | valadded <0 | gross_output <0
keep sic3 id year valadded unsklab sklab skwages unskwages tnkall rmatusd2 rva_1 gross_output def_op85
gen count_obs = 1
*------------------
* Define Variables
*------------------
gen rva = rva_1
gen ln_RVA = ln(rva)
gen ln_L_b = ln(unsklab)
gen ln_L_w = ln(sklab)
gen ln_K = ln(tnkall)
gen ln_M = ln(rmatusd2)
xtset id year
sort id year
gen dln_RVA = D.ln_RVA
gen dln_L_b = D.ln_L_b
gen dln_L_w = D.ln_L_w
gen dln_K = D.ln_K
*========================================
* Part 2: Production Function Estimation
*========================================
*--------------------------
* (1) Pooled OLS Estimates
*--------------------------
if flg_estimation == 1{
sort sic3
statsby _b _se , by(sic3) saving(PL_tmp_OLS, replace): /*
*/ regress ln_RVA ln_L_b ln_L_w ln_K, cluster(id)
}
joinby sic3 using PL_tmp_OLS
sort id year sic3
* Calculate elasticity
gen els_L_b_OLS = _b_ln_L_b
gen els_L_w_OLS = _b_ln_L_w
gen els_K_OLS = _b_ln_K
drop _b_ln_L_b _b_ln_L_w _b_ln_K
drop _se_ln_L_b _se_ln_L_w _se_ln_K
*--------------------------------
* (2) Levinsohn-Petrin Estimates
*--------------------------------
if flg_estimation == 1{
sort sic3
* Number of reps for the boostrap
global nreps 2
statsby _b _se , by(sic3) saving(PL_tmp_LP, replace): /*
*/ levpet ln_RVA, free(ln_L_b ln_L_w) proxy(ln_M) capital(ln_K) valueadded reps($nreps)
}
joinby sic3 using PL_tmp_LP
sort id year sic3
* Calculate elasticity
gen els_L_b_LP = _b_ln_L_b
gen els_L_w_LP = _b_ln_L_w
gen els_K_LP = _b_ln_K
drop _b_ln_L_b _b_ln_L_w _b_ln_K
drop _se_ln_L_b _se_ln_L_w _se_ln_K
*------------------------------
* (3) Wooldrige - LP Estimates
*------------------------------
* lagged variables
gen ln_L_b_l1 = L.ln_L_b
gen ln_L_w_l1 = L.ln_L_w
gen ln_K_l1 = L.ln_K
gen ln_M_l1 = L.ln_M
* Let p_k and p_m be the exponential order of lnK and lnM
* p_k+p_m = 2
gen km_l1 = ln_K_l1*ln_M_l1
gen k2_l1 = ln_K_l1^2
gen m2_l1 = ln_M_l1^2
* p_k+p_m = 3
gen k2m_l1 = ln_K_l1^2*ln_M_l1
gen km2_l1 = ln_K_l1*ln_M_l1^2
gen k3_l1 = ln_K_l1^3
gen m3_l1 = ln_M_l1^3
* Avoiding multi-colinearity, use 1st order poly. for function f(.)
global exoreg /*
*/ ln_K ln_K_l1 ln_M_l1 /*
*/ km_l1 k2_l1 m2_l1 k2m_l1 km2_l1 k3_l1 m3_l1
global endoreg ln_L_b ln_L_w
global instr ln_L_b_l1 ln_L_w_l1
if flg_estimation == 1{
sort sic3
statsby _b _se , by(sic3) saving(PL_tmp_WLP, replace): /*
*/ ivreg2 ln_RVA $exoreg ($endoreg = $instr), gmm cluster(id)
}
joinby sic3 using PL_tmp_WLP
sort id year sic3
* Calculate elasticity
gen els_L_b_WLP = _b_ln_L_b
gen els_L_w_WLP = _b_ln_L_w
gen els_K_WLP = _b_ln_K
drop _b_ln_L_b _b_ln_L_w _b_ln_K
drop _se_ln_L_b _se_ln_L_w _se_ln_K
*---------------------------------------
* Estimates of Plant-Level Productivity
*---------------------------------------
gen ln_prod_OLS = ln_RVA - (els_L_b_OLS*ln_L_b + els_L_w_OLS*ln_L_w + els_K_OLS*ln_K)
gen ln_prod_LP = ln_RVA - (els_L_b_LP *ln_L_b + els_L_w_LP *ln_L_w + els_K_LP *ln_K)
gen ln_prod_WLP = ln_RVA - (els_L_b_WLP*ln_L_b + els_L_w_WLP*ln_L_w + els_K_WLP*ln_K)
*========================
*
* Part 3: Data Dropping
*
*========================
xtset id year
sort id year
*------------------------------------------------------------------------------
* Drop industries with unsuccessful production function estimates (e.g., negative coeff.,)
*------------------------------------------------------------------------------
if flg_colombia == 1{
drop if sic3 == 314 | sic3 == 353 | sic3 == 354
}
else if flg_colombia == 0{
drop if sic3 == 314 | sic3 == 353 | sic3 == 354 | sic3 == 385
}
else {
drop if sic3 == 26 | sic3 == 21 | sic3 ==35
}
}
drop if ln_prod_OLS <0 | ln_prod_LP <0 | ln_prod_WLP <0
drop if ln_prod_OLS ==. | ln_prod_LP ==. | ln_prod_WLP ==.
sort id year
drop dln_RVA dln_L_b dln_L_w dln_K
gen dln_RVA = D.ln_RVA
gen dln_L_b = D.ln_L_b
gen dln_L_w = D.ln_L_w
gen dln_K = D.ln_K
*-----------------------
* Calculate Cost Shares
*-----------------------
egen sum_va = total(valadded), by(year)
sort id year
gen double shr_skw = skwages/sum_va
gen double shr_unskw = unskwages/sum_va
gen s_skw = skwages /valadded
gen s_unskw = unskwages/valadded
drop if shr_skw > 0.01 | shr_unskw > 0.01
*-------------------------------------------------
* Define flgDiffExist after dropping observation
*-------------------------------------------------
sort id year
gen flgDiffExist = 1 if year == year[_n-1] + 1 & id == id[_n-1]
replace flgDiffExist = 0 if flgDiffExist == .
gen mid_shr_skw = (shr_skw + shr_skw[_n-1])/2
gen mid_shr_unskw = (shr_unskw + shr_unskw[_n-1])/2
replace mid_shr_skw = . if flgDiffExist == 0
replace mid_shr_unskw = . if flgDiffExist == 0
*==============================================================================
*
* Part 4 & 5: BHC(1992) and FHK(2001) Decomposition of Aggregate Prod Growth
*
*==============================================================================
gen L = unsklab + sklab
egen sum_L = total(L), by(year)
gen shr_L = L/sum_L
egen sum_rva= total(rva), by(year)
gen BHCweight = shr_L
sort id year
gen PLweight = rva/sum_rva /* Domar weight for PL decomposition */
gen mid_PLweight = (PLweight + L.PLweight) /2
gen mid_BHCweight = (BHCweight + L.BHCweight)/2
gen BHCweight_lag = L.BHCweight
gen dBHCweight = D.BHCweight
replace mid_PLweight = . if flgDiffExist == 0
replace mid_BHCweight = . if flgDiffExist == 0
*------------------------------------------------
* Define a dummy variable for entering & exiting
*------------------------------------------------
sort id year
gen flg_Entry = 0 if year == year[_n-1]+1 & id == id[_n-1]
gen flg_Exit = 0 if year == year[_n+1]-1 & id == id[_n+1]
replace flg_Exit = 1 if flg_Exit == .
replace flg_Entry = 1 if flg_Entry == .
*========================================================================
*
* Part 4-1 BHC(1992) Aggregate Labor Productivity (ALP) Decomposition
*
*========================================================================
*------------------------------------------------------
* Definition: APG_0 = ARVARL(T) - ARVARL(T-1)
* for three different definitions of real value added
*------------------------------------------------------
gen VL_temp = rva/L
*-----------------------------------------------------------------------------
* Winsor VL by 0.1% since sometime VL gets too huge due to dividing with low L
*-----------------------------------------------------------------------------
if flg_colombia ~= -1{
winsor VL_temp, gen(VL) p(0.001)
}
else {
gen VL = VL_temp
}
egen AggVL = total(BHCweight*VL), by(year)
sort id year
gen AggLPG = D.AggVL/L.AggVL
*-----------------------------------------------------------------------------
* First BHC-LaborProd Decomposition
* A1 = sum_i s_i(t-1)*[VL_i(t) -VL_i(t-1)] + sum_i VL_i(T)*[s_i(t) -s_i(t-1)]
* -- TE_(t-1) ----------------------- -- RE_(t)-----------------------
*-----------------------------------------------------------------------------
sort id year
gen dVL = D.VL
gen VL_lag = L.VL
egen TE_1 = total(BHCweight_lag*dVL), by(year)
egen RE_1 = total(VL* dBHCweight),by(year)
gen A1 = RE_1 + TE_1
gen TE_tm1 = TE_1/L.AggVL
gen RE_t = RE_1/L.AggVL
gen LPG_1 = RE_t + TE_tm1
egen Cov_temp = total(dBHCweight*dVL), by(year)
gen Cov = Cov_temp/L.AggVL
*-----------------------------------------------------------------------------
* Third Decomposition
* A3 = sum_i s_i(t)*[VL_i(t) -VL_i(t-1)] + sum_i VL_i(t-1)*[s_i(t) -s_i(t-1)]
* -- TE_(t) ----------------------- -- RE_(t-1)-----------------------
*-----------------------------------------------------------------------------
egen TE_3 = total(BHCweight*dVL), by(year)
egen RE_3 = total(VL_lag *dBHCweight), by(year)
gen A3 = RE_3 + TE_3
sort id year
gen TE_t = TE_3/L.AggVL
gen RE_tm1 = RE_3/L.AggVL
gen LPG_3 = RE_tm1 + TE_t
*-----------------------------------------------------------------------------
* Second Decomposition (Tornquist Divisia)
* A2 = sum_i ave(shr_L(t) + shr_L(t-1))*[VL_i(t) -VL_i(t-1)]
* ------ TE mid --------------------------------------
* + sum_i ave(VL_(t) + VL_(t-1))* [shr_L(t)-shr_L(t-1)]
* ------ RE mid -------------------------------------
*-----------------------------------------------------------------------------
gen mid_VL = (VL + L.VL)/2
replace mid_VL = . if flgDiffExist == 0
egen TE_2 = total(mid_BHCweight*dVL), by(year)
egen RE_2 = total(mid_VL *dBHCweight), by(year)
gen A2 = RE_2 + TE_2
sort id year
gen TE_avg = TE_2/L.AggVL
gen RE_avg = RE_2/L.AggVL
gen LPG_2 = RE_avg + TE_avg
gen LPG_EE = AggLPG - LPG_2
*=============================================================================
*
* Part 4-2 FHK(2001) Labor Productivity Decomposition
*
*============================================================================= sort id year
gen temp0 = L.AggVL
sort year
by year: egen AggVL_lag = max(temp0)
gen temp1 = VL_lag- AggVL_lag
egen temp2 = total(temp1 *dBHCweight), by(year)
sort id year
gen F_RE_tm1 = temp2/L.AggVL
sort year
egen temp3 = total(BHCweight* (VL - AggVL_lag) * flg_Entry), by(year)
egen temp3_1 = total(BHCweight* VL * flg_Entry), by(year)
sort id year
gen F_G_Entry = temp3/L.AggVL
gen LPG_G_Entry = temp3_1/L.AggVL
sort year
egen temp4 = total(BHCweight* (VL - AggVL) * flg_Exit), by(year)
egen temp4_1 = total(BHCweight* VL * flg_Exit), by(year)
sort id year
gen F_G_Exit = - L.temp4/L.AggVL
gen LPG_G_Exit = - L.temp4_1/L.AggVL
gen F_LPG_EE2 = F_G_Entry + F_G_Exit
gen LPG_EE2 = LPG_G_Entry + LPG_G_Exit
drop temp0 temp1 temp2 temp3 temp3_1 temp4 temp4_1
*==============================================================
*
* Part 5-1 BHC(1992) Multifactor Productivity Decomposition
*
*==============================================================
*--------------------------------------------------------
* BHC Aggregate Productivity Growth with Entry and Exit
*--------------------------------------------------------
egen BHC_Agg_prod_WLP = total(BHCweight*ln_prod_WLP), by(year)
sort id year
gen BHC_PG_incEE_WLP = D.BHC_Agg_prod_WLP
*---------------------------------------------------------------
* Entry and Exit components to BHC Aggregate Productivity Growth
*---------------------------------------------------------------
egen BHC_G_Entry_WLP = total(BHCweight*ln_prod_WLP * flg_Entry), by(year)
egen temp0 = min(year)
replace BHC_G_Entry_WLP =. if year == temp0
egen temp1_WLP = total(BHCweight*ln_prod_WLP * flg_Exit), by(year)
sort id year
gen BHC_G_Exit_WLP = - L.temp1_WLP
gen BHC_Net_EE_WLP = BHC_G_Entry_WLP + BHC_G_Exit_WLP
drop temp0 temp1_OLS temp1_LP temp1_WLP
*--------------------------------
* Prepare lag and diff variables
*--------------------------------
sort id year
gen flg_agg = 1 if D.ln_prod_OLS ~=. & D.ln_prod_LP ~=. & D.ln_prod_WLP ~=.
replace flg_agg = 0 if flg_agg ==.
gen dln_prod_WLP = D.ln_prod_WLP
gen ln_prod_lag_WLP = L.ln_prod_WLP
gen mid_ln_prod_WLP = (ln_prod_lag_WLP + ln_prod_WLP)/2
*------------------------------------------------
* First Decomposition
* A1 = sum_i s_i(t-1)*[ln_prod_i(t) -ln_prod_i(t-1)] + sum_i ln_prod_i(t)*[s_i(t) -s_i(t-1)]
* -- TE_(t-1) --------------------------------- -- RE_(t)----------------------------
*
*------------------------------------------------
egen BHC_TE_tm1_WLP = total(BHCweight_lag * dln_prod_WLP * flg_agg), by (year)
egen BHC_RE_t_WLP = total(dBHCweight * ln_prod_WLP * flg_agg), by (year)
*------------------------------------------------
* Third Decomposition
* A3 = sum_i s_i(t)*[ln_prod_i(t) -ln_prod_i(t-1)] + sum_i ln_prod_i(t-1)*[s_i(t) -s_i(t-1)]
* -- TE_(t) --------------------------------- -- RE_(t-1)----------------------------
*
*------------------------------------------------
egen BHC_TE_t_WLP = total(BHCweight * dln_prod_WLP * flg_agg), by (year)
egen BHC_RE_tm1_WLP = total(dBHCweight * ln_prod_lag_WLP * flg_agg), by (year)
*------------------------------------------------
* Second Decomposition (Tornquist Divisia)
* A2 = sum_i ave(s_i(t) + s_i(t-1))*[ln_prod_i(t) -ln_prod_i(t-1)]
* ------ TE mid ------------------------------------------------
* + sum_i [ln_prod_i(t) + ln_prod_i(t-1)]/2 * [s_i(t)-s_i(t-1)]
* ------ RE mid --------------------------------------------
*------------------------------------------------
egen BHC_TE_mid_WLP = total(mid_BHCweight * dln_prod_WLP * flg_agg), by (year)
egen BHC_RE_mid_WLP = total(dBHCweight * mid_ln_prod_WLP * flg_agg), by (year)
*------------------------------------------------
* "covariance term"
* = sum_i [s_i(t)-s_i(t-1)] * [ln_prod_i(t) -ln_prod_i(t-1)]
* ------ COV---------------------------------------------
*-------------------------------------------------
egen BHC_cov_WLP = total(dBHCweight * dln_prod_WLP * flg_agg), by (year)
*=============================================================
*
* Part 5-2 FHK(2001) Multifactor Productivity Decomposition
*
*=============================================================
*---------------------------------------------------------
* Between components to FHK Aggregate Productivity Growth
*---------------------------------------------------------
sort id year
gen temp_WLP = L.BHC_Agg_prod_WLP
sort year
by year: egen BHC_Agg_prod_WLP_lag = max(temp_WLP)
drop temp_WLP
gen temp3_WLP = ln_prod_lag_WLP - BHC_Agg_prod_WLP_lag
egen FHK_RE_tm1_WLP = total(dBHCweight * temp3_WLP * flg_agg), by (year)
*----------------------------------------------------------------
* Entry and Exit components to FHK Aggregate Productivity Growth
*----------------------------------------------------------------
gen temp4_WLP = ln_prod_WLP - BHC_Agg_prod_WLP_lag
egen FHK_G_Entry_WLP = total(BHCweight * temp4_WLP * flg_Entry), by(year)
gen temp5_WLP = ln_prod_WLP - BHC_Agg_prod_WLP
egen temp6_WLP = total(BHCweight * temp5_WLP * flg_Exit), by(year)
sort id year
gen FHK_G_Exit_WLP = - L.temp6_WLP
gen FHK_Net_EE_WLP = FHK_G_Entry_WLP + FHK_G_Exit_WLP
*----------------------------------------
* Decomposing BHC Reallocation (t-1,t)
*----------------------------------------
* Generate # of firms
sort year
by year: egen no_firms = count(id)
sort id year
gen temp_lag = L.no_firms
sort year
by year: egen no_firms_lag = max(temp_lag)
drop temp_lag
* Generate average share
sort year
by year: gen s_t = 1/no_firms
by year: gen s_t_lag = 1/no_firms_lag
gen st_st_lag = s_t - s_t_lag
gen temp1 = BHCweight - s_t
gen temp2 = BHCweight_lag - s_t_lag
egen BHC_RE_term1 = total( temp1 * ln_prod_lag_WLP * flg_agg), by (year)
egen BHC_RE_term2 = total(-1* temp2 * ln_prod_lag_WLP * flg_agg), by (year)
egen BHC_RE_term3 = total( st_st_lag * ln_prod_lag_WLP * flg_agg), by (year)
gen BHC_RE_term1_2 = BHC_RE_term1 + BHC_RE_term2
drop temp1 temp2
*-----------------------------------------------------------------
* Decomposing ALP (Aggregate Labor Prod.) BHC Between term (t-1)
*-----------------------------------------------------------------
gen temp1 = BHCweight - s_t
gen temp2 = BHCweight_lag - s_t_lag
sort id year
gen flg_agg_alp = 1 if D.VL ~=.
replace flg_agg_alp = 0 if flg_agg_alp ==.
sort id year
egen RE_term1_tmp = total( temp1 * VL_lag * flg_agg_alp), by (year)
egen RE_term2_tmp = total(-1* temp2 * VL_lag * flg_agg_alp), by (year)
egen RE_term3_tmp = total( st_st_lag * VL_lag * flg_agg_alp), by (year)
sort id year
gen RE_term1 = RE_term1_tmp/L.AggVL
gen RE_term2 = RE_term2_tmp/L.AggVL
gen RE_term3 = RE_term3_tmp/L.AggVL
gen RE_term1_2 = RE_term1 + RE_term2
drop temp1 temp2
sort id year
gen G_no_firms = D.no_firms/L.no_firms
*====================================================================
*
* Part 6: PL(2010) Aggregate productivity growth with Entry & Exit
*
*====================================================================
*-------------------------------------
* VA Growth: (1) With Entry and Exit
*-------------------------------------
gen temp1 = log(sum_rva)
sort id year
gen VAG_incEE_2 = D.sum_rva/L.sum_rva
drop temp1
*------------------------------------------------------
* VA Growth: (2) Without Entry and Exit = Stayers Only
*------------------------------------------------------
egen VAG_excEE = total(mid_PLweight * dln_RVA), by(year)
*--------------------------------------------------------
* WX (Wage Expenditure) Growth: (1) With Entry and Exit
*--------------------------------------------------------
sort id year
replace skwages = 0 if skwages ==.
replace unskwages = 0 if unskwages ==.
gen r_skwages = skwages*100/def_op85
gen r_unskwages = unskwages*100/def_op85
egen sum_r_skwages = total(r_skwages), by(year)
egen sum_r_unskwages = total(r_unskwages), by(year)
sort id year
gen WXG_incEE_w_2 = D.sum_r_skwages/L.sum_rva
gen WXG_incEE_b_2 = D.sum_r_unskwages/L.sum_rva
*-----------------------------------------------------------
* WX (Wage Expenditure) Growth: (2) Without Entry and Exit
*-----------------------------------------------------------
egen WXG_excEE_w = total(mid_shr_skw * dln_L_w), by(year)
egen WXG_excEE_b = total(mid_shr_unskw * dln_L_b), by(year)
*--------------------------------------------
* Construct PL Aggregate Productivity Growth
*--------------------------------------------
gen PL_PG_incEE_2 = VAG_incEE_2 - WXG_incEE_w_2 -WXG_incEE_b_2
gen PL_PG_excEE = VAG_excEE - WXG_excEE_w -WXG_excEE_b
gen PL_PG_netEE_2 = PL_PG_incEE_2 - PL_PG_excEE
* Decomposition of PL-RE into Input-specific RE (Entry and Exit excluded)
* PL-RE of blue-collar labor
gen mid_wedge_b_WLP = mid_PLweight*els_L_b_WLP - mid_shr_unskw
egen PL_RE_b_WLP = total(mid_wedge_b_WLP*dln_L_b), by(year)
* PL-RE of white-collar labor
gen mid_wedge_w_WLP = mid_PLweight*els_L_w_WLP - mid_shr_skw
egen PL_RE_w_WLP = total(mid_wedge_w_WLP*dln_L_w), by(year)
* PL- total RE and labor RE
gen PL_RE_total = PL_PG_incEE_2 - PL_TE_mid_WLP - PL_PG_netEE_2
gen PL_RE_labor = PL_RE_b_WLP + PL_RE_w_WLP
* PL-TE
egen PL_TE_mid_WLP = total(mid_PLweight * dln_prod_WLP * flg_agg), by (year)
*==================
*
* Part 7: Results
*
*==================
sort year
save before_collapse.dta, replace
collapse (mean) VAG_incEE_2 AggLPG TE_tm1 RE_tm1 F_RE_tm1 Cov LPG_EE2 F_LPG_EE2 /*
*/ PL_PG_incEE_2 PL_TE_mid_WLP PL_RE_total PL_RE_labor PL_PG_netEE2 /*
*/ RE_term1_2 RE_term3 G_no_firms /*
*/ BHC_PG_incEE_WLP BHC_TE_tm1_WLP BHC_RE_tm1_WLP FHK_RE_tm1_WLP BHC_cov_WLP BHC_Net_EE_WLP FHK_Net_EE_WLP /*
*/ , by(year)
tsset year
sort year
*---------------------------
* Make variables percentage
*----------------------------
foreach var of varlist _all {
replace `var' = `var'*100
format `var' %8.2f
}
replace year = year/100
format year %8.0g
*---------------------
* Tables in the paper
*---------------------
* Table 1-3, 8,
list year VAG_incEE_2 AggLPG TE_tm1 RE_tm1 F_RE_tm1 Cov LPG_EE2 F_LPG_EE2
* Table 4, 5, A1
list year VAG_incEE_2 PL_PG_incEE_2 PL_TE_mid_WLP PL_RE_total PL_RE_labor PL_PG_netEE2
* Table 6, 7, A2
list year RE_tm1 RE_term1_2 RE_term3 G_no_firms
* Table 9, 10, A3, A4
list year BHC_PG_incEE_WLP BHC_TE_tm1_WLP BHC_RE_tm1_WLP FHK_RE_tm1_WLP BHC_cov_WLP BHC_Net_EE_WLP FHK_Net_EE_WLP
save PL_TFP_decomp_web.dta, replace
log close
exit