BASICプログラミング入門

はじめに

最近では，社会のどのような分野に於いてもコンピュータ (computer) の必要性を否定する人はほとんどいなくなった。しかしながら，その利用法となると人それぞれの考え方があり，その人の置かれている立場，どのような仕事をしているかにより千差万別である．職域の広い薬学の分野は例外ではない．もっとも見解の分かれる典型的な分野といっても過言ではない．ワープロや表計算だけできればそれ以上は必要ないと本気で主張する人もいれば，簡単なプログラムくらいは書けないと仕事ができないと主張する人もいる．

ところで，文部省大学審議会は，２１世紀に向けた大学の使命として問題提起能力，問題解決能力など創造的な仕事ができる人材を育成することを提言してい る．一方，薬剤師の職能として医薬品に関する様々な情報の提供や薬歴管理など薬剤師が情報を収集，加工，蓄積し患者や医療従事者に向けて積極的に情報発信することが求められて久しいが，人材不足のため機能していない．

熊本大学薬学部では，全国の薬系大学に先駆けて，プログラミング(programming)演習を実施してきた（昭和５９年～）．我々の長年の経験では，簡単なプログラムを理解することで「コンピュータの仕組み」，「データ（ファイル）構造」，「処理の流れ」や「データの精度」等を効率的に理解することができるなどその波及効果はきわめて大きいことを実感した．さらに，コンピュータを搭載した測定器や機器類の理解，ネットワーク (network)等を介した情報資源の有効利用を通して限られた地球資源を節約するという観点からもきわめて意義が大きいものと確信する．

崇城大学薬学部の情報処理演習においては，プログラミング言語としてBASIC (Beginner's All-purpose Symbolic Instruction Code) を用いたアルゴリズムの演習を行う．処理言語としては，Windows用に開発された十進BASICを使用する（本実習ではMacintosh PC上でWIndows OSを操作する）．十進BASICはインターネットを利用して無料で入手できるフリーソフトウエア (freeware) である．十進BASICはインタプリタ( interpreter)であるが，基本仕様のBASICであるため初心者向きであり，複雑な翻訳手続を理解する必要がなくプログラムを完成させることができる．

プログラミング対応年齢について

プログラミングの能力は年齢に反比例する．国の「第五世代コンピュータプロジェクト」では３５才が定年と言われている．実習の過程で，プログラミング経験の無い先輩，年寄りの影響を受けないこと（既成品を使うことに満足している）．プログラミングの「独特の思考パターン」は君たちの年齢でしか対応できない．数学などと同じで，生きていくために必須なものではないが，柔軟に対応できる能力を持った年齢で対応しておくことの大切さを認識してほしい．

プログラミング演習手順

１）フローチャートの作成

プログラムを作る前に必ず処理の流れ図（flowchart , フローチャート）を作り，それにそってBASIC言語を当てはめプログラムを完成させる．

２）プログラム作成

BASIC言語の場合，描画の命令語（グラフィックコマンド）はBASIC言語の種類によって異なるので，必ずマニュアルを参照すること．

３）プログラムの実行

実行 (RUN)するとプログラム全体がチェックされる．文法上不都合な点があると，簡単なコメントが英文で表示されるので修正する．作成したプログラムはテキストで保存する．実行結果は記録する．画像として保存する場合は切り出しソフト（グラブ）を用いる．

＜指導教官から一言＞

１）予習、復習

コンピュータと流暢に対話するためには、予習、復習が必須であることは言うまでもない．毎年「予習、復習なしの実習はまったく意味がない」と注意を喚起しているが，無視する学生が多いのが実情である．

２）英語との関連

他のコンピュータ言語と同様にBASICは外国生まれである．したがって，マニュアル (manual) 等はほとんどは英語である．それなりの努力が必要なことは言うまでもない．本年度の実習で用いる十進BASICでは日本語マニュアル（オンライン）が利用できる．しかし，コンピュータを深く理解しようとすると，英語の資料を読む必要があり英語の読解力が必要である．

３）国家試験との関連

薬剤師業務でコンピュータが必要であることは言うまでもない．しかし，薬剤師国家試験ではコンピュータの知識・技能を問う問題は出題されないので，重要ではないという誤った考えが存在する．コンピュータの勉強は，卒業してからでは遅すぎることを明言しておきたい．

これらの問題点が大学教育における共通の課題であることを近い将来理解することになるはずである．

インタプリタとコンパイラ

人間がプログラミング言語（ここではBASIC言語）で記述したソフトウェアの設計図 (ソースコード)を，コンピュータが実行できる形式(オブジェクトコード)に変換しながら，そのプログラムを実行するソフトウェアにはインタプリタとコンパイラがある．インタプリタ型の言語はプログラムの実行時に変換を行なうため，その分だけコンパイラ型言語よりも遅い．

コンパイラ型言語ではソースコードは翻訳時にまとめて変換され，実行時にはオブジェクトコードを直接実行するため，インタプリタ (interpreter)型言語に比べて実行速度が大幅に速い．そのため，音声や動画の再生を可能にしている．BASIC言語は，インタプリタ方式が多いが，コンパイラ（商用，高価）も開発されている．一方，FORTRAN, Cなどの高速処理を必要とする言語はコンパイラ方式である．

BASIC言語

（仮称）十進BASIC

文教大学の白石和夫氏により数学教育用に開発されたBASIC言語であり，Windowsマシン上で実行可能である．高校や大学のプログラミング教育用に採用されている．インターネット経由でダウンロードできるフリーウエアであるので，自分のパソコンにも容易にインストールできる．

十進BASICのホームページ

その他のBASIC

• N88-BASIC（Windows） NEC系
• FBASIC（Windows）富士通系
• Real BASIC
• FutureBasic III
• TNT BASIC
• BASIC/98
• Visual BASIC
• Quick BASIC
• Chipmunk BASIC（Macintoshフリーウェア）

David Gillespieが基本インタプリタを開発（1990），Ron Nicholsonによってファイル，グラフィックス，UNIX対応へと成長し，現在の形となり，Power Machintoshへの対応が実現した（1998）．インタプリタ本体のエディタが使いにくい難点があるが，前年度実習では簡易エディターとしてBBEdit Liteを使用することによってワープロ感覚でプログラムを編集し，実行させる方式を採用した．Ron's BASIC Programming and Chipmunk Basic Home Page

現在では，統計処理などの問題解決に市販のプログラムを用いればかなりのことが解決できる．そのような高価なプログラムに代わって，いろいろな問題解決に役立つBASIC言語によるプログラミングの世界を体験してほしい．

プログラミングの前に：フローチャートについて

フローチャート（流れ図）は「建築」に例えれば設計図にあたる．簡単なプログラムはフローチャートが無くても作れるが，ちょっと複雑になると予め「手順」を決めておかないと，何をやっているか判らなくなってしまう． 初心者の頃からフローチャートを書くことを心掛けよう（毎年，無視される）．

１）流れ図の基本型

フローチャート記号

フローチャートを作成する場合は JIS (日本工業規格）で定められている記号を使用 する．

FORTRAN言語（科学技術計算に使われる言語）では

N=0

S=0.0

READ(5,10) A

10 FORMAT(5F5.0)

IF(A.LT.0.0) THEN GO TO 60

S=S+A

N=N+1

GO TO 10

H=S/N

WRITE(6,20) N,H

20 FORMAT(2F5.2)

STOP

END

DATAは別のファイルから読み込む 60 70 65 85 43 91 56 81 75 61 35 54 90 80 -999

C言語では

#include ＜stdio.h＞

int main(void)

{

int x[ ] = {60,70,65,85,43,91,56,81,75,61,35,54,90,80};

int n = sizeof x / sizeof x[0];

int i, total;

float average;

for (i= 0, total = 0; i＜n; ++i)

total += x[i];

average = (float)total / (float)n;

printf("Total=%d\n", total);

printf("Average=%6.2f\n", average );

return 0;

}

上記の例から，なんとなく分かる（？）ように，フローチャートができると，いろいろな言語に変換できる．ここで必要なのは手続きを順序たてて考えることである．

かなりのベテランになると，フローチャートを頭の中でイメージしながら，いきなりキーボードから打ち込みプログラムを完成させることができるが，初心者には無理である．必ずフローチャートを作ってからプログラミングを行うよう心掛けること．

プログラム作成，入力時の注意事項

プログラムを書く際，以下に示す文字は誤りやすいので，注意が必要である．

Ｃ と （（括弧）

Ｄ と Ｐ，O（オー）, 0（ゼロ）

I （アイ） と １（いち），ｌ（小文字のLエル），/， i (小文字）

Ｚ と ２

U と Ｖ

： と ；

空白にも注意する．日本語入力モードの「空白」の１文字は半角文字の２文字で表現されている．

プログラム行の中に空白がある時，注意が必要である．詳細は後述する． 

などである．紛らわしい場合は「かさ」や「ネクタイ」を使う．Ｄ，Ｚは縦線にネクタイを付ける．O，Ｖは上部にかさを付ける．Iは上下に横線を付ける．

中括弧，大括弧は使わない．(a-b/(c-d))のようにすべて小括弧で書く．

演習 フローチャートの学習のため，三者面談から大学合格までの道筋をフローチャートで表せ．個人情報保護法のため，必ずしも提出の必要はない．紆余曲折のなかった人は願望を書いてもよい．

BASIC言語の基本文法

BASIC言語にもいろいろな種類があるが，グラフィック機能を除くと基本はほとんど同じである．まず，加減乗除プログラムを入力し，実行することを手始めにBASIC言語の仕組みを理解してほしい．

プログラムの実行 (execution)

出来上がったプログラムを実行 (execution) するにはRUNと打ち込み，リターンキーを押し下げる．十進BASICではメニューから「実行」を選ぶ．

演習 30行を下記のように書き換えるとそれぞれの演算ができる．実行せよ．

引き算 30 c=a-b

掛け算 30 c=a*b

割り算 30 c=a/b

文法に誤りがあると，実行を中止し，修正すべき個所（もっとも可能性の高い）を示してくれる．それを頼りにプログラムの問題点を修正し，再実行する．

文番号と多重文 (statement label and multiple sentence)

プログラムの際は文番号を付ける．

多重文が使えるBASICでは，次のような書き方ができる．

10 a=2: b=3: c=a+b:

20 print c

予約語 (reserved word) 以下の綴りは予約語（命令などのために使用される）のため，変数名や関数名として使えない．

NOT，ELSE，PRINT，REM，PI（π），RND，MAXNUM，TIME，DATE，EXTYPE，EXLINE，ZER，CON，IDN，TRANSFORM

I=A+Bのように足し算の演算結果をPIという変数に入れることはできない．PIは3.141592をコンピュータに記憶させるために予約されている．予約語はBASIC言語の種類によって異なるので，注意が必要である．

INPUT文

上記のプログラムは「足し算」する値をプログラムの中に書き込んで実行した例である．キーボードから任意の数値を入力する場合は INPUT文を用いる．対話型処理ができる．パソコンがA, Bの値を入力するように促すので，それぞれの値を入力する．

十進BASICを起動すると

• BASICプログラムを書き込み編集，実行するメニュー画面
• INPUT文が実行されると入力を促す質問画面
• 答えを表示する画面

が自動的に表示される．

BMIによる標準体重

BMIとは，Body Mass Indexのことで，体重÷身長÷身長で算出した体格指数である．

1980年代以降に肥満度の指標として国際的に用いられている．

日本肥満学会は，最も疾病の少ないＢＭＩ２２を基準としている．

したがって，標準体重の計算式は次のようにあらわされる．

身長（m）の2乗×22（女性は21をかける）．

例えば，身長1.75ｍの男性の場合は，

1.75×1.75×22=67.4

で，67kgが標準体重となる

そこで，

標準体重（ＢＭＩ）を計算するプログラムを作ってみよう．

●ＢＭＩ＝ 体重（kg）÷ 身長（ｍ）÷ 身長（ｍ）

●標準体重（kg）＝ 身長（ｍ）× 身長（ｍ）×２２

プログラムは下記のように対話形式（英語）にすること．

身長 (body height) を入力 (input) してください？

体重 (body weight) を入力してください？

あなたのＢＭＩ値は２４です．

あなたの標準体重は６２です．

演習 不快指数の算出プログラムを作成せよ．不快指数Ｄは，気温Ｔ，相対湿度Ｕから，次式で定義される．

Ｄ＝0．81Ｔ＋0．01Ｕ(0．99Ｔ－14.3)＋46.3 

不快指数の感覚的目安としては，

不快指数７５以上・・・・・やや暑い．

不快指数８０以上・・・・・暑くて汗が出る．

不快指数８５以上・・・・・暑くてたまらない．

READ文

データをdata文で与えることもできる．下記のプログラムを実行すると，まず10行を実行し，aを読み込む．その際，50行のdata文で与えられた"2"が読み込まれる．20行では60行のdata文の3が読み込まれる．

10 read a 

20 read b

30 c=a+b

40 print c

50 data 2

60 data 3

70 end

10行と20行を合体させて，read a,bでもよい．

演習 プログラムを入力し実行せよ．

数値変数と文字変数

いままでコンピュータにデータを入力するには変数を用いてきた．例）a=2 

では「a」という文字そのものを表示するにはどうすればよいだろうか．答えは簡単. a$="a" である．

BASICでは，通常の変数は「数値変数」として扱われ，初めは値にゼロが入っている．変数を文字として取り扱うときには変数名の最後に「$：ダラー」をつけると「文字変数」になる．文字は"（ダブルクォーテーション）でくくる．

文字列の加算（連結）

10 READ A$

20 READ B$

30 C$=A$+B$

40 PRINT C$

50 DATA SOJO

60 DATA UNIVERSITY

70 END

A$="SOJO"，B$="UNIVERSITY"の場合，C$は"SOJO UNIVERSITYである"．

演習 上記プログラムを書き換え，いろいろな文字を表示してみる．

文字処理のため，数値ー文字変換 (STR$)，文字数 (LEN) 関数等が用意されている．但し，一般のBASICで使用される文字列検索 (INSTR)，部分文字列を切り出す関数(LEFT$, MID$, RIGHT$)については，十進BASICでは形式の異なる下記の関数を使用する． FORTRAN言語と同じ方法を採用している．

文字列検索 ：POS(a$,b$) a$ における b$ の位置を返す．

部分文字列指定：文字列変数 s$(a:b) は s$ のa文字目からb文字目までの部分文字列を表す．

文字列の長さ，位置，切り出し

10 LET a$="Department of Computational Molecular Design, Faculty of Pharmaceutical Sciences, Sojo University"

20 LET n=len(a$)

30 PRINT n

40 LET b=pos(a$,"Mol")

50 PRINT b

60 LET d$=a$(15:25)

70 PRINT d$

80 END

演習 上記プログラムを入力，実行し，コマンドを理解せよ．

実行結果はそれぞれ

a$の文字数，"Mol"が表れる位置，15文字目から25文字目までを切り出したものである．

演習 対話形式で年齢を入力し，画面に「私の年齢は○○歳です」と表示するプログラムを作成せよ．

文字変数の詳細にについては別項で詳述する．また文字列の取扱いには awk, perl, ruby などのスクリプト系言語がよく用いられる．これらについては５年次開講予定の「UNIX入門」で学習する．

組み込み関数 (intrinsic function)

次に示す例は関数を用いて平方根 ( square root, 略 SQRT) を求めるプログラムである．括弧内に変数が入る．実行すると次々に値を要求してくる．10行と40行で「くり返し（ループ）」を構成している．

10 input a

20 b = sqr(a)

30 print b

40 goto 10

50 end

演習 プログラムを入力し実行せよ．また，２０行のsqrの代わりに以下の関数を用いて実行せよ．

abs(x) 絶対値

int(x) 整数値

log(x) 自然対数

exp(x) eのx乗 e=2.7182818...

SIN(X), COS(X), ATN(X)の三角関数のXはコンピュータではラジアンである．十進数を変換する場合は，3.141592/180を乗じる．十進BASICでは，十進数のオプション（OPTION ANGLE DEGREES）が用意されている．

初心者のうちは，ここに紹介した程度の関数の知識で十分である．

数値と数値関数 (numeric value and numeric function)

数値は15桁の浮動小数点10進数

JISが定める数値組込み関数はすべて用意されている。詳細はオンラインヘルプを参照。

OPTION ANGLE DEGREES 三角関数の角の大きさの単位を度(°)にする。

OPTION ANGLE RADIANS 三角関数の角の大きさの単位をラジアンにする。

ANGLE DGREESを選択すると，COS(90),SIN(180)などは正確に0になる。

演習 三角関数プログラムを入力し，度(°)およびラジアンモードで実行せよ．

○区分求積法 (sectional measurement)

積分値 ∫ab f(x)dxを計算する

図で x=a から x=b まで N 等分して、その幅を v=(b-a)/n とすると、

面積 s は、

s = f(a)v + f(a+h)v + … + f(a+(n-1)v)v

で近似される。

分割数 N を増やしていけば、より正確な積分値に近づく。

10 def fn(x)=x*x

15 t=0

20 for i=0 to 1 step 0.01

30 l=fn(i)

35 t=0.01*l

40 s=s+t

50 next i

60 print s

70 end

このプログラムは、y=x²の0から1までの面積を求めるプログラムである。step 0.01は100等分することを意味している。

演習 上記プログラムを入力せよ．STEP値をいろいろ変えて（0.1, 0.05, 0.01など）実行し、数学の公式で求めた値 と比較せよ．結果を電子メモに記録しておくこと．

ヒント

1. print 変数 を実行すると計算結果を表示する毎に改行する．したがって結果は縦に表示される．
2. 計算結果を水平方向へ表示させるにはセミコロンを付加する（PRINT K;）．
3. 決められた位置に表示するには，次の構文を用いる．
4. print using "####”:k;
5. printだけを実行すると，「改行（カーソルは次行の始めに移動）」のみを行う．

演習

1. 九九算を逆順に書き出すようにプログラムを書き換えよ（81 72 63 54 - -）．
2. print using "##．##":k;を用いて実行せよ．

いろいろな繰り返し構文（追加）

for--next文以外にもいろいろな構文が利用できる．

for variable = start to end [ step increment ]       例 for I=0 to 10 step 0.5:a=a+i: next i

  commands                                                                                    

next                                                                                               

do

  commands

loop

while condition                     例 while x<12

  commands

wend

do while condition                  例 do while x<12

  commands

loop

数値演算の条件記述法

• ａ＝ｂ 等しい場合 ＝ Equal To
• ａ＞ｂ より大きい場合 ＞ Greater Than
• ａ＞＝ｂ より大きいか等しい場合 ≧ Greater than or Equal to
• ａ＜ｂ より小さい場合 ＜ Less Than
• ａ＜＝ｂ より小さいか等しい場合 ≦ Less than or Equal to
• ａ＜＞ｂ 等しくない場合 ≠ Not Equal to

ブロックIF文の使用法 (if_then_else_elseif_end ifなど)

すっきりした構文で，込み入った条件が記述できる．ここでは，入力された点数に応じて，優，良，可，不合格の４段階に仕分けして，その結果を表示する．条件が二重になっている点に注意すること．

10 input a

15 if a>100 then

16    print"再入力！"

18    goto 10

19 end if 

20 if a<=100 and a>=80 then            ！’80<= a <=100

30     print"優"

40   elseif a<80 and a>=70 then        ！’70<= a <80

50     print"良"

60   elseif a<70 and a>=60 then        ！’60<= a <70

70     print"可（但しレポート提出）"

80   else                              ！’a <60

90     print"再試験"

100 end if

110 goto 10

120 end

重要追加項目 if_then_elseif_else_end if 構文について

(1)

  IF 論理式1 THEN

     ………1

  ELSEIF 論理式2 THEN 

     ………2

  ELSE 

     ………3

  END IF

は，次の構文（二重IF文）と等価である．

  IF 論理式1 THEN

     ………1

   ELSE

     IF 論理式2 THEN 

      ………2

     ELSE 

      ………3

     END IF

  END IF

  論理式1が真であるとき………1が実行され，

  論理式1が偽であるときは，

  論理式2が真であれば………2が実行され，

  論理式2も偽であれば………3が実行される。

例 ２次方程式の解のプログラム

  INPUT a, b, c

  LET D=b^2-4*a*c

  IF D>0 THEN

     PRINT (-b+sqr(D))/(2*a),(-b-sqr(D))/(2*a)

  ELSEIF D=0 THEN

     PRINT -b/(2*a)

  ELSE

     PRINT "no solution"

  END IF

  END

(2)  一般的な構文

  IF 論理式1 THEN

     ………1

  ELSEIF 論理式2 THEN

     ………2

  ELSEIF 論理式3 THEN

     ………3

     ～～～

     ～～～

  ELSEIF 論理式n-1 THEN

     ………n-1

  ELSE 

     ………n

  END IF

  論理式1が真であるとき………1が実行され，

  論理式1が偽であるとき，

  論理式2が真であれば………2が実行され，

  論理式2も偽であるとき，

  論理式3が真であれば………3が実行され，

  ～～～，すべての論理式が偽であるとき………nが実行される。

演習 上記プログラムについて，いろいろな値を入力，実行し，構文を理解せよ．

GOTO文を多用して，あっちこっちに飛ぶような書き方は極力避けるべきである．ブロックIF文はFORTRAN言語などの高級言語でも使用される．

演習 前出のBMIプログラムを，性別を入力し，区別して計算できるように改造しなさい．

その際，下記の判定結果も表示しなさい．．

• 18.5未満 やせ
• 18.5～25未満 標準
• 25～30未満 肥満
• 30以上 高度肥満

配列変数 (array variable)

プログラムのはじめの部分に，DIM a(8) と書くと，a(1)，a(2)，a(3)，a(4)，a(5)，a(6)，a(7)，a(8)の計8個の変数が用意される．a(1)，a(2)，…，a (8)は，それぞれ，普通の変数として使用できる．これらの変数全体をまとめて配列とよぶ．個々の変数は添字付き変数，括弧内を添字という． 単純にaと書いた変数とは異なり，a(1), a(2)・・a(n)で表される変数である．括弧内の整数値で何番目の変数かを指定することができる．

演習 以下のDATA文を読み込み，最小値と最大値を求めるプログラムをつくれ．

DATA 1, 2, 3, 4, 5, 6, 7, 8, 9, 10

下記のプログラムを実行すると，ランダムに列んだn個の数値データを読み込んで，小さい順に並べ替える．そのためには，まずdimension文を使用して，n個の番号のついた記憶場所をメモリー上に用意する．

○並べ替えプログラム (Sorting)

10 read n →データの個数を100行のdata文から読み込む

20 dim x(n) →変数xはx(1), x(2), x(3), ・・, x(n)のように番号を付けられ，n個のデータの記憶場所が確保される

30 for i=1 to n → iは1からnまで変化しながら次行でデータx(i)を110行のdata文から読み込む

40 read x(i)

50 next i →30行と繰り返し文を構成している

55 rem ----- sorting ----- →コメント行（実行とは関係ないメモ）

60 for i=1 to n →90行と繰り返し構文

65 for j=i+1 to n →85行と繰り返し構文

70 if x(j)＜x(i) then →80行と判断文を構成（もし条件が成立すれば以下を実行）

72 kari=x(i) →kariにx(i)の値を代入

74 x(i)=x(j) →x(i)にx(j)の値を代入

76 x(j)=kari → x(j)にkariの値を代入，x(j)とx(i)の入れ替えが実行される，

80 end if 

85 next j →

90 next i →

91 rem ----- output of result ----- →結果の表示（メモ）

92 for i=1 to n

94 print x(i);

96 next i

100 data 10

110 data 6,2,5,4,10,9,1,8,3,7

120 end

実行すると

1 2 3 4 5 6 7 8 9 10

が得られる．

演習 上記プログラムを入力，実行し，構文を理解せよ．

参考資料（関連コマンド）

SWAPによる配列の入れ替え (swap operation)

ほとんどのBASICでは配列の値を直接交換する "SWAP"が利用できるが、コマンドとして準備されていないBASICもあるので仮変数を用いる前例を理解しておくこと。

60 for i=1 to n

65 for j=i+1 to n

70 if x(j)＜x(i) then

75 swap x(i),x(j) →前出のプログラムの72,74,76行を一行で実行する

80 end if

85 next j

90 next i

演習 前のプログラムの「データ入替え部分」をswap文を用いる方式に書き直し，実行して構文を理解せよ．

＜２次元配列について＞

２次元配列の概念を理解する．まず，下記のプログラムを実行して理解してほしい．九九算の値を９行９列の配列 [A(i,j)]に記憶させ，逆順に取り出して表示する．

＜参考にするプログラム＞

10 dim ij(9,9)

15 for i=1 to 9

20 for j=1 to 9

25 ij(i,j)=i*j

30 next j

35 next i

40 for i=9 to 1 step -1

50 for j=9 to 1 step -1

60 print using "###": ij(i,j);

70 next j

75 print

80 next i

90 end

＜演習問題１＞

有機化合物を構成する炭素、水素、窒素等の比を求めるために、元素分析を行う。分析センターに試料を提出すると、有機物を完全燃焼させることにより得られる生成物（炭酸ガス、水等）から計算した値（各元素のパーセント）が返される。元素分析値から組成式を計算するプログラムを作りなさい。

○炭素，水素，窒素以外は酸素とすること．

したがって，酸素％＝１００－（炭素％＋水素％＋窒素％）である．

○最終的には，分子量が与えられたとして，分子式を求めること．

１．電卓で計算するとしたらどのような手順で計算するか考える．

２．その手順に沿ってフローチャート（メモでもよい）を考える．

１）配列変数を確保する

２）データを読み込む

３）データを合計する

４）酸素の％を求める

以下，C, H, O, N比を求め，これに分子量をかけることで，各原子の比が得られる．

その他の方法として，C, H, O, N比を求め，その最小値を求める. さらに最小値を１とする相対値を求める．

得られた値を整数化する．

３．フローチャートにBASIC言語をあてはめる．

４．テストデータ

ニトロベンゼン

炭素 ５８．５４％：水素 ４．０９％： 窒素 １１．３８％

分子量 １２３．１１

５．計算結果はC₆H₅NO₂のように表示させる．（下付きにはしなくてよい）

＜データ＞

炭素 ６９．１９％：水素 ６．０７％： 窒素 ７．６１％ 分子量 ３６６．４１

炭素 ６８．１５％：水素 ５．００％： 窒素 ３．３４％ 分子量 ４１９．４３

炭素 ７７．１５％：水素 ５．０３％： 窒素 ０％ 分子量 ３５８．１２

＜演習問題２＞（予定）

最小二乗法（直線のあてはめ）を用いて回帰式と相関係数を算出する。

作成手順：

1. READ～DATA 文によるデータの配列変数への読み込み
2. Xi の和、Yi の和、Xi の平均値 (Xav) 、Yi の平均値 (Yav) の算出
3. (Xi -Xav)^2 の和、(Yi -Yav)^2 の和、(Xi -Xav)(Yi -Yav) の和の算出
4. y=a*x+bのa, b, r（相関係数） の算出

テストデータと計算結果

データ数：４

Ｘ Ｙ Xの平均 2.5

１ ５ Ｙの平均 8 傾き a=1.6

２ ８ Ｘの分散 1.25 切片 b=4

３ ９ Ｙの分散 3.5 相関係数 r=0.956

４ 10 共分散 2

デバッグ

注意して作ったプログラムでも，データを変えて実行しているうちに，予想しなかったエラーが発生し，実行できなくなることがある．このような「バグ」を見つけだし，改善することをデバッグとよぶ．プログラム内に潜む虫を退治することを意味する．演算過程で発生するエラーは，計算式の後にprint文を挿入し途中結果を書きだすことにより発見できることが多い．十進BASICでは，このような場合に対応するための機能が準備されている．

グラフィックス

画像を描くコマンドは言語の種類によって異なるので，プログラムを作成する際はマニュアルを調べる必要がある．

ディスプレイは小さな点の集合体 (800x600, 1024x768など) である．任意の点を指定した色で光らせることにより，どんな図形でも描くことができる．以下に示すプログラムでは，曲線，サインカーブや円などを画面に表示させる． まず，WINDOWで画面の範囲を指定する．線を描くには PLOT LINES文を用いている．

○関数のグラフを描く

下記のプログラムを実行し，各行の意味を理解してほしい．

10 OPTION ANGLE DEGREES

20 DEF f(x)=sin(x)

30 SET WINDOW -360,360,-2,2

40 DRAW GRID(90,1)

50 FOR x=-360 TO 360

60 PLOT LINES: x,f(x);

70 NEXT x

80 END

10行：角の単位は標準ではラジアンであるが，OPTION ANGLE DEGREESをプログラムのはじめに書くことにより，単位を度(degrees)に変えることができる．SIN関数が実行する前に書く．

20行：DEF文は関数を定義する命令

30行：SET WINDOW文は，画面上の描画領域に，x座標の範囲が-360から360，y座標の範囲が-2から2となるような座標系を設定する．

40行：grid(a,b)は，横軸方向a間隔，縦軸方向b間隔の格子を描く．

60行：PLOT LINES命令は，点[x , sin(x)]を順に結び線を描く．

演習 上記プログラムを入力，実行し，構文を理解せよ．

演習 -4≦x≦4，-4≦y≦4の範囲で関数y=x^3-3*x＋1のグラフを描きなさい．

上記プログラムの10,20,30,40,50行を修正する．

○円，楕円を描く

-PI から PI まで STEP 0.002で計算した座標を結んで図を描く．

10 SET WINDOW -5,5,-5,5

20 FOR T=-PI TO PI STEP 0.002

30 PLOT LINES: T,SIN(T);

40 NEXT T

50 END

30行を PLOT LINES: SIN(T),COS(T); に代えると円を描く．ここでは省略するが，線の色や塗りつぶす色なども指定できる．

演習

指導者に質問する前に努力すること．

１）半径を変えて円を描きなさい．

２）楕円を描きなさい．

３）線の色を変えて円を描きなさい（ヘルプで調べる）．

＜参考資料＞図形処理のための命令

JISに従い，問題座標系によるグラフィック機能を提供している。詳細はオンラインヘルプを参照。

SET WINDOW 

SET LINE COLOR 

SET POINT COLOR 

SET AREA COLOR 

SET TEXT COLOR 

SET COLOR MIX 

SET LINE STYLE 

SET POINT STYLE 

SET TEXT JUSUTIFY 

ASK WINDOW 

PLOT LINES 

PLOT POINTS 

PLOT AREA 

PLOT TEXT （動作上の非互換がある） 

GET POINT 

その他

色番号 0白， 1黒， 2青， 3緑， 4赤， 5水色， 6黄色， 7赤紫，8 灰色，9 濃い青, 10 濃い緑，11 青緑， 12 えび茶，13 オリーブ色，14 濃い紫，15 銀色

図形変形関数：DRAW文で次の関数が使える．

• SHIFT(a,b) 平行移動
• SCALE(a,b) 拡大縮小
• SCALE(a) 拡大縮小
• ROTATE(a) 回転
• SHEAR(a) せん断

＜演習問題＞

先に作った最小二乗法プログラムのグラフィック表示を行え．

1. 入力データをプロットする．
2. 最小二乗線を描く．
3. 最後に，どのような入力データにも適応するように改造すること．そのためには，入力データX, Yそれぞれの最小値，最大値を求め，その幅に合わせてWINDOW幅を変える必要がある．
4. グラフ上にタイトル，相関係数などのデータを表示させる．

文字列の処理

BASIC言語には文章の処理を対象にしたコマンドが用意されている．文字列は変数の後に$マークを付ける．

文字列の加算（連結）

10 READ A$

20 READ B$

30 C$=A$+B$

40 PRINT C$

44 DATA KUMAMOTO

46 DATA UNIVERSITY

50 END

A$="KUMAMOTO"，B$="UNIVERSITY"の場合，C$はKUMAMOTO UNIVERSITYである．

演習 上記プログラムを入力，実行し，構文を理解せよ．

文字処理のため，数値ー文字変換 (STR$)，文字数 (LEN) 関数等が用意されている．但し，一般のBASICで使用される文字列検索 (INSTR)，部分文字列を切り出す関数(LEFT$, MID$, RIGHT$)については，十進BASICでは形式の異なる下記の関数を使用する． FORTRAN言語と同じ方法を採用している．

文字列検索 ：POS(a$,b$) a$ における b$ の位置を返す．

部分文字列指定：文字列変数 s$(a:b) は s$ のa文字目からb文字目までの部分文字列を表す．

文字列の長さ，位置，切り出し

10 LET a$="Department of Computational Molecular Design, Faculty of Pharmaceutical Sciences, Kumamoto University"

20 LET n=len(a$)

30 PRINT n

40 LET b=pos(a$,"Mol")

50 PRINT b

60 LET d$=a$(15:25)

70 PRINT d$

80 END

演習 上記プログラムを入力，実行し，コマンドを理解せよ．

実行すると

101

29

Computation

が表示される．a$の文字数，"Mol"が表れる位置，Computationは15文字目から25文字目までを切り出した結果である．

キャラクターコード

文字の内部表現

BASICでは変数に＄が付くと文字変数と判断する．

abcABC 12345, などは１バイト（８個の0,1）．漢字は２バイト（１６個の0,1）で表す．文字にはキャラクターコード番号が付けられている．

例

• 01010000:P
• 10110001:
• 0011000000100110：愛
• 0010011000100001：Ａ（漢字）

キャラクターコード実例

十進数と１６進数で表した場合

• Aは65， 41
• aは97， 61
• Kは75， 4B
• kは107，6B

である．大文字，小文字も区別できる．漢字も同じようにコードが存在する．

コード表はいろいろな参考書に出ているので詳しい説明は省略する．

文字配列

文字にはキャラクターコード番号が付けられているので，文字列の比較も可能である．以下のプログラムは氏名をアルファベット順に並びかえるプログラムである．コンピュータは第一文字目のコードを比較してその順に並びかえる．第一文字目が同じ場合は２文字目を比較する．

10 dim a$(10)

20 for i=1 to 10  →配列（データを記憶させる場所）を１０個確保する．

30  read a$(i)

40 next i

50 for i=1 to 9 

55  for j=i+1 to 10

56    if a$(i) < a$(j) then 70

57      qqq$=a$(i)

58      a$(i)=a$(j)

59      a$(j)=qqq$

70  next j

80 next i

90 for i=1 to 10

92  print a$(i);

94 next i

96 data watanabe,kojima,yamada,suzuki,murakami,simada,nakamura,kimura,yasuda,imai

98 end 

演習 上記プログラムを入力，実行し，構文を解析せよ．数値の並べ替えプログラムと比較せよ．また，医薬品名やクラスメートの氏名（漢字）などを入力し，実行せよ．

＜参考資料＞文字列を処理するための命令

文字列組込み関数（JISが定める組込み関数はすべて用意されている）。詳細はオンラインヘルプを参照。

• CHR$(m) 文字コードｍに対応する文字
• DATE$ 日付
• LCASE$(a$) 小文字に変換
• LEN(a$) 長さ
• LTRIM$(a$) 左空白削除
• ORD(a$) a$の文字コード
• POS(a$,b$) a$におけるb$の位置
• REPEAT$(A$,m) 反復文字列
• RTRIM$(a$) 右空白削除
• STR$（x） 文字列
• TIME$ 時刻
• UCASE$(a$) 小文字に変換
• USING$(a$,x) 書式化
• VAL(a$) 数値化

部分文字列指定

s$を文字列変数，a,bを数値式とするとき，s$(a:b)はs$のa文字目からb文字目までの部分文字列を表す．

LET s$(a:b)=文字列式 の形式で，部分文字列の置換も可能．

おわりに

BASIC 言語は，1965年米国ダートマス大学のJ. G. KemenyとT. E. Kurtzによって開発された． 当時，大学１年生に４時間程度の集中講習で修得させたとのことである．

今回はファイルの入出力の詳細を紹介できななかった．BASIC言語を実用的に利用するには必須である．これらの利用法についてはプログラム中の HELPメニューや実例を参考にしてほしい．

ゲノム創薬研究者や情報処理に精通した薬剤師になるために問題解決手法（アルゴリズム）の一つとしてプログラミング技法をぜひ修得しておいてほしい．

卒業したら年齢的に柔軟性が減少し，プログラミング対応力が減退するので，何でも吸収できる今が絶好のチャンスである．

崇城大学薬学部版（平成２０年６月２日） 修正責任者 原野一誠