Double Transducer: Rotational Speed to Heat

// Double transducer project, RPM to Heat. 

// Code uses hall sensor to pick up RPM, maps that to volume of speaker, mic picks up volume, vol

// from mic maps to bulb brightness. Extra LED to check if mic picking up vol above a certain level.

// Pins:

//Speaker: INPUT --> pin 5. 

//Hall Sensor: INPUT --> pin 3. 

//LED: INPUT --> pin 13.

//Mic: envelope--> INPUT--> pin A0.

//Bulb: OUTPUT --> pin 6.

//LCD: SDA, SCL.

#include <Wire.h>

#include <LiquidCrystal_I2C.h>

#include "Volume.h"

Volume vol;

int speakerPin = 5;     // only

int hallSensorPin = 3;  // + to 5v

int ledPin = 13;        // testing purposes

int micPin = A0;        // + to 5v

int bulbPin = 6;        // closed 5v, + to main ground

int delayLCD = 500;

unsigned long LCDtimer = 0;

LiquidCrystal_I2C screen(0x27, 16, 2);

int micState = 0;

int rotations = 0;  // below all for hall sensor & rpm

int rpm = 0;

bool hallPrevious = 1;

bool hallState = 1;

unsigned long hallPreviousTime = 0;

unsigned long hallCurrentTime = 0;

void setup() {

  Serial.begin(9600);

  pinMode(ledPin, OUTPUT);

  pinMode(bulbPin, OUTPUT);

  pinMode(hallSensorPin, INPUT);

  pinMode(speakerPin, OUTPUT);

  pinMode(micPin, INPUT);

  screen.init();

  screen.backlight();

  screen.home();

  vol.begin();  // note that volume library uses vol.millis() & vol.delay()

}

void loop() {

  hallState = digitalRead(hallSensorPin);          // check if hallState has changed

  if (hallState == HIGH && hallPrevious == LOW) {  // if the magnet state has changed from off to on

    rotations += 1;

    rpm = 60000 / (hallCurrentTime - hallPreviousTime);  // time inbetween rotations

    hallPreviousTime = vol.millis();                     // reset rotation timer

  }

  hallCurrentTime = vol.millis();

  hallPrevious = digitalRead(hallSensorPin);                // log current hallState

  int rpmMap = map(constrain(rpm, 0, 500), 0, 500, 0, 99);  // map for LCD

                                                            // have seen rpm hit > 5000, sensor is very finicky

                                                            // pretty sure I have bad wiring on hall & LCD chip board

  vol.delay(15);                                            // hopefully helps here?

  int speakerVol = map(constrain(rpm, 0, 500), 0, 500, 0, 255);  // map for Speaker output

  int speakerVolMap = map(speakerVol, 0, 255, 0, 99);            // map for LCD

  vol.tone(150, speakerVol);                                     // (frequency, volume 0 to 255)

  int micState = constrain(analogRead(micPin), 5, 150);  // (speakerVol = 255) = (micState ~ 137)

  int micMap = map(micState, 5, 150, 0, 99);             // map for LCD

  int brightness = map(micState, 5, 150, 0, 255);        // map for Bulb output

  int brightnessMap = map(brightness, 0, 255, 0, 99);    // map for LCD

  analogWrite(bulbPin, brightness);  // Bulb output happening

  if (micState > 127) {  // misc LED for testing audio vvv

    digitalWrite(ledPin, HIGH);

  } else {

    digitalWrite(ledPin, LOW);

  }

  if (vol.millis() - LCDtimer >= delayLCD) {  //LCD

    screen.clear();

    screen.setCursor(0, 0);

    screen.print("i:");

    screen.setCursor(3, 0);

    screen.print(rpmMap);  // rpm (hall sensor) input

    screen.setCursor(7, 0);

    screen.print("m:");

    screen.setCursor(9, 0);

    screen.print(speakerVolMap);  // speaker volume output

    screen.setCursor(9, 1);

    screen.print(micMap);  // mic (sensor) input

    screen.setCursor(12, 1);

    screen.print("o:");

    screen.setCursor(14, 1);

    screen.print(brightnessMap);  // bulb brightness output

    LCDtimer = vol.millis();

  }

}