Ограничение количества файлов бэкапа

Файл tcbackup1.cmd:

@echo off

REM http://forum.script-coding.com/viewtopic.php?id=7493

:: Вывод n первых строк файла

::

:: Использование:

:: head n filename

::

:: Пример:

:: head 10 %windir%\System32\drivers\etc\hosts

:: Необходим временный файл для хранения n номеров первых строк в виде "[n]"

(

for /l %%n in ( 1, 1, %~1 ) do (

echo.[%%n]

)

)>"%TEMP%\$$$head.txt"

:: нумеруем каждую строку

:: ищем только строки с заданным номером и выводим эти строки

:: по окончании временный файл удаляем

for /f "tokens=1,* delims=]" %%n in (

'find /n /v "" "%~2" ^| findstr /b /l /g:"%TEMP%\$$$head.txt" ^&^& del "%TEMP%\$$$head.txt"'

) do (

echo.%%o >> C:\programs\cmd\tcbackup2.txt

)

FOR /F %%f in ('TYPE C:\programs\cmd\tcbackup2.txt') DO (

MOVE C:\temp\TrustClient\1\%%f C:\temp\TrustClient\2\

)

DEL /F /Q C:\temp\TrustClient\1\*.*

MOVE C:\temp\TrustClient\2\*.* C:\TrustClient\backup\

DEL C:\programs\cmd\tcbackup2.txt

:END

Что он делает:

• Создаёт временный файл для хранения заданного количества строк. Количество строк передаётся в переменную %~1 в виде параметра при вызове скрипта (число 5):

(

for /l %%n in ( 1, 1, %~1 ) do (

echo.[%%n]

)

)>"%TEMP%\$$$head.txt"

• Выводит в текстовый файл строки с заданными номерами из файла-списка, который передаётся скрипту как второй параметр в переменной %~2 (файл C:\programs\cmd\tcbackup.txt):

for /f "tokens=1,* delims=]" %%n in (

'find /n /v "" "%~2" ^| findstr /b /l /g:"%TEMP%\$$$head.txt" ^&^& del "%TEMP%\$$$head.txt"'

) do (

echo.%%o >> C:\programs\cmd\tcbackup2.txt

)

• Используя созданный на предыдущем шаге временный текстовый файл C:\programs\cmd\tcbackup2.txt перемещает файлы бэкапа из временного каталога C:\temp\TrustClient\1 во второй временный каталог C:\temp\TrustClient\2. Это те пять файлов, которые будут сохранены:

FOR /F %%f in ('TYPE C:\programs\cmd\tcbackup2.txt') DO (

MOVE C:\temp\TrustClient\1\%%f C:\temp\TrustClient\2\

)

• Оставшиеся в первом временном каталоге файлы удаляются: DEL /F /Q C:\temp\TrustClient\1\*.*
• Файлы из второго временного каталога перемещаются обратно, в каталог бэкапов: MOVE C:\temp\TrustClient\2\*.* C:\TrustClient\backup\
• Временный файл-список удаляется: DEL C:\programs\cmd\tcbackup2.txt

В планировщике Windows нужно создать задание, которое ежедневно будет запускать скрипт tcbackup.cmd.