Bank

#CLASS {Bank}

#ALIAS helpBank {

#PRINT {%crlf <C dodgerblue>-----Bank Help File-----</C>}

#PRINT { Keeps track of all character's bank account balances.}

#PRINT {}

#PRINT { Type <C dodgerblue>balBank</C> to view current balance for current character.}

#PRINT { Note: helpBank shows all balances for all characters.}

#PRINT {}

#VAR bankTotal {}

#PRINT { <C dodgerblue>--Character Balance--</C>}

#SORT bankList

#FORALL @bankList {

#PRINT { %i %repeat(" ",%eval(13-%len(%i))) %repeat(" ",%eval(4-%len(%eval(%eval(%concat(~@,bankAccount,%i))/20))))%eval(%eval(%concat(~@,bankAccount,%i))/20) gold crowns.}

#ADD bankTotal %eval(%eval(%concat(~@,bankAccount,%i))/20)

}

#PRINT {}

#PRINT { Total balance: <C goldenrod>@bankTotal</C> gold crowns.}

#PRINT {}

}

#VAR bankList {}

#VAR bankTotal {}

#ALIAS balBank {

#PRINT {%crlf %char's balance is: <C dodgerblue>%eval(%eval(%concat(~@,bankAccount,%char))/20)</C> gold crowns. %crlf}

}

#TRIGGER "bankBalance" {whispers to you 'Your balance is the equivalent of (%d) copper.'} {

#VAR %concat(bankAccount,%char) %1

} "" {case|disable}

#TRIGGER "bankDeposit" {tells you, '(%d) copper has been credited to your account.'} {

#ADD %concat(bankAccount,%char) %1

} "" {case|disable}

#TRIGGER "bankWithdraw" {tells you '(%d) copper has been deducted from your account.'} {

#ADD %concat(bankAccount,%char) -%1

} "" {case|disable}

#TRIGGER "bankPrompt" {{o|*} * >} {

#T- bankPrompt

#T- bankBalance

#T- bankDeposit

#T- bankWithdraw

} "" {disable|nocr|prompt}

#ONINPUT "bankBalInput" {^{bal|bala|balan|balanc|balance}$} {

#T+ bankBalance

#T+ bankPrompt

} "" {}

#ONINPUT "bankDepInput" {^{de|dep|depo|depos|deposi|deposit} (%d)$} {

#T+ bankDeposit

#T+ bankPrompt

} "" {}

#ONINPUT "bankWithInput" {^{wit|with|withd|withdr|withdra|withdraw} (%d)$} {

#T+ bankWithdraw

#T+ bankPrompt

} "" {}

#EVENT onConnect {

#IF (%class(%concat(bankAccount,%char))=-1) {

#ADDITEM bankList %char

#VAR %concat(bankAccount,%char) 0 {_nodef} "Bank"

}

}

#CLASS 0