/* Preliminary Descriptives for ANCOVA variables */
PROC MEANS Data = SASUSER.Adv04 Mean STD Skewness Kurtosis Min Q1 Median Q3 Max;
VAR Influenc Satis; RUN;
/* Preliminary correlation among ANCOVA variables */
PROC CORR Data = Sasuser.Adv04; VAR sex1f2m Satis Influenc; RUN;
/* Request a scatterplot for DV and covariate: should be linear */
PROC GPLOT Data = Sasuser.Adv04; PLOT Influenc*Satis; RUN;
/* Request boxplots on DV after sorting by gender */
PROC Sort Data = Sasuser.Adv04; By sex1f2m;
PROC Boxplot Data = SASUSER.Adv04;
Plot Influenc*sex1f2m / BOXSTYLE=SCHEMATIC; RUN;
/* Homogeneity of regression test for ANCOVA: Interaction should be NS */
PROC GLM Data = Sasuser.Adv04;
CLASS sex1f2m;
MODEL Influenc = sex1f2m | Satis; RUN; QUIT;
/* ANOVA with IV=Sex(1=F,2=M) & DV=Influence */
PROC GLM Data = Sasuser.Adv04;
CLASS sex1f2m; MODEL Influenc = sex1f2m / effectsize alpha=.05;
LSMEANS sex1f2m /PDIFF CL; RUN; QUIT;
/* ANCOVA with IV=Sex(1=F,2=M) & DV=Influence COV=Satisfaction */
PROC GLM Data = Sasuser.Adv04;
CLASS sex1f2m;
MODEL Influenc = sex1f2m Satis / effectsize alpha=.05;
LSMEANS sex1f2m /PDIFF CL; RUN; QUIT;