DESCRIPTION.

La procdure PROC_TVmodifyitem() permet de modifier l'intitulé et/ou l'identifiant d'un élément existant.

SYNTAXE.

PROC_TVmodifyitem( adresse , chaine , identifiant ) 

REMARQUES

adresse doit être l'identifiant de la variable qui a mémorisé la valeur retournée par la fonction FN_TVinsertitem() qui a été appelé pour créer l'élément à modifier.

chaine doit être une chaine de caractères quelconque mais valide. chaine sera affichée pour identifier l'élément dans l'arbre.

identifiant doit être une valeur numérique strictement positive. Dans arbre toutes les valeurs de identifiant doivent être unique.

Rappel : restez très prudent sur la gestion de la mémoire lors de la création et des modifications que vous apporterez quand vous utilserez les procédures et fonctions du module treeview.bbc.  

Rappel : une fonction FN_TVcreatetree() doit être appelé avant toute utilisation d'une procédure ou fonction du module treepview.bbc sur un arbre.  

La fonction PROC_TVmodifyitem() est importée depuis le module treeview.bbc. 

EXEMPLE.

REM --- INITIALISATION GENERALE ---

INSTALL @lib$ + "treeview.bbc" : REM - importe les procedures et fonctions du modules dans le script

MODE 8 : REM - bascule la fenetre de sortie avec un mode graphique

VDU 26 : REM - restaure les paramettres de surfaces textuelle et graphique par défaut

VDU 23,23,10;0;0;0;0; : REM - optimisation du rendu des polices sous SDL

CLS : COLOUR 12 : COLOUR 142 : REM - modifie les couleurs de la surface textuelle

CLG : GCOL 12 : GCOL 142 : REM - modifie les couleurs de la surface graphique

DIM LST_Noeuds%%( 5 , 5 )

REM --- Creation d'un arbre ---

TRV_Arbre%% = FN_TVcreatetree( @lib$ + "DejaVuSans" , 12 ) : REM - cree un nouvel arbre avec une police specifique

PROC_Elements( TRV_Arbre%% ) : REM - appel la procédure qui placera les elements dans l'arbre

PROC_TVmodifyitem( LST_Noeuds%%( 1 , 3 ) , "Niveau 01 MODIFIE" , 901 )

PROC_TVmodifyitem( LST_Noeuds%%( 3 , 2 ) , "Niveau 03 MODIFIE" , 902 )

PROC_TVmodifyitem( LST_Noeuds%%( 2 , 1 ) , "Niveau 02 MODIFIE" , 903 )

REM --- Gestion des actions sur l'arbre ---

REPEAT : REM - debute un boucle pour la survaillance des actions sur l'arbre

kelement%% = FN_TVviewtree( TRV_Arbre%% ) : REM - attend une action sur l'arbre pour continuer le programme

VDU 4 : PRINT TAB( 0 , 20 ) "Identifiant : " ; kelement%% : REM - affiche la valeur retournee par FN_TVviewtree()

PRINT "Appuyez sur entree pour continuer ..." : kpause$ = GET$

PRINT TAB( 0 , 20 ) "En attente ..." + STRING$( 20 , " " ): PRINT STRING$( 70 , " " )

UNTIL kelement%% = 2 : REM - sort de la boucle de la surveillance de l'arbre

REM --- Fin du programme ---

CLS : CLG : REM - efface l'arbre

PRINT ' "Test du module treeview.bbc termine."

PRINT " Au revoir."

END 

REM --- DEFINITIONS DES PROCEDURES PERSONNALISEES ---

DEF PROC_Elements( TRV_Arbre%% ) 

LST_Noeuds%%( 1 , 0 ) = FN_TVinsertitem( TRV_Arbre%% , 0 , "Niveau 01", 10 )

LST_Noeuds%%( 1 , 1 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 1 , 0 ) , "Niveau 01 A" , 101 )

LST_Noeuds%%( 1 , 2 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 1 , 0 ) , "Niveau 01 B" , 102 )

LST_Noeuds%%( 1 , 3 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 1 , 0 ) , "Niveau 01 C" , 103 )

LST_Noeuds%%( 1 , 4 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 1 , 0 ) , "Niveau 01 D" , 104 )

LST_Noeuds%%( 2 , 0 ) = FN_TVinsertitem( TRV_Arbre%% , 0 , "Niveau 02" , 20 )

LST_Noeuds%%( 2 , 1 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 2 , 0 ) , "Niveau 02 A" , 201 )

LST_Noeuds%%( 2 , 2 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 2 , 0 ) , "Niveau 02 B" , 202 )

LST_Noeuds%%( 3 , 0 ) = FN_TVinsertitem( TRV_Arbre%% , 0 , "Niveau 03" , 30 )

LST_Noeuds%%( 3 , 1 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 3 , 0 ) , "Niveau 03 A" , 301 )

LST_Noeuds%%( 3 , 2 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 3 , 0 ) , "Niveau 03 B" , 302 )

LST_Noeuds%%( 3 , 3 ) = FN_TVinsertitem( TRV_Arbre%% , LST_Noeuds%%( 3 , 0 ) , "Niveau 03 C" , 303 )

ENDPROC