Использование общих модулей "Длительные операции" позволяет перенести всю тяжесть исполнения ресурсоемких процедур на сторону сервера, не мешая при этом работе клиентского приложения, инициировавшего этот процесс, т.е. не мешая дальнейшей работе пользователя в приложении. Описанная возможность реализуется в модулях БСП за счет исполнения "тяжелых" процедур на сервере в фоновом режиме (запуску фоновых заданий под каждую процедуру).
Для этого в форме обязательно должны содержаться два реквизита "АдресХранилища" (типа строка) и "ИдентификаторЗадания" (типа уникального идентификатора), в модуле формы должна быть объявлена клиентская переменная "ПараметрыОбработчикаОжидания".
Помимо этого экспортная процедура длительной операции должна содержать в себе два параметра "СтруктураПараметров" (типа структуры) и "АдресХранилища" (типа строка), результат исполнения должен быть помещен во временное хранилище, а адрес в нем должен быть присвоен параметру "АдресХранилища".
Пример:
Процедура ПодготовитьДанныеДляЗаполнения(СтруктураПараметров, АдресХранилища) Экспорт
ДанныеДляЗаполнения = Новый Структура;
Результат = ПолучтьРезультат(СтруктураПараметров);
ДанныеДляЗаполнения.Вставить("Результат", Результат);
ПоместитьВоВременноеХранилище(ДанныеДляЗаполнения, АдресХранилища);
КонецПроцедуры
Алгоритм:
1. Процедура обработчика команды, отображаемой на форме, инициирующей запуск длительной операции.
2. В ней производится передача исполнения на сервер и получение результата выполнения.
3. В случае, если результат для отображения пользователю еще не готов, то наша операция "квалифицируется" как длительная, и производится подключение обработчика ожидания для периодической проверки выполнения фонового задания, исполняющего нашу длительную операцию.
&НаКлиенте
Процедура ВыполнитьПроцедуруФоново(Команда)
ОтключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания");
РезультатВыполнения = ВыполнитьФоновоеЗаданиеНаСервере();
Если РезультатВыполнения.ЗаданиеВыполнено Тогда
РезультатВыполнения = ПолучитьИзВременногоХранилища(АдресХранилища);
Иначе
ДлительныеОперацииКлиент.ИнициализироватьПараметрыОбработчикаОжидания(ПараметрыОбработчикаОжидания);
ПодключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания", 1, Истина);
КонецЕсли;
КонецПроцедуры
Собственно сама серверная процедура, которая запускает необходимую нам длительную операцию, вызов которой будет произведен из "ИмяМодуля.ИмяЭкспортнойПроцедуры" (например: "Обработки.РегистрацияСчетовФактурНаАванс.ПодготовитьДанныеДляЗаполнения"). Также в этой процедуре заполняется структура параметров, необходимых для исполнения длительной операции, и запоминается идентификатор фонового задания, под которым выполняется длительная операция.
&НаСервере
Функция ВыполнитьФоновоеЗаданиеНаСервере()
ДлительныеОперации.ОтменитьВыполнениеЗадания(ИдентификаторЗадания);
ИдентификаторЗадания = Неопределено;
СтруктураПараметров = Новый Структура;
Если ОбщегоНазначения.ИнформационнаяБазаФайловая() Тогда
АдресХранилища = ПоместитьВоВременноеХранилище(Неопределено, УникальныйИдентификатор);
// здесь должен быть вызов нашей процедуры
РезультатВыполнения = Новый Структура("ЗаданиеВыполнено", Истина);
Иначе
РезультатВыполнения = ДлительныеОперации.ЗапуститьВыполнениеВФоне(УникальныйИдентификатор,
"ИмяМодуля.ИмяЭкспортнойПроцедуры",
СтруктураПараметров,
"Наименование фонового задания");
//Например:
//НаименованиеФоновогоЗадания = НСтр("ru = 'Заполнение таблицы ""Регистрация счетов-фактур на аванс""'");
// РезультатВыполнения= ДлительныеОперации.ЗапуститьВыполнениеВФоне(
// УникальныйИдентификатор,
// "Обработки.РегистрацияСчетовФактурНаАванс.ПодготовитьДанныеДляЗаполнения",
// СтруктураПараметров,
// НаименованиеФоновогоЗадания);
//
ИдентификаторЗадания = РезультатВыполнения.ИдентификаторЗадания;
АдресХранилища = РезультатВыполнения.АдресХранилища;
КонецЕсли;
Возврат РезультатВыполнения;
КонецФункции
Процедура обработчика ожидания мониторит выполнение запущенного нами фонового задания, в случае успеха - результат выполнения длительной операции извлекается из временного хранилища по адресу "АдресХранилища", в противном случае обработчик ожидания подключается заново для следующей очередной проверки.
&НаКлиенте
Процедура Подключаемый_ПроверитьВыполнениеЗадания()
Попытка
Если ЗаданиеВыполнено(ИдентификаторЗадания) Тогда
РезультатВыполнения = ПолучитьИзВременногоХранилища(АдресХранилища);
Иначе
ДлительныеОперацииКлиент.ОбновитьПараметрыОбработчикаОжидания(ПараметрыОбработчикаОжидания);
ПодключитьОбработчикОжидания("Подключаемый_ПроверитьВыполнениеЗадания",
ПараметрыОбработчикаОжидания.ТекущийИнтервал, Истина);
КонецЕсли;
Исключение
ВызватьИсключение;
КонецПопытки;
КонецПроцедуры
&НаСервереБезКонтекста
Функция ЗаданиеВыполнено(ИдентификаторЗадания)
Возврат ДлительныеОперации.ЗаданиеВыполнено(ИдентификаторЗадания);
КонецФункции