DESCRIPTION.

La fonction FN_getcomboboxselect() retourne l'index de la sélection actuelle d'une liste déroulante de sélections.

SYNTAXE.

kindex% = FN_getcomboboxselect( boite , controle )

REMARQUES.

boite doit être l'identifiant de la boite de dialogue contenant la liste déroulante de sélections. Il s'agit du nom de la variable qui a reçu la valeur retournée par la fonction FN_newdialog() pour la création de boite.

controle doit être l'identifiant de la liste déroulante de sélections.

Voir la fonction FN_newdialog() qui permet de déclarer et de créer une boite de dialogue. 

Voir la procédure PROC_combobox() qui crée une liste déroulante de choix dans une boite de dialogue.

Voir la procédure FN_getdlgitemtext() qui retourne la valeur de la sélection d'une liste déroulante de choix.

La procédure FN_getcomboboxselect() est importée depuis le module dlglib.bbc. 

EXEMPLE.

REM --- Importation des modules ---

REM --- Module de la bibliothèque BBC BASIC ---

INSTALL @lib$ + "dlglib.bbc"

REM --- Chargement de la police de caracteres par defaut ---

OSCLI "FONT """ + @lib$ + "DejaVuSans"",12" 

REM --- Initialisation des elements de la liste ---

DIM LST_Choix$( 10 ) 

FOR kindex = 0 TO 10 : LST_Choix$( kindex ) = "Element " + CHR$( 65 + kindex ) : NEXT kindex

REM --- Creation d'une boite de dialogue nommee DLG_Test de 160 x 60 unites intitulee Test ---

DLG_Test = FN_newdialog( "Test ..." , 60 , 100 )

kselection = FN_setproc( PROC_Action() )

REM --- Creation des controles de la boite de dialogue ---

PROC_button( DLG_Test , "Fermer." , 8 , 10 , 80 , 40 , 15 , 0 )

PROC_combobox( DLG_Test , "Defaut." , kselection , 5 , 5 , 50 , 70 , 0 ) 

PROC_setcomboboxarray( DLG_Test , kselection , LST_Choix$() , 7 )

REM --- Affichage de la boite de dialogue et attende des choix de l'utilisateur ---

kcontrole = FN_showdialog( DLG_Test , &FFFFFFFF80000000 , &FFFFFFFF80000000 )  

REM --- Fermeture de la boite de dialogue ---

PROC_closedialog( DLG_Test ) 

REM --- Fin du programme ---

PRINT : PRINT "Au revoir."

END

REM --- DEFINITION DES METHODES PERSONNALISEES ---

REM --- Procedures d'appel de la boite de dialogue DLG_Test ---

DEF PROC_Action( Qboite , Qliste ) : 

PRINT TAB( 0 , 0 ) "Index de la selection : " , FN_getcomboboxselect( Qboite , Qliste ) , "     "

PRINT TAB( 0 , 1 ) "Valeur de la selection : " , FN_getdlgitemtext( Qboite , Qliste ) , "     "

ENDPROC