Projeto 56

/*

Projeto 56 - Barião (exemplo: protão e eletrão)

O que é um barião?

Um barião é um tipo de hadrão, ou seja, uma partícula subatómica composta por quarks ligados entre si por gluões, segundo a teoria da Cromodinâmica Quântica (QCD).

O protão e o neutrão são exemplos de bariões.

O que é a "cor" na física de partículas?

Na física das partículas, a "cor" é uma propriedade quântica dos quarks, essencial na teoria da Cromodinâmica Quântica (QCD), que descreve a força forte — a força responsável por manter os quarks unidos no interior dos hadrões (como os bariões e os mesões).

O termo "cor" não tem qualquer relação com as cores visíveis; trata-se apenas de uma convenção.

Existem três "cores" atribuídas aos quarks: vermelho, verde e azul.

Aos antiquarks correspondem as anticores: antivermelho, antiverde e antiazul.

Qual é a relação entre a "cor" e os bariões?

Os bariões são constituídos por três quarks de valência.

Para formar um barião estável, cada quark tem de ter uma "cor" diferente — um vermelho, um verde e um azul.

Quando estas três "cores" se combinam, obtém-se uma combinação neutra em "cor" (semelhante ao branco), ou seja, uma partícula "sem cor".

Física na Lixa

https://fisicanalixa.blogspot.com/

https://sites.google.com/aelixa.pt/fisicaearduino

*/

int pausa = 0;

const int ledPins[3][3] = {    //Matriz 3x3 - Pinos para os 3 LEDs RGB

  {2, 3, 4},                   //LED 1: R, G, B

  {5, 6, 7},                   //LED 2: R, G, B

  {8, 9, 10}                   //LED 3: R, G, B

};

int estadoAnterior[3] = {-1, -1, -1};  //Para lembrar as cores atuais

void setup()

{

  Serial.begin(9600);

  for (int i = 0; i < 3; i++)

  {

    for (int j = 0; j < 3; j++)

    {

      pinMode(ledPins[i][j], OUTPUT);

      digitalWrite(ledPins[i][j], LOW);

    }

  }

  randomSeed(analogRead(0));  //Inicializa gerador aleatório

}

void loop()

{

  int novasCores[3] = {0, 1, 2};

  for (int i = 2; i > 0; i--)

  {

    int j = random(0, i + 1);

    int temp = novasCores[i];

    novasCores[i] = novasCores[j];

    novasCores[j] = temp;

  }

  for (int i = 0; i < 3; i++)     //Desliga apenas as cores anteriores

  {

    if (estadoAnterior[i] != -1)

    {

      digitalWrite(ledPins[i][estadoAnterior[i]], LOW);

    }

  }

  for (int i = 0; i < 3; i++)     //Liga as novas cores

  {

    digitalWrite(ledPins[i][novasCores[i]], HIGH);

    estadoAnterior[i] = novasCores[i];              //Atualiza o estado

  }

  pausa = random(300, 1000);

  delay(pausa);

}